nb_kernel331_x86_64_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,353 行 · 第 1/5 页

;#
;# $Id: nb_kernel331_x86_64_sse2.intel_syntax.s,v 1.1.2.2 2006/09/22 08:40:37 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as






.globl nb_kernel331_x86_64_sse2
.globl _nb_kernel331_x86_64_sse2
nb_kernel331_x86_64_sse2:	
_nb_kernel331_x86_64_sse2:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb331_fshift,           16
.equiv          nb331_gid,              24
.equiv          nb331_pos,              32
.equiv          nb331_faction,          40
.equiv          nb331_charge,           48
.equiv          nb331_p_facel,          56
.equiv          nb331_argkrf,           64
.equiv          nb331_argcrf,           72
.equiv          nb331_Vc,               80
.equiv          nb331_type,             88
.equiv          nb331_p_ntype,          96
.equiv          nb331_vdwparam,         104
.equiv          nb331_Vvdw,             112
.equiv          nb331_p_tabscale,       120
.equiv          nb331_VFtab,            128
.equiv          nb331_invsqrta,         136
.equiv          nb331_dvda,             144
.equiv          nb331_p_gbtabscale,     152
.equiv          nb331_GBtab,            160
.equiv          nb331_p_nthreads,       168
.equiv          nb331_count,            176
.equiv          nb331_mtx,              184
.equiv          nb331_outeriter,        192
.equiv          nb331_inneriter,        200
.equiv          nb331_work,             208
	;# stack offsets for local variables 
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb331_ixO,              0
.equiv          nb331_iyO,              16
.equiv          nb331_izO,              32
.equiv          nb331_ixH1,             48
.equiv          nb331_iyH1,             64
.equiv          nb331_izH1,             80
.equiv          nb331_ixH2,             96
.equiv          nb331_iyH2,             112
.equiv          nb331_izH2,             128
.equiv          nb331_iqO,              144
.equiv          nb331_iqH,              160
.equiv          nb331_dxO,              176
.equiv          nb331_dyO,              192
.equiv          nb331_dzO,              208
.equiv          nb331_dxH1,             224
.equiv          nb331_dyH1,             240
.equiv          nb331_dzH1,             256
.equiv          nb331_dxH2,             272
.equiv          nb331_dyH2,             288
.equiv          nb331_dzH2,             304
.equiv          nb331_qqO,              320
.equiv          nb331_qqH,              336
.equiv          nb331_rinvO,            352
.equiv          nb331_rinvH1,           368
.equiv          nb331_rinvH2,           384
.equiv          nb331_rO,               400
.equiv          nb331_rH1,              416
.equiv          nb331_rH2,              432
.equiv          nb331_tsc,              448
.equiv          nb331_two,              464
.equiv          nb331_c6,               480
.equiv          nb331_c12,              496
.equiv          nb331_vctot,            512
.equiv          nb331_Vvdwtot,          528
.equiv          nb331_fixO,             544
.equiv          nb331_fiyO,             560
.equiv          nb331_fizO,             576
.equiv          nb331_fixH1,            592
.equiv          nb331_fiyH1,            608
.equiv          nb331_fizH1,            624
.equiv          nb331_fixH2,            640
.equiv          nb331_fiyH2,            656
.equiv          nb331_fizH2,            672
.equiv          nb331_fjx,              688
.equiv          nb331_fjy,              704
.equiv          nb331_fjz,              720
.equiv          nb331_half,             736
.equiv          nb331_three,            752
.equiv          nb331_is3,              768
.equiv          nb331_ii3,              772
.equiv          nb331_nri,              776
.equiv          nb331_iinr,             784
.equiv          nb331_jindex,           792
.equiv          nb331_jjnr,             800
.equiv          nb331_shift,            808
.equiv          nb331_shiftvec,         816
.equiv          nb331_facel,            824
.equiv          nb331_innerjjnr,        832
.equiv          nb331_ntia,             840
.equiv          nb331_innerk,           844
.equiv          nb331_n,                848
.equiv          nb331_nn1,              852
.equiv          nb331_nouter,           856
.equiv          nb331_ninner,           860
	push rbp
	mov  rbp, rsp
	push rbx
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 872		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb331_nouter], eax
	mov [rsp + nb331_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb331_nri], edi
	mov [rsp + nb331_iinr], rsi
	mov [rsp + nb331_jindex], rdx
	mov [rsp + nb331_jjnr], rcx
	mov [rsp + nb331_shift], r8
	mov [rsp + nb331_shiftvec], r9
	mov rsi, [rbp + nb331_p_facel]
	movsd xmm0, [rsi]
	movsd [rsp + nb331_facel], xmm0

	mov rax, [rbp + nb331_p_tabscale]
	movsd xmm3, [rax]
	shufpd xmm3, xmm3, 0
	movapd [rsp + nb331_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double half IEEE (hex)
	mov ebx, 0x3fe00000
	mov [rsp + nb331_half], eax
	mov [rsp + nb331_half+4], ebx
	movsd xmm1, [rsp + nb331_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# one
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# two
	addpd  xmm3, xmm2	;# three
	movapd [rsp + nb331_half], xmm1
	movapd [rsp + nb331_two], xmm2
	movapd [rsp + nb331_three], xmm3

	;# assume we have at least one i particle - start directly 
	mov   rcx, [rsp + nb331_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx]	    ;# ebx =ii 

	mov   rdx, [rbp + nb331_charge]
	movsd xmm3, [rdx + rbx*8]	
	movsd xmm4, [rdx + rbx*8 + 8]	
	movsd xmm5, [rsp + nb331_facel]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [rsp + nb331_iqO], xmm3
	movapd [rsp + nb331_iqH], xmm4
	
	mov   rdx, [rbp + nb331_type]
	mov   ecx, [rdx + rbx*4]
	shl   ecx, 1
	mov rdi, [rbp + nb331_p_ntype]
	imul  ecx, [rdi]      ;# rcx = ntia = 2*ntype*type[ii0] 
	mov   [rsp + nb331_ntia], ecx

.nb331_threadloop:
        mov   rsi, [rbp + nb331_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb331_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb331_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb331_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb331_n], eax
        mov [rsp + nb331_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb331_outerstart
	jmp .nb331_end
	
.nb331_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb331_nouter]
	mov [rsp + nb331_nouter], ebx

.nb331_outer:
	mov   rax, [rsp + nb331_shift]      ;# rax = pointer into shift[] 
	mov   ebx, [rax+rsi*4]		;# rbx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb331_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb331_shiftvec]   ;# rax = base of shiftvec[] 

	movsd xmm0, [rax + rbx*8]
	movsd xmm1, [rax + rbx*8 + 8]
	movsd xmm2, [rax + rbx*8 + 16] 

	mov   rcx, [rsp + nb331_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx+rsi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2

	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb331_pos]    ;# rax = base of pos[]  
	mov   [rsp + nb331_ii3], ebx

	addsd xmm3, [rax + rbx*8]
	addsd xmm4, [rax + rbx*8 + 8]
	addsd xmm5, [rax + rbx*8 + 16]		
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb331_ixO], xmm3
	movapd [rsp + nb331_iyO], xmm4
	movapd [rsp + nb331_izO], xmm5

	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm0, [rax + rbx*8 + 24]
	addsd xmm1, [rax + rbx*8 + 32]
	addsd xmm2, [rax + rbx*8 + 40]		
	addsd xmm3, [rax + rbx*8 + 48]
	addsd xmm4, [rax + rbx*8 + 56]
	addsd xmm5, [rax + rbx*8 + 64]		

	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb331_ixH1], xmm0
	movapd [rsp + nb331_iyH1], xmm1
	movapd [rsp + nb331_izH1], xmm2
	movapd [rsp + nb331_ixH2], xmm3
	movapd [rsp + nb331_iyH2], xmm4
	movapd [rsp + nb331_izH2], xmm5
	
	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [rsp + nb331_vctot], xmm4
	movapd [rsp + nb331_Vvdwtot], xmm4
	movapd [rsp + nb331_fixO], xmm4
	movapd [rsp + nb331_fiyO], xmm4
	movapd [rsp + nb331_fizO], xmm4
	movapd [rsp + nb331_fixH1], xmm4
	movapd [rsp + nb331_fiyH1], xmm4
	movapd [rsp + nb331_fizH1], xmm4
	movapd [rsp + nb331_fixH2], xmm4
	movapd [rsp + nb331_fiyH2], xmm4
	movapd [rsp + nb331_fizH2], xmm4
	
	mov   rax, [rsp + nb331_jindex]
	mov   ecx, [rax+rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rsi, [rbp + nb331_pos]
	mov   rdi, [rbp + nb331_faction]	
	mov   rax, [rsp + nb331_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb331_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [rsp + nb331_ninner]
	mov   [rsp + nb331_ninner], ecx
	add   edx, 0
	mov   [rsp + nb331_innerk], edx    ;# number of innerloop atoms 
	jge   .nb331_unroll_loop
	jmp   .nb331_checksingle
.nb331_unroll_loop:
	;# twice unrolled innerloop here 
	mov   rdx, [rsp + nb331_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]
	
	add qword ptr [rsp + nb331_innerjjnr],  8 ;# advance pointer (unrolled 2) 

	mov rsi, [rbp + nb331_charge]    ;# base of charge[] 
	
	movlpd xmm3, [rsi + rax*8]
	movhpd xmm3, [rsi + rbx*8]
	movapd xmm4, xmm3	     
	mulpd  xmm3, [rsp + nb331_iqO]
	mulpd  xmm4, [rsp + nb331_iqH]
	movapd  [rsp + nb331_qqO], xmm3
	movapd  [rsp + nb331_qqH], xmm4	

	mov rsi, [rbp + nb331_type]
	mov r8d, [rsi + rax*4]
	mov r9d, [rsi + rbx*4]
	mov rsi, [rbp + nb331_vdwparam]
	shl r8d, 1	
	shl r9d, 1	
	mov edi, [rsp + nb331_ntia]
	add r8d, edi
	add r9d, edi

	movlpd xmm6, [rsi + r8*8]	;# c6a
	movlpd xmm7, [rsi + r9*8]	;# c6b
	movhpd xmm6, [rsi + r8*8 + 8]	;# c6a c12a 
	movhpd xmm7, [rsi + r9*8 + 8]	;# c6b c12b 

	movapd xmm4, xmm6
	unpcklpd xmm4, xmm7
	unpckhpd xmm6, xmm7
	
	movapd [rsp + nb331_c6], xmm4
	movapd [rsp + nb331_c12], xmm6

	mov rsi, [rbp + nb331_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	

	;# move j coordinates to local temp variables 
    movlpd xmm0, [rsi + rax*8] 
    movlpd xmm1, [rsi + rax*8 + 8] 
    movlpd xmm2, [rsi + rax*8 + 16] 
    movhpd xmm0, [rsi + rbx*8] 
    movhpd xmm1, [rsi + rbx*8 + 8] 
    movhpd xmm2, [rsi + rbx*8 + 16] 

    ;# xmm0 = jx
    ;# xmm1 = jy
    ;# xmm2 = jz
        
    movapd xmm3, xmm0
    movapd xmm4, xmm1
    movapd xmm5, xmm2
    movapd xmm6, xmm0
    movapd xmm7, xmm1
    movapd xmm8, xmm2
    
    subpd xmm0, [rsp + nb331_ixO]
    subpd xmm1, [rsp + nb331_iyO]
    subpd xmm2, [rsp + nb331_izO]
    subpd xmm3, [rsp + nb331_ixH1]
    subpd xmm4, [rsp + nb331_iyH1]
    subpd xmm5, [rsp + nb331_izH1]
    subpd xmm6, [rsp + nb331_ixH2]
    subpd xmm7, [rsp + nb331_iyH2]
    subpd xmm8, [rsp + nb331_izH2]
    
	movapd [rsp + nb331_dxO], xmm0
	movapd [rsp + nb331_dyO], xmm1
	movapd [rsp + nb331_dzO], xmm2
	mulpd  xmm0, xmm0
	mulpd  xmm1, xmm1
	mulpd  xmm2, xmm2
	movapd [rsp + nb331_dxH1], xmm3
	movapd [rsp + nb331_dyH1], xmm4
	movapd [rsp + nb331_dzH1], xmm5
	mulpd  xmm3, xmm3
	mulpd  xmm4, xmm4
	mulpd  xmm5, xmm5
	movapd [rsp + nb331_dxH2], xmm6
	movapd [rsp + nb331_dyH2], xmm7
	movapd [rsp + nb331_dzH2], xmm8
	mulpd  xmm6, xmm6
	mulpd  xmm7, xmm7
	mulpd  xmm8, xmm8
	addpd  xmm0, xmm1
	addpd  xmm0, xmm2
	addpd  xmm3, xmm4
	addpd  xmm3, xmm5
    addpd  xmm6, xmm7
    addpd  xmm6, xmm8

	;# start doing invsqrt for j atoms
    cvtpd2ps xmm1, xmm0
    cvtpd2ps xmm4, xmm3
    cvtpd2ps xmm7, xmm6
	rsqrtps xmm1, xmm1
	rsqrtps xmm4, xmm4
    rsqrtps xmm7, xmm7
    cvtps2pd xmm1, xmm1
    cvtps2pd xmm4, xmm4
    cvtps2pd xmm7, xmm7
	
	movapd  xmm2, xmm1
	movapd  xmm5, xmm4
    movapd  xmm8, xmm7
    
	mulpd   xmm1, xmm1 ;# lu*lu
	mulpd   xmm4, xmm4 ;# lu*lu
    mulpd   xmm7, xmm7 ;# lu*lu
		
	movapd  xmm9, [rsp + nb331_three]
	movapd  xmm10, xmm9
    movapd  xmm11, xmm9

	mulpd   xmm1, xmm0 ;# rsq*lu*lu
	mulpd   xmm4, xmm3 ;# rsq*lu*lu 
    mulpd   xmm7, xmm6 ;# rsq*lu*lu
	
	subpd   xmm9, xmm1
	subpd   xmm10, xmm4
    subpd   xmm11, xmm7 ;# 3-rsq*lu*lu

	mulpd   xmm9, xmm2