nb_kernel201_x86_64_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,738 行 · 第 1/4 页

;#
;# $Id: nb_kernel201_x86_64_sse2.intel_syntax.s,v 1.1.2.2 2006/09/22 08:40:33 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as



	

.globl nb_kernel201_x86_64_sse2
.globl _nb_kernel201_x86_64_sse2
nb_kernel201_x86_64_sse2:	
_nb_kernel201_x86_64_sse2:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb201_fshift,           16
.equiv          nb201_gid,              24
.equiv          nb201_pos,              32
.equiv          nb201_faction,          40
.equiv          nb201_charge,           48
.equiv          nb201_p_facel,          56
.equiv          nb201_argkrf,           64
.equiv          nb201_argcrf,           72
.equiv          nb201_Vc,               80
.equiv          nb201_type,             88
.equiv          nb201_p_ntype,          96
.equiv          nb201_vdwparam,         104
.equiv          nb201_Vvdw,             112
.equiv          nb201_p_tabscale,       120
.equiv          nb201_VFtab,            128
.equiv          nb201_invsqrta,         136
.equiv          nb201_dvda,             144
.equiv          nb201_p_gbtabscale,     152
.equiv          nb201_GBtab,            160
.equiv          nb201_p_nthreads,       168
.equiv          nb201_count,            176
.equiv          nb201_mtx,              184
.equiv          nb201_outeriter,        192
.equiv          nb201_inneriter,        200
.equiv          nb201_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb201_ixO,              0
.equiv          nb201_iyO,              16
.equiv          nb201_izO,              32
.equiv          nb201_ixH1,             48
.equiv          nb201_iyH1,             64
.equiv          nb201_izH1,             80
.equiv          nb201_ixH2,             96
.equiv          nb201_iyH2,             112
.equiv          nb201_izH2,             128
.equiv          nb201_iqO,              144
.equiv          nb201_iqH,              160
.equiv          nb201_dxO,              176
.equiv          nb201_dyO,              192
.equiv          nb201_dzO,              208
.equiv          nb201_dxH1,             224
.equiv          nb201_dyH1,             240
.equiv          nb201_dzH1,             256
.equiv          nb201_dxH2,             272
.equiv          nb201_dyH2,             288
.equiv          nb201_dzH2,             304
.equiv          nb201_qqO,              320
.equiv          nb201_qqH,              336
.equiv          nb201_vctot,            352
.equiv          nb201_fixO,             384
.equiv          nb201_fiyO,             400
.equiv          nb201_fizO,             416
.equiv          nb201_fixH1,            432
.equiv          nb201_fiyH1,            448
.equiv          nb201_fizH1,            464
.equiv          nb201_fixH2,            480
.equiv          nb201_fiyH2,            496
.equiv          nb201_fizH2,            512
.equiv          nb201_fjx,              528
.equiv          nb201_fjy,              544
.equiv          nb201_fjz,              560
.equiv          nb201_half,             576
.equiv          nb201_three,            592
.equiv          nb201_two,              608
.equiv          nb201_krf,              624
.equiv          nb201_crf,              640
.equiv          nb201_krsqO,            656
.equiv          nb201_krsqH1,           672
.equiv          nb201_krsqH2,           688
.equiv          nb201_nri,              704
.equiv          nb201_iinr,             712
.equiv          nb201_jindex,           720
.equiv          nb201_jjnr,             728
.equiv          nb201_shift,            736
.equiv          nb201_shiftvec,         744
.equiv          nb201_facel,            752
.equiv          nb201_innerjjnr,        760
.equiv          nb201_is3,              768
.equiv          nb201_ii3,              772
.equiv          nb201_innerk,           776
.equiv          nb201_n,                780
.equiv          nb201_nn1,              784
.equiv          nb201_nouter,           788
.equiv          nb201_ninner,           792
	push rbp
	mov  rbp, rsp
	push rbx
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 808		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb201_nouter], eax
	mov [rsp + nb201_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb201_nri], edi
	mov [rsp + nb201_iinr], rsi
	mov [rsp + nb201_jindex], rdx
	mov [rsp + nb201_jjnr], rcx
	mov [rsp + nb201_shift], r8
	mov [rsp + nb201_shiftvec], r9
	mov rsi, [rbp + nb201_p_facel]
	movsd xmm0, [rsi]
	movsd [rsp + nb201_facel], xmm0

	mov rsi, [rbp + nb201_argkrf]
	mov rdi, [rbp + nb201_argcrf]
	movsd xmm1, [rsi]
	movsd xmm2, [rdi]
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	movapd [rsp + nb201_krf], xmm1
	movapd [rsp + nb201_crf], xmm2

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double half IEEE (hex)
	mov ebx, 0x3fe00000
	mov [rsp + nb201_half], eax
	mov [rsp + nb201_half+4], ebx
	movsd xmm1, [rsp + nb201_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# one
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# two
	addpd  xmm3, xmm2	;# three
	movapd [rsp + nb201_half], xmm1
	movapd [rsp + nb201_two], xmm2
	movapd [rsp + nb201_three], xmm3

	;# assume we have at least one i particle - start directly 
	mov   rcx, [rsp + nb201_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx]	    ;# ebx =ii 

	mov   rdx, [rbp + nb201_charge]
	movsd xmm3, [rdx + rbx*8]	
	movsd xmm4, [rdx + rbx*8 + 8]	

	movsd xmm5, [rsp + nb201_facel]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [rsp + nb201_iqO], xmm3
	movapd [rsp + nb201_iqH], xmm4
	
.nb201_threadloop:
        mov   rsi, [rbp + nb201_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb201_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb201_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb201_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb201_n], eax
        mov [rsp + nb201_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb201_outerstart
        jmp .nb201_end

.nb201_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb201_nouter]
	mov [rsp + nb201_nouter], ebx

.nb201_outer:
	mov   rax, [rsp + nb201_shift]      ;# rax = pointer into shift[] 
	mov   ebx, [rax + rsi*4]		;# rbx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb201_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb201_shiftvec]   ;# rax = base of shiftvec[] 

	movsd xmm0, [rax + rbx*8]
	movsd xmm1, [rax + rbx*8 + 8]
	movsd xmm2, [rax + rbx*8 + 16] 

	mov   rcx, [rsp + nb201_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx+rsi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2

	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb201_pos]    ;# rax = base of pos[]  
	mov   [rsp + nb201_ii3], ebx

	addsd xmm3, [rax + rbx*8]
	addsd xmm4, [rax + rbx*8 + 8]
	addsd xmm5, [rax + rbx*8 + 16]		
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb201_ixO], xmm3
	movapd [rsp + nb201_iyO], xmm4
	movapd [rsp + nb201_izO], xmm5

	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm0, [rax + rbx*8 + 24]
	addsd xmm1, [rax + rbx*8 + 32]
	addsd xmm2, [rax + rbx*8 + 40]		
	addsd xmm3, [rax + rbx*8 + 48]
	addsd xmm4, [rax + rbx*8 + 56]
	addsd xmm5, [rax + rbx*8 + 64]		

	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb201_ixH1], xmm0
	movapd [rsp + nb201_iyH1], xmm1
	movapd [rsp + nb201_izH1], xmm2
	movapd [rsp + nb201_ixH2], xmm3
	movapd [rsp + nb201_iyH2], xmm4
	movapd [rsp + nb201_izH2], xmm5
	
	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [rsp + nb201_vctot], xmm4
	movapd [rsp + nb201_fixO], xmm4
	movapd [rsp + nb201_fiyO], xmm4
	movapd [rsp + nb201_fizO], xmm4
	movapd [rsp + nb201_fixH1], xmm4
	movapd [rsp + nb201_fiyH1], xmm4
	movapd [rsp + nb201_fizH1], xmm4
	movapd [rsp + nb201_fixH2], xmm4
	movapd [rsp + nb201_fiyH2], xmm4
	movapd [rsp + nb201_fizH2], xmm4
	
	mov   rax, [rsp + nb201_jindex]
	mov   ecx, [rax + rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rsi, [rbp + nb201_pos]
	mov   rdi, [rbp + nb201_faction]	
	mov   rax, [rsp + nb201_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb201_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [rsp + nb201_ninner]
	mov   [rsp + nb201_ninner], ecx
	add   edx, 0
	mov   [rsp + nb201_innerk], edx    ;# number of innerloop atoms 
	jge   .nb201_unroll_loop
	jmp   .nb201_checksingle
.nb201_unroll_loop:
	;# twice unrolled innerloop here 
	mov   rdx, [rsp + nb201_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]

	add qword ptr [rsp + nb201_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov rsi, [rbp + nb201_charge]    ;# base of charge[] 
	
	movlpd xmm3, [rsi + rax*8]
	movhpd xmm3, [rsi + rbx*8]
	movapd xmm4, xmm3
	mulpd  xmm3, [rsp + nb201_iqO]
	mulpd  xmm4, [rsp + nb201_iqH]
	movapd  [rsp + nb201_qqO], xmm3
	movapd  [rsp + nb201_qqH], xmm4	

	mov rsi, [rbp + nb201_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	

	;# move j coordinates to local temp variables 
    movlpd xmm0, [rsi + rax*8] 
    movlpd xmm1, [rsi + rax*8 + 8] 
    movlpd xmm2, [rsi + rax*8 + 16] 
    movhpd xmm0, [rsi + rbx*8] 
    movhpd xmm1, [rsi + rbx*8 + 8] 
    movhpd xmm2, [rsi + rbx*8 + 16] 

    ;# xmm0 = jx
    ;# xmm1 = jy
    ;# xmm2 = jz
        
    movapd xmm3, xmm0
    movapd xmm4, xmm1
    movapd xmm5, xmm2
    movapd xmm6, xmm0
    movapd xmm7, xmm1
    movapd xmm8, xmm2
    
    subpd xmm0, [rsp + nb201_ixO]
    subpd xmm1, [rsp + nb201_iyO]
    subpd xmm2, [rsp + nb201_izO]
    subpd xmm3, [rsp + nb201_ixH1]
    subpd xmm4, [rsp + nb201_iyH1]
    subpd xmm5, [rsp + nb201_izH1]
    subpd xmm6, [rsp + nb201_ixH2]
    subpd xmm7, [rsp + nb201_iyH2]
    subpd xmm8, [rsp + nb201_izH2]
    
	movapd [rsp + nb201_dxO], xmm0
	movapd [rsp + nb201_dyO], xmm1
	movapd [rsp + nb201_dzO], xmm2
	mulpd  xmm0, xmm0
	mulpd  xmm1, xmm1
	mulpd  xmm2, xmm2
	movapd [rsp + nb201_dxH1], xmm3
	movapd [rsp + nb201_dyH1], xmm4
	movapd [rsp + nb201_dzH1], xmm5
	mulpd  xmm3, xmm3
	mulpd  xmm4, xmm4
	mulpd  xmm5, xmm5
	movapd [rsp + nb201_dxH2], xmm6
	movapd [rsp + nb201_dyH2], xmm7
	movapd [rsp + nb201_dzH2], xmm8
	mulpd  xmm6, xmm6
	mulpd  xmm7, xmm7
	mulpd  xmm8, xmm8
	addpd  xmm0, xmm1
	addpd  xmm0, xmm2
	addpd  xmm3, xmm4
	addpd  xmm3, xmm5
    addpd  xmm6, xmm7
    addpd  xmm6, xmm8

	;# start doing invsqrt for j atoms
    cvtpd2ps xmm1, xmm0
    cvtpd2ps xmm4, xmm3
    cvtpd2ps xmm7, xmm6
	rsqrtps xmm1, xmm1
	rsqrtps xmm4, xmm4
    rsqrtps xmm7, xmm7
    cvtps2pd xmm1, xmm1
    cvtps2pd xmm4, xmm4
    cvtps2pd xmm7, xmm7
	
	movapd  xmm2, xmm1
	movapd  xmm5, xmm4
    movapd  xmm8, xmm7
    
	mulpd   xmm1, xmm1 ;# lu*lu
	mulpd   xmm4, xmm4 ;# lu*lu
    mulpd   xmm7, xmm7 ;# lu*lu
		
	movapd  xmm9, [rsp + nb201_three]
	movapd  xmm10, xmm9
    movapd  xmm11, xmm9

	mulpd   xmm1, xmm0 ;# rsq*lu*lu
	mulpd   xmm4, xmm3 ;# rsq*lu*lu 
    mulpd   xmm7, xmm6 ;# rsq*lu*lu
	
	subpd   xmm9, xmm1