nb_kernel330_x86_64_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,450 行 · 第 1/4 页

##
## $Id: nb_kernel330_x86_64_sse2.s,v 1.4.2.3 2006/09/22 08:40:37 lindahl Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##




.globl nb_kernel330_x86_64_sse2
.globl _nb_kernel330_x86_64_sse2
nb_kernel330_x86_64_sse2:       
_nb_kernel330_x86_64_sse2:      
##      Room for return address and rbp (16 bytes)
.set nb330_fshift, 16
.set nb330_gid, 24
.set nb330_pos, 32
.set nb330_faction, 40
.set nb330_charge, 48
.set nb330_p_facel, 56
.set nb330_argkrf, 64
.set nb330_argcrf, 72
.set nb330_Vc, 80
.set nb330_type, 88
.set nb330_p_ntype, 96
.set nb330_vdwparam, 104
.set nb330_Vvdw, 112
.set nb330_p_tabscale, 120
.set nb330_VFtab, 128
.set nb330_invsqrta, 136
.set nb330_dvda, 144
.set nb330_p_gbtabscale, 152
.set nb330_GBtab, 160
.set nb330_p_nthreads, 168
.set nb330_count, 176
.set nb330_mtx, 184
.set nb330_outeriter, 192
.set nb330_inneriter, 200
.set nb330_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb330_ix, 0
.set nb330_iy, 16
.set nb330_iz, 32
.set nb330_iq, 48
.set nb330_dx, 64
.set nb330_dy, 80
.set nb330_dz, 96
.set nb330_rinv, 112
.set nb330_tsc, 128
.set nb330_qq, 144
.set nb330_c6, 160
.set nb330_c12, 176
.set nb330_eps, 192
.set nb330_vctot, 208
.set nb330_Vvdwtot, 224
.set nb330_fix, 240
.set nb330_fiy, 256
.set nb330_fiz, 272
.set nb330_half, 288
.set nb330_three, 304
.set nb330_nri, 320
.set nb330_iinr, 328
.set nb330_jindex, 336
.set nb330_jjnr, 344
.set nb330_shift, 352
.set nb330_shiftvec, 360
.set nb330_facel, 368
.set nb330_innerjjnr, 376
.set nb330_is3, 384
.set nb330_ii3, 388
.set nb330_ntia, 392
.set nb330_innerk, 396
.set nb330_n, 400
.set nb330_nn1, 404
.set nb330_ntype, 408
.set nb330_nouter, 412
.set nb330_ninner, 416
        push %rbp
        movq %rsp,%rbp
        push %rbx
        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $440,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb330_nouter(%rsp)
        movl %eax,nb330_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb330_nri(%rsp)
        movq %rsi,nb330_iinr(%rsp)
        movq %rdx,nb330_jindex(%rsp)
        movq %rcx,nb330_jjnr(%rsp)
        movq %r8,nb330_shift(%rsp)
        movq %r9,nb330_shiftvec(%rsp)
        movq nb330_p_ntype(%rbp),%rdi
        movl (%rdi),%edi
        movl %edi,nb330_ntype(%rsp)
        movq nb330_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd %xmm0,nb330_facel(%rsp)

        movq nb330_p_tabscale(%rbp),%rax
        movsd (%rax),%xmm3
        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb330_tsc(%rsp)

        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double half IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb330_half(%rsp)
        movl %ebx,nb330_half+4(%rsp)
        movsd nb330_half(%rsp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## one
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## two
        addpd  %xmm2,%xmm3      ## three
        movapd %xmm1,nb330_half(%rsp)
        movapd %xmm3,nb330_three(%rsp)

_nb_kernel330_x86_64_sse2.nb330_threadloop: 
        movq  nb330_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel330_x86_64_sse2.nb330_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel330_x86_64_sse2.nb330_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb330_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb330_n(%rsp)
        movl %ebx,nb330_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel330_x86_64_sse2.nb330_outerstart
        jmp _nb_kernel330_x86_64_sse2.nb330_end

_nb_kernel330_x86_64_sse2.nb330_outerstart: 
        ## ebx contains number of outer iterations
        addl nb330_nouter(%rsp),%ebx
        movl %ebx,nb330_nouter(%rsp)

_nb_kernel330_x86_64_sse2.nb330_outer: 
        movq  nb330_shift(%rsp),%rax        ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx        ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb330_is3(%rsp)      ## store is3 

        movq  nb330_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movsd (%rax,%rbx,8),%xmm0
        movsd 8(%rax,%rbx,8),%xmm1
        movsd 16(%rax,%rbx,8),%xmm2

        movq  nb330_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]        
        movl  (%rcx,%rsi,4),%ebx    ## ebx =ii 

        movq  nb330_charge(%rbp),%rdx
        movsd (%rdx,%rbx,8),%xmm3
        mulsd nb330_facel(%rsp),%xmm3
        shufpd $0,%xmm3,%xmm3

        movq  nb330_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%edx
        imull nb330_ntype(%rsp),%edx
        shll  %edx
        movl  %edx,nb330_ntia(%rsp)

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb330_pos(%rbp),%rax      ## rax = base of pos[]  

        addsd (%rax,%rbx,8),%xmm0
        addsd 8(%rax,%rbx,8),%xmm1
        addsd 16(%rax,%rbx,8),%xmm2

        movapd %xmm3,nb330_iq(%rsp)

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2

        movapd %xmm0,nb330_ix(%rsp)
        movapd %xmm1,nb330_iy(%rsp)
        movapd %xmm2,nb330_iz(%rsp)

        movl  %ebx,nb330_ii3(%rsp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb330_vctot(%rsp)
        movapd %xmm4,nb330_Vvdwtot(%rsp)
        movapd %xmm4,nb330_fix(%rsp)
        movapd %xmm4,nb330_fiy(%rsp)
        movapd %xmm4,nb330_fiz(%rsp)

        movq  nb330_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx             ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb330_pos(%rbp),%rsi
        movq  nb330_faction(%rbp),%rdi
        movq  nb330_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb330_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb330_ninner(%rsp),%ecx
        movl  %ecx,nb330_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb330_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel330_x86_64_sse2.nb330_unroll_loop
        jmp   _nb_kernel330_x86_64_sse2.nb330_checksingle
_nb_kernel330_x86_64_sse2.nb330_unroll_loop: 
        ## twice unrolled innerloop here 
        movq  nb330_innerjjnr(%rsp),%rdx     ## pointer to jjnr[k] 
        movl  (%rdx),%r12d
        movl  4(%rdx),%r13d
        addq $8,nb330_innerjjnr(%rsp)                   ## advance pointer (unrolled 2) 


        movq nb330_pos(%rbp),%rsi               ## base of pos[] 

        lea  (%r12,%r12,2),%rax     ## replace jnr with j3 
        lea  (%r13,%r13,2),%rbx

        ## move two coordinates to xmm4-xmm6 
        movlpd (%rsi,%rax,8),%xmm4
        movlpd 8(%rsi,%rax,8),%xmm5
        movlpd 16(%rsi,%rax,8),%xmm6
        movhpd (%rsi,%rbx,8),%xmm4
        movhpd 8(%rsi,%rbx,8),%xmm5
        movhpd 16(%rsi,%rbx,8),%xmm6

        ## calc dr 
        subpd nb330_ix(%rsp),%xmm4
        subpd nb330_iy(%rsp),%xmm5
        subpd nb330_iz(%rsp),%xmm6

        ## store dr 
        movapd %xmm4,nb330_dx(%rsp)
        movapd %xmm5,nb330_dy(%rsp)
        movapd %xmm6,nb330_dz(%rsp)

        movq nb330_charge(%rbp),%rsi     ## base of charge[] 

        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm4
        addpd %xmm6,%xmm4
        ## rsq in xmm4 
        movlpd (%rsi,%r12,8),%xmm3

        cvtpd2ps %xmm4,%xmm5
        rsqrtps %xmm5,%xmm5
        cvtps2pd %xmm5,%xmm2    ## lu in low xmm2 
        movhpd (%rsi,%r13,8),%xmm3
        movq nb330_type(%rbp),%rsi

        ## lookup seed in xmm2 
        movapd %xmm2,%xmm5      ## copy of lu 
        mulpd %xmm2,%xmm2       ## lu*lu 
        movapd nb330_three(%rsp),%xmm1
        mulpd  nb330_iq(%rsp),%xmm3
        mulpd %xmm4,%xmm2       ## rsq*lu*lu                    
        movapd nb330_half(%rsp),%xmm0
        subpd %xmm2,%xmm1       ## 30-rsq*lu*lu 
        mulpd %xmm5,%xmm1
        mulpd %xmm0,%xmm1       ## xmm0=iter1 of rinv (new lu) 
        movapd %xmm3,nb330_qq(%rsp)

        movl (%rsi,%r12,4),%r8d
        movl (%rsi,%r13,4),%r9d

        movapd %xmm1,%xmm5      ## copy of lu 
        mulpd %xmm1,%xmm1       ## lu*lu 
        movapd nb330_three(%rsp),%xmm2
        mulpd %xmm4,%xmm1       ## rsq*lu*lu                    
        movapd nb330_half(%rsp),%xmm0
        subpd %xmm1,%xmm2       ## 30-rsq*lu*lu 
        mulpd %xmm5,%xmm2
        mulpd %xmm2,%xmm0       ## xmm0=iter2 of rinv (new lu) 
        mulpd %xmm0,%xmm4       ## xmm4=r 
        mulpd nb330_tsc(%rsp),%xmm4
    movapd %xmm0,%xmm15 ## copy of rinv
        shll %r8d
        shll %r9d
        movl nb330_ntia(%rsp),%edi

        cvttpd2pi %xmm4,%mm6    ## mm6 = lu idx 
        addl %edi,%r8d
        addl %edi,%r9d
        cvtpi2pd %mm6,%xmm5
        subpd %xmm5,%xmm4
        movapd %xmm4,nb330_eps(%rsp)

        pslld $2,%mm6           ## idx *= 4 

        movq nb330_VFtab(%rbp),%rsi
        movd %mm6,%r10d
        psrlq $32,%mm6
        movd %mm6,%r11d         ## indices in r10,r11

        lea  (%r10,%r10,2),%r10        ## idx*=3 (12 total now) 
        lea  (%r11,%r11,2),%r11        ## idx*=3 (12 total now) 

    ## load Coulomb and LJ table data in parallel
    movapd (%rsi,%r10,8),%xmm0         ## Y1c F1c
    movapd (%rsi,%r11,8),%xmm12        ## Y2c F2c
    movapd 32(%rsi,%r10,8),%xmm4       ## Y1d F1d
    movapd 32(%rsi,%r11,8),%xmm13      ## Y2d F2d
    movapd 64(%rsi,%r10,8),%xmm8       ## Y1r F1r
    movapd 64(%rsi,%r11,8),%xmm14      ## Y2r F2r
        movapd %xmm0,%xmm1
        movapd %xmm4,%xmm5
        movapd %xmm8,%xmm9
        unpcklpd %xmm12,%xmm0   ## Y1c Y2c 
        unpckhpd %xmm12,%xmm1   ## F1c F2c 
        unpcklpd %xmm13,%xmm4   ## Y1d Y2d 
        unpckhpd %xmm13,%xmm5   ## F1d F2d 
        unpcklpd %xmm14,%xmm8   ## Y1r Y2r 
        unpckhpd %xmm14,%xmm9   ## F1r F2r 

    movapd 16(%rsi,%r10,8),%xmm2       ## G1c H1c
    movapd 16(%rsi,%r11,8),%xmm12      ## G2c H2c
    movapd 48(%rsi,%r10,8),%xmm6       ## G1d H1d
    movapd 48(%rsi,%r11,8),%xmm13      ## G2d H2d
    movapd 80(%rsi,%r10,8),%xmm10      ## G1r H1r