nb_kernel133_x86_64_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,141 行 · 第 1/5 页

        movsd  56(%rdi,%rcx,8),%xmm4
        movsd  64(%rdi,%rcx,8),%xmm5
        subsd  %xmm0,%xmm3
        subsd  %xmm1,%xmm4
        subsd  %xmm2,%xmm5
        movsd  %xmm3,48(%rdi,%rcx,8)
        movsd  %xmm4,56(%rdi,%rcx,8)
        movsd  %xmm5,64(%rdi,%rcx,8)

        ## accumulate force in xmm6/xmm7 for fshift 
        addsd %xmm2,%xmm7
        unpcklpd %xmm1,%xmm0
        addpd %xmm0,%xmm6

        ## accumulate Mi forces in xmm0, xmm1, xmm2 
        movapd nb133_fixM(%rsp),%xmm0
        movapd nb133_fiyM(%rsp),%xmm1
        movapd nb133_fizM(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addsd  %xmm3,%xmm0
        addsd  %xmm4,%xmm1
        addsd  %xmm5,%xmm2 ## sum is in low xmm0-xmm2 

        ## increment i force 
        movsd  72(%rdi,%rcx,8),%xmm3
        movsd  80(%rdi,%rcx,8),%xmm4
        movsd  88(%rdi,%rcx,8),%xmm5
        subsd  %xmm0,%xmm3
        subsd  %xmm1,%xmm4
        subsd  %xmm2,%xmm5
        movsd  %xmm3,72(%rdi,%rcx,8)
        movsd  %xmm4,80(%rdi,%rcx,8)
        movsd  %xmm5,88(%rdi,%rcx,8)

        ## accumulate force in xmm6/xmm7 for fshift 
        addsd %xmm2,%xmm7
        unpcklpd %xmm1,%xmm0
        addpd %xmm0,%xmm6

        ## increment fshift force 
        movlpd (%rsi,%rdx,8),%xmm3
        movhpd 8(%rsi,%rdx,8),%xmm3
        movsd  16(%rsi,%rdx,8),%xmm4
        subpd  %xmm6,%xmm3
        subsd  %xmm7,%xmm4
        movlpd %xmm3,(%rsi,%rdx,8)
        movhpd %xmm3,8(%rsi,%rdx,8)
        movsd  %xmm4,16(%rsi,%rdx,8)

        ## get n from stack
        movl nb133_n(%rsp),%esi
        ## get group index for i particle 
        movq  nb133_gid(%rbp),%rdx              ## base of gid[]
        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movapd nb133_vctot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addsd  %xmm6,%xmm7      ## low xmm7 has the sum now 

        ## add earlier value from mem 
        movq  nb133_Vc(%rbp),%rax
        addsd (%rax,%rdx,8),%xmm7
        ## move back to mem 
        movsd %xmm7,(%rax,%rdx,8)

        ## accumulate total lj energy and update it 
        movapd nb133_Vvdwtot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addsd  %xmm6,%xmm7      ## low xmm7 has the sum now 

        ## add earlier value from mem 
        movq  nb133_Vvdw(%rbp),%rax
        addsd (%rax,%rdx,8),%xmm7
        ## move back to mem 
        movsd %xmm7,(%rax,%rdx,8)

       ## finish if last 
        movl nb133_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel133_x86_64_sse2.nb133_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb133_n(%rsp)
        jmp _nb_kernel133_x86_64_sse2.nb133_outer
_nb_kernel133_x86_64_sse2.nb133_outerend: 
        ## check if more outer neighborlists remain
        movl  nb133_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel133_x86_64_sse2.nb133_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel133_x86_64_sse2.nb133_threadloop
_nb_kernel133_x86_64_sse2.nb133_end: 
        movl nb133_nouter(%rsp),%eax
        movl nb133_ninner(%rsp),%ebx
        movq nb133_outeriter(%rbp),%rcx
        movq nb133_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $1080,%rsp
        emms


        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret





.globl nb_kernel133nf_x86_64_sse2
.globl _nb_kernel133nf_x86_64_sse2
nb_kernel133nf_x86_64_sse2:     
_nb_kernel133nf_x86_64_sse2:    
##      Room for return address and rbp (16 bytes)
.set nb133nf_fshift, 16
.set nb133nf_gid, 24
.set nb133nf_pos, 32
.set nb133nf_faction, 40
.set nb133nf_charge, 48
.set nb133nf_p_facel, 56
.set nb133nf_argkrf, 64
.set nb133nf_argcrf, 72
.set nb133nf_Vc, 80
.set nb133nf_type, 88
.set nb133nf_p_ntype, 96
.set nb133nf_vdwparam, 104
.set nb133nf_Vvdw, 112
.set nb133nf_p_tabscale, 120
.set nb133nf_VFtab, 128
.set nb133nf_invsqrta, 136
.set nb133nf_dvda, 144
.set nb133nf_p_gbtabscale, 152
.set nb133nf_GBtab, 160
.set nb133nf_p_nthreads, 168
.set nb133nf_count, 176
.set nb133nf_mtx, 184
.set nb133nf_outeriter, 192
.set nb133nf_inneriter, 200
.set nb133nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb133nf_ixO, 0
.set nb133nf_iyO, 16
.set nb133nf_izO, 32
.set nb133nf_ixH1, 48
.set nb133nf_iyH1, 64
.set nb133nf_izH1, 80
.set nb133nf_ixH2, 96
.set nb133nf_iyH2, 112
.set nb133nf_izH2, 128
.set nb133nf_ixM, 144
.set nb133nf_iyM, 160
.set nb133nf_izM, 176
.set nb133nf_iqH, 192
.set nb133nf_iqM, 208
.set nb133nf_qqH, 224
.set nb133nf_qqM, 240
.set nb133nf_c6, 256
.set nb133nf_c12, 272
.set nb133nf_vctot, 288
.set nb133nf_Vvdwtot, 304
.set nb133nf_half, 320
.set nb133nf_three, 336
.set nb133nf_tsc, 352
.set nb133nf_rinvH1, 368
.set nb133nf_rinvH2, 384
.set nb133nf_rinvM, 400
.set nb133nf_krsqH1, 416
.set nb133nf_krsqH2, 432
.set nb133nf_krsqM, 448
.set nb133nf_rsqO, 464
.set nb133nf_nri, 496
.set nb133nf_iinr, 504
.set nb133nf_jindex, 512
.set nb133nf_jjnr, 520
.set nb133nf_shift, 528
.set nb133nf_shiftvec, 536
.set nb133nf_facel, 544
.set nb133nf_innerjjnr, 552
.set nb133nf_is3, 560
.set nb133nf_ii3, 564
.set nb133nf_ntia, 568
.set nb133nf_innerk, 572
.set nb133nf_n, 576
.set nb133nf_nn1, 580
.set nb133nf_nouter, 584
.set nb133nf_ninner, 588
        push %rbp
        movq %rsp,%rbp
        push %rbx
        emms


        push %r12
        push %r13
        push %r14
        push %r15

        subq $600,%rsp          ## local variable stack space (n*16+8)
        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb133nf_nouter(%rsp)
        movl %eax,nb133nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb133nf_nri(%rsp)
        movq %rsi,nb133nf_iinr(%rsp)
        movq %rdx,nb133nf_jindex(%rsp)
        movq %rcx,nb133nf_jjnr(%rsp)
        movq %r8,nb133nf_shift(%rsp)
        movq %r9,nb133nf_shiftvec(%rsp)
        movq nb133nf_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd %xmm0,nb133nf_facel(%rsp)

        movq nb133nf_p_tabscale(%rbp),%rax
        movsd (%rax),%xmm3
        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb133nf_tsc(%rsp)

        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double half IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb133nf_half(%rsp)
        movl %ebx,nb133nf_half+4(%rsp)
        movsd nb133nf_half(%rsp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## one
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## two
        addpd  %xmm2,%xmm3      ## three
        movapd %xmm1,nb133nf_half(%rsp)
        movapd %xmm3,nb133nf_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb133nf_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]      
        movl  (%rcx),%ebx           ## ebx =ii 

        movq  nb133nf_charge(%rbp),%rdx
        movsd 8(%rdx,%rbx,8),%xmm3
        movsd 24(%rdx,%rbx,8),%xmm4

        movsd nb133nf_facel(%rsp),%xmm5
        mulsd  %xmm5,%xmm3
        mulsd  %xmm5,%xmm4

        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        movapd %xmm3,nb133nf_iqH(%rsp)
        movapd %xmm4,nb133nf_iqM(%rsp)

        movq  nb133nf_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%ecx
        shll  %ecx
        movq nb133nf_p_ntype(%rbp),%rdi
        imull (%rdi),%ecx     ## rcx = ntia = 2*ntype*type[ii0] 
        movl  %ecx,nb133nf_ntia(%rsp)
_nb_kernel133nf_x86_64_sse2.nb133nf_threadloop: 
        movq  nb133nf_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel133nf_x86_64_sse2.nb133nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel133nf_x86_64_sse2.nb133nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb133nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb133nf_n(%rsp)
        movl %ebx,nb133nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel133nf_x86_64_sse2.nb133nf_outerstart
        jmp _nb_kernel133nf_x86_64_sse2.nb133nf_end

_nb_kernel133nf_x86_64_sse2.nb133nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb133nf_nouter(%rsp),%ebx
        movl %ebx,nb133nf_nouter(%rsp)

_nb_kernel133nf_x86_64_sse2.nb133nf_outer: 
        movq  nb133nf_shift(%rsp),%rax        ## eax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx        ## ebx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb133nf_is3(%rsp)            ## store is3 

        movq  nb133nf_shiftvec(%rsp),%rax     ## eax = base of shiftvec[] 

        movsd (%rax,%rbx,8),%xmm0
        movsd 8(%rax,%rbx,8),%xmm1
        movsd 16(%rax,%rbx,8),%xmm2

        movq  nb133nf_iinr(%rsp),%rcx         ## ecx = pointer into iinr[]      
        movl  (%rcx,%rsi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5
        movapd %xmm0,%xmm6
        movapd %xmm1,%xmm7

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb133nf_pos(%rbp),%rax      ## eax = base of pos[]  
        movl  %ebx,nb133nf_ii3(%rsp)

        addsd (%rax,%rbx,8),%xmm3       ## ox
        addsd 8(%rax,%rbx,8),%xmm4      ## oy
        addsd 16(%rax,%rbx,8),%xmm5     ## oz   
        addsd 24(%rax,%rbx,8),%xmm6     ## h1x
        addsd 32(%rax,%rbx,8),%xmm7     ## h1y
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm7,%xmm7
        movapd %xmm3,nb133nf_ixO(%rsp)
        movapd %xmm4,nb133nf_iyO(%rsp)
        movapd %xmm5,nb133nf_izO(%rsp)
        movapd %xmm6,nb133nf_ixH1(%rsp)
        movapd %xmm7,nb133nf_iyH1(%rsp)

        movsd %xmm2,%xmm6
        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 40(%rax,%rbx,8),%xmm6    ## h1z
        addsd 48(%rax,%rbx,8),%xmm0    ## h2x
        addsd 56(%rax,%rbx,8),%xmm1    ## h2y
        addsd 64(%rax,%rbx,8),%xmm2    ## h2z
        addsd 72(%rax,%rbx,8),%xmm3    ## mx
        addsd 80(%rax,%rbx,8),%xmm4    ## my
        addsd 88(%rax,%rbx,8),%xmm5    ## mz

        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm6,nb133nf_izH1(%rsp)
        movapd %xmm0,nb133nf_ixH2(%rsp)
        movapd %xmm1,nb133nf_iyH2(%rsp)
        movapd %xmm2,nb133nf_izH2(%rsp)
        movapd %xmm3,nb133nf_ixM(%rsp)
        movapd %xmm4,nb133nf_iyM(%rsp)
        movapd %xmm5,nb133nf_izM(%rsp)

        ## clear vctot
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb133nf_vctot(%rsp)
        movapd %xmm4,nb133nf_Vvdwtot(%rsp)

        movq  nb133nf_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx             ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb133nf_pos(%rbp),%rsi
        movq  nb133nf_faction(%rbp),%rdi
        movq  nb133nf_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb133nf_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb133nf_ninner(%rsp),%ecx
        movl  %ecx,nb133nf_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb133nf_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel133nf_x86_64_sse2.nb133nf_unroll_loop
        jmp   _nb_kernel133nf_x86_64_sse2.nb133nf_checksingle
_nb_kernel133nf_x86_64_sse2.nb133nf_unroll_loop: 
        ## twice unrolled innerloop here 
        movq  nb133nf_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx

        addq $8,nb133nf_innerjjnr(%rsp)                 ## advance pointer (unrolled 2) 

        movq nb133nf_charge(%rbp),%rsi     ## base of charge[] 

        movlpd (%rsi,%rax,8),%xmm3
        movhpd (%rsi,%rbx,8),%xmm3
        movapd %xmm3,%xmm4
        mulpd  nb133nf_iqM(%rsp),%xmm3
        mulpd  nb133nf_iqH(%rsp),%xmm4

        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1

        movapd  %xmm3,nb133nf_qqM(%rsp)
        movapd  %xmm4,nb133nf_qqH(%rsp)

        movq nb133nf_type(%rbp),%rsi
        movl (%rsi,%rax,4),%eax
        movl (%rsi,%rbx,4),%ebx
        movq nb133nf_vdwparam(%rbp),%rsi
        shll %eax
        shll %ebx
        movl nb133nf_ntia(%rsp),%edi
        addl %edi,%eax