nb_kernel113_x86_64_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,046 行 · 第 1/4 页

;#
;# $Id: nb_kernel113_x86_64_sse2.intel_syntax.s,v 1.1.2.2 2006/09/22 08:40:32 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as

.globl nb_kernel113_x86_64_sse2
.globl _nb_kernel113_x86_64_sse2
nb_kernel113_x86_64_sse2:	
_nb_kernel113_x86_64_sse2:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb113_fshift,           16
.equiv          nb113_gid,              24
.equiv          nb113_pos,              32
.equiv          nb113_faction,          40
.equiv          nb113_charge,           48
.equiv          nb113_p_facel,          56
.equiv          nb113_argkrf,           64
.equiv          nb113_argcrf,           72
.equiv          nb113_Vc,               80
.equiv          nb113_type,             88
.equiv          nb113_p_ntype,          96
.equiv          nb113_vdwparam,         104
.equiv          nb113_Vvdw,             112
.equiv          nb113_p_tabscale,       120
.equiv          nb113_VFtab,            128
.equiv          nb113_invsqrta,         136
.equiv          nb113_dvda,             144
.equiv          nb113_p_gbtabscale,     152
.equiv          nb113_GBtab,            160
.equiv          nb113_p_nthreads,       168
.equiv          nb113_count,            176
.equiv          nb113_mtx,              184
.equiv          nb113_outeriter,        192
.equiv          nb113_inneriter,        200
.equiv          nb113_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb113_ixO,              0
.equiv          nb113_iyO,              16
.equiv          nb113_izO,              32
.equiv          nb113_ixH1,             48
.equiv          nb113_iyH1,             64
.equiv          nb113_izH1,             80
.equiv          nb113_ixH2,             96
.equiv          nb113_iyH2,             112
.equiv          nb113_izH2,             128
.equiv          nb113_ixM,              144
.equiv          nb113_iyM,              160
.equiv          nb113_izM,              176
.equiv          nb113_iqH,              192
.equiv          nb113_iqM,              208
.equiv          nb113_dxO,              224
.equiv          nb113_dyO,              240
.equiv          nb113_dzO,              256
.equiv          nb113_dxH1,             272
.equiv          nb113_dyH1,             288
.equiv          nb113_dzH1,             304
.equiv          nb113_dxH2,             320
.equiv          nb113_dyH2,             336
.equiv          nb113_dzH2,             352
.equiv          nb113_dxM,              368
.equiv          nb113_dyM,              384
.equiv          nb113_dzM,              400
.equiv          nb113_qqH,              416
.equiv          nb113_qqM,              432
.equiv          nb113_c6,               448
.equiv          nb113_c12,              464
.equiv          nb113_six,              480
.equiv          nb113_twelve,           496
.equiv          nb113_vctot,            512
.equiv          nb113_Vvdwtot,          528
.equiv          nb113_fixO,             544
.equiv          nb113_fiyO,             560
.equiv          nb113_fizO,             576
.equiv          nb113_fixH1,            592
.equiv          nb113_fiyH1,            608
.equiv          nb113_fizH1,            624
.equiv          nb113_fixH2,            640
.equiv          nb113_fiyH2,            656
.equiv          nb113_fizH2,            672
.equiv          nb113_fixM,             688
.equiv          nb113_fiyM,             704
.equiv          nb113_fizM,             720
.equiv          nb113_fjx,              736
.equiv          nb113_fjy,              752
.equiv          nb113_fjz,              768
.equiv          nb113_half,             784
.equiv          nb113_three,            800
.equiv          nb113_two,              816
.equiv          nb113_rinvH1,           832
.equiv          nb113_rinvH2,           848
.equiv          nb113_rinvM,            864
.equiv          nb113_nri,              880
.equiv          nb113_iinr,             888
.equiv          nb113_jindex,           896
.equiv          nb113_jjnr,             904
.equiv          nb113_shift,            912
.equiv          nb113_shiftvec,         920
.equiv          nb113_facel,            928
.equiv          nb113_innerjjnr,        936
.equiv          nb113_is3,              944
.equiv          nb113_ii3,              948
.equiv          nb113_ntia,             952
.equiv          nb113_innerk,           956
.equiv          nb113_n,                960
.equiv          nb113_nn1,              964
.equiv          nb113_nouter,           968
.equiv          nb113_ninner,           972
	push rbp
	mov  rbp, rsp
	push rbx
	
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 984		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb113_nouter], eax
	mov [rsp + nb113_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb113_nri], edi
	mov [rsp + nb113_iinr], rsi
	mov [rsp + nb113_jindex], rdx
	mov [rsp + nb113_jjnr], rcx
	mov [rsp + nb113_shift], r8
	mov [rsp + nb113_shiftvec], r9
	mov rsi, [rbp + nb113_p_facel]
	movsd xmm0, [rsi]
	movsd [rsp + nb113_facel], xmm0

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double half IEEE (hex)
	mov ebx, 0x3fe00000     ;# upper half of half
	mov [rsp + nb113_half], eax
	mov [rsp + nb113_half+4], ebx
	movsd xmm1, [rsp + nb113_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# one
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# two
	addpd  xmm3, xmm2	;# three
	movapd xmm4, xmm3
	addpd  xmm4, xmm4       ;# six
	movapd xmm5, xmm4
	addpd  xmm5, xmm5       ;# twelve
	movapd [rsp + nb113_half], xmm1
	movapd [rsp + nb113_two], xmm2
	movapd [rsp + nb113_three], xmm3
	movapd [rsp + nb113_six], xmm4
	movapd [rsp + nb113_twelve], xmm5

	;# assume we have at least one i particle - start directly 
	mov   rcx, [rsp + nb113_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx]	    ;# ebx =ii 

	mov   rdx, [rbp + nb113_charge]
	movsd xmm3, [rdx + rbx*8 + 8]	
	movsd xmm4, [rdx + rbx*8 + 24]	
	mov rsi, [rbp + nb113_p_facel]
	movsd xmm0, [rsi]
	movsd xmm5, [rsp + nb113_facel]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [rsp + nb113_iqH], xmm3
	movapd [rsp + nb113_iqM], xmm4
	
	mov   rdx, [rbp + nb113_type]
	mov   ecx, [rdx + rbx*4]
	shl   ecx, 1
	mov rdi, [rbp + nb113_p_ntype]
	imul  ecx, [rdi]      ;# rcx = ntia = 2*ntype*type[ii0] 
	mov   [rsp + nb113_ntia], ecx		
.nb113_threadloop:
        mov   rsi, [rbp + nb113_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb113_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb113_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb113_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb113_n], eax
        mov [rsp + nb113_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb113_outerstart
        jmp .nb113_end

.nb113_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb113_nouter]
	mov [rsp + nb113_nouter], ebx

.nb113_outer:
	mov   rax, [rsp + nb113_shift]      ;# rax = pointer into shift[] 
	mov   ebx, [rax+rsi*4]		;# rbx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb113_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb113_shiftvec]   ;# rax = base of shiftvec[] 

	movsd xmm0, [rax + rbx*8]
	movsd xmm1, [rax + rbx*8 + 8]
	movsd xmm2, [rax + rbx*8 + 16] 

	mov   rcx, [rsp + nb113_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx+rsi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2
	movapd xmm6, xmm0
	movapd xmm7, xmm1

	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb113_pos]    ;# rax = base of pos[]  
	mov   [rsp + nb113_ii3], ebx

	addsd xmm3, [rax + rbx*8] 	;# ox
	addsd xmm4, [rax + rbx*8 + 8] 	;# oy
	addsd xmm5, [rax + rbx*8 + 16]	;# oz	
	addsd xmm6, [rax + rbx*8 + 24] 	;# h1x
	addsd xmm7, [rax + rbx*8 + 32] 	;# h1y
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	shufpd xmm7, xmm7, 0
	movapd [rsp + nb113_ixO], xmm3
	movapd [rsp + nb113_iyO], xmm4
	movapd [rsp + nb113_izO], xmm5
	movapd [rsp + nb113_ixH1], xmm6
	movapd [rsp + nb113_iyH1], xmm7

	movsd xmm6, xmm2
	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm6, [rax + rbx*8 + 40] ;# h1z
	addsd xmm0, [rax + rbx*8 + 48] ;# h2x
	addsd xmm1, [rax + rbx*8 + 56] ;# h2y
	addsd xmm2, [rax + rbx*8 + 64] ;# h2z
	addsd xmm3, [rax + rbx*8 + 72] ;# mx
	addsd xmm4, [rax + rbx*8 + 80] ;# my
	addsd xmm5, [rax + rbx*8 + 88] ;# mz

	shufpd xmm6, xmm6, 0
	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb113_izH1], xmm6
	movapd [rsp + nb113_ixH2], xmm0
	movapd [rsp + nb113_iyH2], xmm1
	movapd [rsp + nb113_izH2], xmm2
	movapd [rsp + nb113_ixM], xmm3
	movapd [rsp + nb113_iyM], xmm4
	movapd [rsp + nb113_izM], xmm5

	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [rsp + nb113_vctot], xmm4
	movapd [rsp + nb113_Vvdwtot], xmm4
	movapd [rsp + nb113_fixO], xmm4
	movapd [rsp + nb113_fiyO], xmm4
	movapd [rsp + nb113_fizO], xmm4
	movapd [rsp + nb113_fixH1], xmm4
	movapd [rsp + nb113_fiyH1], xmm4
	movapd [rsp + nb113_fizH1], xmm4
	movapd [rsp + nb113_fixH2], xmm4
	movapd [rsp + nb113_fiyH2], xmm4
	movapd [rsp + nb113_fizH2], xmm4
	movapd [rsp + nb113_fixM], xmm4
	movapd [rsp + nb113_fiyM], xmm4
	movapd [rsp + nb113_fizM], xmm4
	
	mov   rax, [rsp + nb113_jindex]
	mov   ecx, [rax + rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rsi, [rbp + nb113_pos]
	mov   rdi, [rbp + nb113_faction]	
	mov   rax, [rsp + nb113_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb113_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [rsp + nb113_ninner]
	mov   [rsp + nb113_ninner], ecx
	add   edx, 0
	mov   [rsp + nb113_innerk], edx    ;# number of innerloop atoms 
	jge   .nb113_unroll_loop
	jmp   .nb113_checksingle
.nb113_unroll_loop:
	;# twice unrolled innerloop here 
	mov   rdx, [rsp + nb113_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]

	add qword ptr [rsp + nb113_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov rsi, [rbp + nb113_charge]    ;# base of charge[] 
	
	movlpd xmm3, [rsi + rax*8]
	movhpd xmm3, [rsi + rbx*8]
	movapd xmm4, xmm3
	mulpd  xmm3, [rsp + nb113_iqM]
	mulpd  xmm4, [rsp + nb113_iqH]

	movapd  [rsp + nb113_qqM], xmm3
	movapd  [rsp + nb113_qqH], xmm4
	
	mov rsi, [rbp + nb113_type]
	mov r8d, [rsi + rax*4]
	mov r9d, [rsi + rbx*4]
	mov rsi, [rbp + nb113_vdwparam]
	shl r8d, 1	
	shl r9d, 1	
	mov edi, [rsp + nb113_ntia]
	add r8d, edi
	add r9d, edi

	movlpd xmm6, [rsi + r8*8]	;# c6a c6b
	movhpd xmm6, [rsi + r9*8]	;# 
	movlpd xmm7, [rsi + r8*8 + 8]	;# c12a c12b 
	movhpd xmm7, [rsi + r9*8 + 8]	;# 
	
	movapd [rsp + nb113_c6], xmm6
	movapd [rsp + nb113_c12], xmm7
	
	mov rsi, [rbp + nb113_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	

	;# move j coordinates to local temp variables 
    movlpd xmm0, [rsi + rax*8] 
    movlpd xmm1, [rsi + rax*8 + 8] 
    movlpd xmm2, [rsi + rax*8 + 16] 
    movhpd xmm0, [rsi + rbx*8] 
    movhpd xmm1, [rsi + rbx*8 + 8] 
    movhpd xmm2, [rsi + rbx*8 + 16] 

    ;# xmm0 = jx
    ;# xmm1 = jy
    ;# xmm2 = jz
    
    ;# O interaction
    ;# copy to xmm3-xmm5
    movapd xmm3, xmm0
    movapd xmm4, xmm1
    movapd xmm5, xmm2
    
    subpd xmm3, [rsp + nb113_ixO]
    subpd xmm4, [rsp + nb113_iyO]
    subpd xmm5, [rsp + nb113_izO]
    
    movapd xmm13, xmm3
    movapd xmm14, xmm4
    movapd xmm15, xmm5
    
	mulpd  xmm3, xmm3
	mulpd  xmm4, xmm4
	mulpd  xmm5, xmm5

	addpd  xmm3, xmm4
	addpd  xmm3, xmm5

    ;# calc 1/rsq
    cvtpd2ps xmm6, xmm3    
    rcpps xmm6, xmm6
    cvtps2pd xmm6, xmm6     ;# lu in low xmm6 
        
    ;# 1/x lookup seed in xmm6 
    movapd xmm4, [rsp + nb113_two]
    movapd xmm5, xmm3       ;# rsq
    mulpd xmm3, xmm6        ;# lu*rsq 
    subpd xmm4, xmm3        ;# 2-lu*rsq 
    mulpd xmm6, xmm4        ;# (new lu) 
        
    movapd xmm4, [rsp + nb113_two]
    mulpd xmm5, xmm6        ;# lu*rsq 
    subpd xmm4, xmm5        ;# 2-lu*rsq 
    mulpd xmm4, xmm6        ;# xmm4=rinvsq 

    movapd xmm3, xmm4       ;# rinvsq
    mulpd  xmm4, xmm4       ;# rinv4
    mulpd  xmm4, xmm3       ;# rinv6
    movapd xmm5, xmm4     
    mulpd  xmm5, xmm5       ;# rinv12
    mulpd  xmm4, [rsp + nb113_c6]
    mulpd  xmm5, [rsp + nb113_c12]
    movapd xmm6, xmm5
    subpd  xmm6, xmm4  ;# Vvdw=vvdw12-vvdw6
    mulpd  xmm4, [rsp + nb113_six]
    mulpd  xmm5, [rsp + nb113_twelve]
    subpd  xmm5, xmm4
    mulpd  xmm3, xmm5   ;# fscal
    
    addpd  xmm6, [rsp + nb113_Vvdwtot]
    movapd [rsp + nb113_Vvdwtot], xmm6
    
    mulpd  xmm13, xmm3 ;# fx
    mulpd  xmm14, xmm3 ;# fy
    mulpd  xmm15, xmm3 ;# fz

    ;# save j force temporarily
    movapd [rsp + nb113_fjx], xmm13
    movapd [rsp + nb113_fjy], xmm14
    movapd [rsp + nb113_fjz], xmm15
    
    ;# increment i O force
    addpd xmm13, [rsp + nb113_fixO]
    addpd xmm14, [rsp + nb113_fiyO]
    addpd xmm15, [rsp + nb113_fizO]
    movapd [rsp + nb113_fixO], xmm13
    movapd [rsp + nb113_fiyO], xmm14
    movapd [rsp + nb113_fizO], xmm15    
    ;# finished O LJ interaction.


    ;# do H1, H2, and M interactions in parallel.
    ;# xmm0-xmm2 still contain j coordinates.        
    movapd xmm3, xmm0
    movapd xmm4, xmm1
    movapd xmm5, xmm2
    movapd xmm6, xmm0
    movapd xmm7, xmm1
    movapd xmm8, xmm2
    
    subpd xmm0, [rsp + nb113_ixH1]
    subpd xmm1, [rsp + nb113_iyH1]
    subpd xmm2, [rsp + nb113_izH1]
    subpd xmm3, [rsp + nb113_ixH2]
    subpd xmm4, [rsp + nb113_iyH2]
    subpd xmm5, [rsp + nb113_izH2]
    subpd xmm6, [rsp + nb113_ixM]
    subpd xmm7, [rsp + nb113_iyM]
    subpd xmm8, [rsp + nb113_izM]
    
	movapd [rsp + nb113_dxH1], xmm0
	movapd [rsp + nb113_dyH1], xmm1
	movapd [rsp + nb113_dzH1], xmm2
	mulpd  xmm0, xmm0
	mulpd  xmm1, xmm1