nb_kernel333_x86_64_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,340 行 · 第 1/5 页

;#
;# $Id: nb_kernel333_x86_64_sse2.intel_syntax.s,v 1.1.2.2 2006/09/22 08:40:37 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as






.globl nb_kernel333_x86_64_sse2
.globl _nb_kernel333_x86_64_sse2
nb_kernel333_x86_64_sse2:	
_nb_kernel333_x86_64_sse2:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb333_fshift,           16
.equiv          nb333_gid,              24
.equiv          nb333_pos,              32
.equiv          nb333_faction,          40
.equiv          nb333_charge,           48
.equiv          nb333_p_facel,          56
.equiv          nb333_argkrf,           64
.equiv          nb333_argcrf,           72
.equiv          nb333_Vc,               80
.equiv          nb333_type,             88
.equiv          nb333_p_ntype,          96
.equiv          nb333_vdwparam,         104
.equiv          nb333_Vvdw,             112
.equiv          nb333_p_tabscale,       120
.equiv          nb333_VFtab,            128
.equiv          nb333_invsqrta,         136
.equiv          nb333_dvda,             144
.equiv          nb333_p_gbtabscale,     152
.equiv          nb333_GBtab,            160
.equiv          nb333_p_nthreads,       168
.equiv          nb333_count,            176
.equiv          nb333_mtx,              184
.equiv          nb333_outeriter,        192
.equiv          nb333_inneriter,        200
.equiv          nb333_work,             208
	;# stack offsets for local variables 
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb333_ixO,              0
.equiv          nb333_iyO,              16
.equiv          nb333_izO,              32
.equiv          nb333_ixH1,             48
.equiv          nb333_iyH1,             64
.equiv          nb333_izH1,             80
.equiv          nb333_ixH2,             96
.equiv          nb333_iyH2,             112
.equiv          nb333_izH2,             128
.equiv          nb333_ixM,              144
.equiv          nb333_iyM,              160
.equiv          nb333_izM,              176
.equiv          nb333_iqM,              192
.equiv          nb333_iqH,              208
.equiv          nb333_dxO,              224
.equiv          nb333_dyO,              240
.equiv          nb333_dzO,              256
.equiv          nb333_dxH1,             272
.equiv          nb333_dyH1,             288
.equiv          nb333_dzH1,             304
.equiv          nb333_dxH2,             320
.equiv          nb333_dyH2,             336
.equiv          nb333_dzH2,             352
.equiv          nb333_dxM,              368
.equiv          nb333_dyM,              384
.equiv          nb333_dzM,              400
.equiv          nb333_qqM,              416
.equiv          nb333_qqH,              432
.equiv          nb333_rinvO,            448
.equiv          nb333_rinvH1,           464
.equiv          nb333_rinvH2,           480
.equiv          nb333_rinvM,            496
.equiv          nb333_rO,               512
.equiv          nb333_rH1,              528
.equiv          nb333_rH2,              544
.equiv          nb333_rM,               560
.equiv          nb333_tsc,              576
.equiv          nb333_two,              592
.equiv          nb333_c6,               608
.equiv          nb333_c12,              624
.equiv          nb333_vctot,            640
.equiv          nb333_Vvdwtot,          656
.equiv          nb333_fixO,             672
.equiv          nb333_fiyO,             688
.equiv          nb333_fizO,             704
.equiv          nb333_fixH1,            720
.equiv          nb333_fiyH1,            736
.equiv          nb333_fizH1,            752
.equiv          nb333_fixH2,            768
.equiv          nb333_fiyH2,            784
.equiv          nb333_fizH2,            800
.equiv          nb333_fixM,             816
.equiv          nb333_fiyM,             832
.equiv          nb333_fizM,             848
.equiv          nb333_fjx,              864
.equiv          nb333_fjy,              880
.equiv          nb333_fjz,              896
.equiv          nb333_half,             912
.equiv          nb333_three,            928
.equiv          nb333_is3,              944
.equiv          nb333_ii3,              948
.equiv          nb333_nri,              952
.equiv          nb333_iinr,             960
.equiv          nb333_jindex,           968
.equiv          nb333_jjnr,             976
.equiv          nb333_shift,            984
.equiv          nb333_shiftvec,         992
.equiv          nb333_facel,            1000
.equiv          nb333_innerjjnr,        1008
.equiv          nb333_ntia,             1016
.equiv          nb333_innerk,           1020
.equiv          nb333_n,                1024
.equiv          nb333_nn1,              1028
.equiv          nb333_nouter,           1032
.equiv          nb333_ninner,           1036
	push rbp
	mov  rbp, rsp
	push rbx
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 1048		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb333_nouter], eax
	mov [rsp + nb333_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb333_nri], edi
	mov [rsp + nb333_iinr], rsi
	mov [rsp + nb333_jindex], rdx
	mov [rsp + nb333_jjnr], rcx
	mov [rsp + nb333_shift], r8
	mov [rsp + nb333_shiftvec], r9
	mov rsi, [rbp + nb333_p_facel]
	movsd xmm0, [rsi]
	movsd [rsp + nb333_facel], xmm0

	mov rax, [rbp + nb333_p_tabscale]
	movsd xmm3, [rax]
	shufpd xmm3, xmm3, 0
	movapd [rsp + nb333_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double half IEEE (hex)
	mov ebx, 0x3fe00000
	mov [rsp + nb333_half], eax
	mov [rsp + nb333_half+4], ebx
	movsd xmm1, [rsp + nb333_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# one
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# two
	addpd  xmm3, xmm2	;# three
	movapd [rsp + nb333_half], xmm1
	movapd [rsp + nb333_two], xmm2
	movapd [rsp + nb333_three], xmm3

	;# assume we have at least one i particle - start directly 
	mov   rcx, [rsp + nb333_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx]	    ;# ebx =ii 

	mov   rdx, [rbp + nb333_charge]
	movsd xmm3, [rdx + rbx*8 + 8]	
	movsd xmm4, [rdx + rbx*8 + 24]	
	mov rsi, [rbp + nb333_p_facel]
	movsd xmm0, [rsi]
	movsd xmm5, [rsp + nb333_facel]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [rsp + nb333_iqH], xmm3
	movapd [rsp + nb333_iqM], xmm4
	
	mov   rdx, [rbp + nb333_type]
	mov   ecx, [rdx + rbx*4]
	shl   ecx, 1
	mov rdi, [rbp + nb333_p_ntype]
	imul  ecx, [rdi]      ;# rcx = ntia = 2*ntype*type[ii0] 
	mov   [rsp + nb333_ntia], ecx		
.nb333_threadloop:
        mov   rsi, [rbp + nb333_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb333_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb333_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb333_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb333_n], eax
        mov [rsp + nb333_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb333_outerstart
        jmp .nb333_end

.nb333_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb333_nouter]
	mov [rsp + nb333_nouter], ebx

.nb333_outer:
	mov   rax, [rsp + nb333_shift]      ;# rax = pointer into shift[] 
	mov   ebx, [rax+rsi*4]		;# rbx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb333_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb333_shiftvec]   ;# rax = base of shiftvec[] 

	movsd xmm0, [rax + rbx*8]
	movsd xmm1, [rax + rbx*8 + 8]
	movsd xmm2, [rax + rbx*8 + 16] 

	mov   rcx, [rsp + nb333_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx+rsi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2
	movapd xmm6, xmm0
	movapd xmm7, xmm1

	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb333_pos]    ;# rax = base of pos[]  
	mov   [rsp + nb333_ii3], ebx

	addsd xmm3, [rax + rbx*8] 	;# ox
	addsd xmm4, [rax + rbx*8 + 8] 	;# oy
	addsd xmm5, [rax + rbx*8 + 16]	;# oz	
	addsd xmm6, [rax + rbx*8 + 24] 	;# h1x
	addsd xmm7, [rax + rbx*8 + 32] 	;# h1y
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	shufpd xmm7, xmm7, 0
	movapd [rsp + nb333_ixO], xmm3
	movapd [rsp + nb333_iyO], xmm4
	movapd [rsp + nb333_izO], xmm5
	movapd [rsp + nb333_ixH1], xmm6
	movapd [rsp + nb333_iyH1], xmm7

	movsd xmm6, xmm2
	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm6, [rax + rbx*8 + 40] ;# h1z
	addsd xmm0, [rax + rbx*8 + 48] ;# h2x
	addsd xmm1, [rax + rbx*8 + 56] ;# h2y
	addsd xmm2, [rax + rbx*8 + 64] ;# h2z
	addsd xmm3, [rax + rbx*8 + 72] ;# mx
	addsd xmm4, [rax + rbx*8 + 80] ;# my
	addsd xmm5, [rax + rbx*8 + 88] ;# mz

	shufpd xmm6, xmm6, 0
	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb333_izH1], xmm6
	movapd [rsp + nb333_ixH2], xmm0
	movapd [rsp + nb333_iyH2], xmm1
	movapd [rsp + nb333_izH2], xmm2
	movapd [rsp + nb333_ixM], xmm3
	movapd [rsp + nb333_iyM], xmm4
	movapd [rsp + nb333_izM], xmm5
	
	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [rsp + nb333_vctot], xmm4
	movapd [rsp + nb333_Vvdwtot], xmm4
	movapd [rsp + nb333_fixO], xmm4
	movapd [rsp + nb333_fiyO], xmm4
	movapd [rsp + nb333_fizO], xmm4
	movapd [rsp + nb333_fixH1], xmm4
	movapd [rsp + nb333_fiyH1], xmm4
	movapd [rsp + nb333_fizH1], xmm4
	movapd [rsp + nb333_fixH2], xmm4
	movapd [rsp + nb333_fiyH2], xmm4
	movapd [rsp + nb333_fizH2], xmm4
	movapd [rsp + nb333_fixM], xmm4
	movapd [rsp + nb333_fiyM], xmm4
	movapd [rsp + nb333_fizM], xmm4
	
	mov   rax, [rsp + nb333_jindex]
	mov   ecx, [rax+rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rsi, [rbp + nb333_pos]
	mov   rdi, [rbp + nb333_faction]	
	mov   rax, [rsp + nb333_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb333_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [rsp + nb333_ninner]
	mov   [rsp + nb333_ninner], ecx
	add   edx, 0
	mov   [rsp + nb333_innerk], edx    ;# number of innerloop atoms 
	jge   .nb333_unroll_loop
	jmp   .nb333_checksingle
.nb333_unroll_loop:
	;# twice unrolled innerloop here 
	mov   rdx, [rsp + nb333_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]
	
	add qword ptr [rsp + nb333_innerjjnr],  8 ;# advance pointer (unrolled 2) 

	mov rsi, [rbp + nb333_charge]    ;# base of charge[] 
	
	movlpd xmm3, [rsi + rax*8]
	movhpd xmm3, [rsi + rbx*8]
	movapd xmm4, xmm3	     
	mulpd  xmm3, [rsp + nb333_iqM]
	mulpd  xmm4, [rsp + nb333_iqH]
	movapd  [rsp + nb333_qqM], xmm3
	movapd  [rsp + nb333_qqH], xmm4	

	mov rsi, [rbp + nb333_type]
	mov r8d, [rsi + rax*4]
	mov r9d, [rsi + rbx*4]
	mov rsi, [rbp + nb333_vdwparam]
	shl r8d, 1	
	shl r9d, 1	
	mov edi, [rsp + nb333_ntia]
	add r8d, edi
	add r9d, edi

	movlpd xmm6, [rsi + r8*8]	;# c6a
	movlpd xmm7, [rsi + r9*8]	;# c6b
	movhpd xmm6, [rsi + r8*8 + 8]	;# c6a c12a 
	movhpd xmm7, [rsi + r9*8 + 8]	;# c6b c12b 
	movapd xmm4, xmm6
	unpcklpd xmm4, xmm7
	unpckhpd xmm6, xmm7
	
	movapd [rsp + nb333_c6], xmm4
	movapd [rsp + nb333_c12], xmm6

	mov rsi, [rbp + nb333_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	

	;# move j coordinates to local temp variables 
    movlpd xmm0, [rsi + rax*8] 
    movlpd xmm1, [rsi + rax*8 + 8] 
    movlpd xmm2, [rsi + rax*8 + 16] 
    movhpd xmm0, [rsi + rbx*8] 
    movhpd xmm1, [rsi + rbx*8 + 8] 
    movhpd xmm2, [rsi + rbx*8 + 16] 

    ;# xmm0 = jx
    ;# xmm1 = jy
    ;# xmm2 = jz
        
    ;# O interaction
    ;# copy to xmm3-xmm5
    movapd xmm3, xmm0
    movapd xmm4, xmm1
    movapd xmm5, xmm2
    
    subpd xmm3, [rsp + nb333_ixO]
    subpd xmm4, [rsp + nb333_iyO]
    subpd xmm5, [rsp + nb333_izO]
    
    movapd [rsp + nb333_dxO], xmm3
    movapd [rsp + nb333_dyO], xmm4
    movapd [rsp + nb333_dzO], xmm5
    
	mulpd  xmm3, xmm3
	mulpd  xmm4, xmm4
	mulpd  xmm5, xmm5

	addpd  xmm3, xmm4
	addpd  xmm3, xmm5
    ;# xmm3=rsq

    cvtpd2ps xmm5, xmm3     
    rsqrtps xmm5, xmm5
    cvtps2pd xmm15, xmm5     ;# lu in low xmm2 

    ;# lookup seed in xmm2 
    movapd xmm5, xmm15       ;# copy of lu 
    mulpd xmm15, xmm15        ;# lu*lu 
    movapd xmm7, [rsp + nb333_three]
    mulpd xmm15, xmm3        ;# rsq*lu*lu                    
    movapd xmm6, [rsp + nb333_half]
    subpd xmm7, xmm15        ;# 30-rsq*lu*lu 
    mulpd xmm7, xmm5        
    mulpd xmm7, xmm6        ;# xmm0=iter1 of rinv (new lu) 

    movapd xmm5, xmm7       ;# copy of lu 
    mulpd xmm7, xmm7        ;# lu*lu 
    movapd xmm15, [rsp + nb333_three]
    mulpd xmm7, xmm3        ;# rsq*lu*lu                    
    movapd xmm6, [rsp + nb333_half]
    subpd xmm15, xmm7        ;# 30-rsq*lu*lu 
    mulpd xmm15, xmm5        
    mulpd xmm15, xmm6        ;# xmm15=rinv