nb_kernel303_x86_64_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,073 行 · 第 1/5 页

        ## bottom of stack is cache-aligned for sse use 
.set nb303nf_ixM, 0
.set nb303nf_iyM, 16
.set nb303nf_izM, 32
.set nb303nf_ixH1, 48
.set nb303nf_iyH1, 64
.set nb303nf_izH1, 80
.set nb303nf_ixH2, 96
.set nb303nf_iyH2, 112
.set nb303nf_izH2, 128
.set nb303nf_iqM, 144
.set nb303nf_iqH, 160
.set nb303nf_qqM, 176
.set nb303nf_qqH, 192
.set nb303nf_rinvM, 208
.set nb303nf_rinvH1, 224
.set nb303nf_rinvH2, 240
.set nb303nf_rM, 256
.set nb303nf_rH1, 272
.set nb303nf_rH2, 288
.set nb303nf_tsc, 304
.set nb303nf_vctot, 320
.set nb303nf_half, 336
.set nb303nf_three, 352
.set nb303nf_is3, 368
.set nb303nf_ii3, 372
.set nb303nf_nri, 376
.set nb303nf_iinr, 384
.set nb303nf_jindex, 392
.set nb303nf_jjnr, 400
.set nb303nf_shift, 408
.set nb303nf_shiftvec, 416
.set nb303nf_facel, 424
.set nb303nf_innerjjnr, 432
.set nb303nf_innerk, 440
.set nb303nf_n, 444
.set nb303nf_nn1, 448
.set nb303nf_nouter, 452
.set nb303nf_ninner, 456
        push %rbp
        movq %rsp,%rbp
        push %rbx
        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $472,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb303nf_nouter(%rsp)
        movl %eax,nb303nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb303nf_nri(%rsp)
        movq %rsi,nb303nf_iinr(%rsp)
        movq %rdx,nb303nf_jindex(%rsp)
        movq %rcx,nb303nf_jjnr(%rsp)
        movq %r8,nb303nf_shift(%rsp)
        movq %r9,nb303nf_shiftvec(%rsp)
        movq nb303nf_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd %xmm0,nb303nf_facel(%rsp)

        movq nb303nf_p_tabscale(%rbp),%rax
        movsd (%rax),%xmm3
        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb303nf_tsc(%rsp)

        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double half IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb303nf_half(%rsp)
        movl %ebx,nb303nf_half+4(%rsp)
        movsd nb303nf_half(%rsp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## one
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## two
        addpd  %xmm2,%xmm3      ## three
        movapd %xmm1,nb303nf_half(%rsp)
        movapd %xmm3,nb303nf_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb303nf_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]      
        movl  (%rcx),%ebx           ## ebx =ii 

        movq  nb303nf_charge(%rbp),%rdx
        movsd 8(%rdx,%rbx,8),%xmm3
        movsd 24(%rdx,%rbx,8),%xmm4
        movq nb303nf_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd nb303nf_facel(%rsp),%xmm5
        mulsd  %xmm5,%xmm3
        mulsd  %xmm5,%xmm4

        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        movapd %xmm3,nb303nf_iqH(%rsp)
        movapd %xmm4,nb303nf_iqM(%rsp)

_nb_kernel303nf_x86_64_sse2.nb303nf_threadloop: 
        movq  nb303nf_count(%rbp),%rsi          ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel303nf_x86_64_sse2.nb303nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                           ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel303nf_x86_64_sse2.nb303nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb303nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb303nf_n(%rsp)
        movl %ebx,nb303nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel303nf_x86_64_sse2.nb303nf_outerstart
        jmp _nb_kernel303nf_x86_64_sse2.nb303nf_end

_nb_kernel303nf_x86_64_sse2.nb303nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb303nf_nouter(%rsp),%ebx
        movl %ebx,nb303nf_nouter(%rsp)

_nb_kernel303nf_x86_64_sse2.nb303nf_outer: 
        movq  nb303nf_shift(%rsp),%rax        ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx        ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 

        movq  nb303nf_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movsd (%rax,%rbx,8),%xmm0
        movsd 8(%rax,%rbx,8),%xmm1
        movsd 16(%rax,%rbx,8),%xmm2

        movq  nb303nf_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]      
        movl  (%rcx,%rsi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb303nf_pos(%rbp),%rax      ## rax = base of pos[]  
        movl  %ebx,nb303nf_ii3(%rsp)

        addsd 24(%rax,%rbx,8),%xmm3
        addsd 32(%rax,%rbx,8),%xmm4
        addsd 40(%rax,%rbx,8),%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb303nf_ixH1(%rsp)
        movapd %xmm4,nb303nf_iyH1(%rsp)
        movapd %xmm5,nb303nf_izH1(%rsp)

        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 48(%rax,%rbx,8),%xmm0
        addsd 56(%rax,%rbx,8),%xmm1
        addsd 64(%rax,%rbx,8),%xmm2
        addsd 72(%rax,%rbx,8),%xmm3
        addsd 80(%rax,%rbx,8),%xmm4
        addsd 88(%rax,%rbx,8),%xmm5

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm0,nb303nf_ixH2(%rsp)
        movapd %xmm1,nb303nf_iyH2(%rsp)
        movapd %xmm2,nb303nf_izH2(%rsp)
        movapd %xmm3,nb303nf_ixM(%rsp)
        movapd %xmm4,nb303nf_iyM(%rsp)
        movapd %xmm5,nb303nf_izM(%rsp)

        ## clear vctot 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb303nf_vctot(%rsp)

        movq  nb303nf_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx             ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb303nf_pos(%rbp),%rsi
        movq  nb303nf_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb303nf_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb303nf_ninner(%rsp),%ecx
        movl  %ecx,nb303nf_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb303nf_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel303nf_x86_64_sse2.nb303nf_unroll_loop
        jmp   _nb_kernel303nf_x86_64_sse2.nb303nf_checksingle
_nb_kernel303nf_x86_64_sse2.nb303nf_unroll_loop: 
        ## twice unrolled innerloop here 
        movq  nb303nf_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx

        addq $8,nb303nf_innerjjnr(%rsp)                 ## advance pointer (unrolled 2) 
        movq nb303nf_charge(%rbp),%rsi     ## base of charge[] 

        movlpd (%rsi,%rax,8),%xmm3
        movhpd (%rsi,%rbx,8),%xmm3
        movapd %xmm3,%xmm4
        mulpd  nb303nf_iqM(%rsp),%xmm3
        mulpd  nb303nf_iqH(%rsp),%xmm4

        movapd  %xmm3,nb303nf_qqM(%rsp)
        movapd  %xmm4,nb303nf_qqH(%rsp)

        movq nb303nf_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx

        ## move two coordinates to xmm0-xmm2    
        movlpd (%rsi,%rax,8),%xmm0
        movlpd 8(%rsi,%rax,8),%xmm1
        movlpd 16(%rsi,%rax,8),%xmm2
        movhpd (%rsi,%rbx,8),%xmm0
        movhpd 8(%rsi,%rbx,8),%xmm1
        movhpd 16(%rsi,%rbx,8),%xmm2

        ## move ixM-izM to xmm4-xmm6 
        movapd nb303nf_ixM(%rsp),%xmm4
        movapd nb303nf_iyM(%rsp),%xmm5
        movapd nb303nf_izM(%rsp),%xmm6

        ## calc dr 
        subpd %xmm0,%xmm4
        subpd %xmm1,%xmm5
        subpd %xmm2,%xmm6

        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm4
        addpd %xmm6,%xmm4
        movapd %xmm4,%xmm7
        ## rsqM in xmm7 

        ## move ixH1-izH1 to xmm4-xmm6 
        movapd nb303nf_ixH1(%rsp),%xmm4
        movapd nb303nf_iyH1(%rsp),%xmm5
        movapd nb303nf_izH1(%rsp),%xmm6

        ## calc dr 
        subpd %xmm0,%xmm4
        subpd %xmm1,%xmm5
        subpd %xmm2,%xmm6

        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm6
        addpd %xmm4,%xmm6
        ## rsqH1 in xmm6 

        ## move ixH2-izH2 to xmm3-xmm5  
        movapd nb303nf_ixH2(%rsp),%xmm3
        movapd nb303nf_iyH2(%rsp),%xmm4
        movapd nb303nf_izH2(%rsp),%xmm5

        ## calc dr 
        subpd %xmm0,%xmm3
        subpd %xmm1,%xmm4
        subpd %xmm2,%xmm5

        ## square it 
        mulpd %xmm3,%xmm3
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        addpd %xmm4,%xmm5
        addpd %xmm3,%xmm5
        ## rsqH2 in xmm5, rsqH1 in xmm6, rsqM in xmm7 

        ## start with rsqM - put seed in xmm2 
        cvtpd2ps %xmm7,%xmm2
        rsqrtps %xmm2,%xmm2
        cvtps2pd %xmm2,%xmm2

        movapd  %xmm2,%xmm3
        mulpd   %xmm2,%xmm2
        movapd  nb303nf_three(%rsp),%xmm4
        mulpd   %xmm7,%xmm2     ## rsq*lu*lu 
        subpd   %xmm2,%xmm4     ## 30-rsq*lu*lu 
        mulpd   %xmm3,%xmm4     ## lu*(3-rsq*lu*lu) 
        mulpd   nb303nf_half(%rsp),%xmm4   ## iter1 ( new lu) 

        movapd %xmm7,%xmm2
        movapd %xmm4,%xmm3
        mulpd %xmm4,%xmm4       ## lu*lu 
        mulpd %xmm4,%xmm2       ## rsq*lu*lu 
        movapd nb303nf_three(%rsp),%xmm4
        subpd %xmm2,%xmm4       ## 3-rsq*lu*lu 
        mulpd %xmm3,%xmm4       ## lu*( 3-rsq*lu*lu) 
        mulpd nb303nf_half(%rsp),%xmm4   ## rinv 
        movapd  %xmm4,nb303nf_rinvM(%rsp)       ## rinvM in xmm4 
        mulpd   %xmm4,%xmm7
        movapd  %xmm7,nb303nf_rM(%rsp)          ## r in xmm7 

        ## rsqH1 - seed in xmm2 
        cvtpd2ps %xmm6,%xmm2
        rsqrtps %xmm2,%xmm2
        cvtps2pd %xmm2,%xmm2

        movapd  %xmm2,%xmm3
        mulpd   %xmm2,%xmm2
        movapd  nb303nf_three(%rsp),%xmm4
        mulpd   %xmm6,%xmm2     ## rsq*lu*lu 
        subpd   %xmm2,%xmm4     ## 30-rsq*lu*lu 
        mulpd   %xmm3,%xmm4     ## lu*(3-rsq*lu*lu) 
        mulpd   nb303nf_half(%rsp),%xmm4   ## iter1 ( new lu) 

        movapd %xmm6,%xmm2
        movapd %xmm4,%xmm3
        mulpd %xmm4,%xmm4       ## lu*lu 
        mulpd %xmm4,%xmm2       ## rsq*lu*lu 
        movapd nb303nf_three(%rsp),%xmm4
        subpd %xmm2,%xmm4       ## 3-rsq*lu*lu 
        mulpd %xmm3,%xmm4       ## lu*( 3-rsq*lu*lu) 
        mulpd nb303nf_half(%rsp),%xmm4   ## rinv 
        movapd %xmm4,nb303nf_rinvH1(%rsp)       ## rinvH1 
        mulpd  %xmm4,%xmm6
        movapd %xmm6,nb303nf_rH1(%rsp)          ## rH1 

        ## rsqH2 - seed in xmm2 
        cvtpd2ps %xmm5,%xmm2
        rsqrtps %xmm2,%xmm2
        cvtps2pd %xmm2,%xmm2

        movapd  %xmm2,%xmm3
        mulpd   %xmm2,%xmm2
        movapd  nb303nf_three(%rsp),%xmm4
        mulpd   %xmm5,%xmm2     ## rsq*lu*lu 
        subpd   %xmm2,%xmm4     ## 30-rsq*lu*lu 
        mulpd   %xmm3,%xmm4     ## lu*(3-rsq*lu*lu) 
        mulpd   nb303nf_half(%rsp),%xmm4   ## iter1 ( new lu) 

        movapd %xmm5,%xmm2
        movapd %xmm4,%xmm3
        mulpd %xmm4,%xmm4       ## lu*lu 
        mulpd %xmm4,%xmm2       ## rsq*lu*lu 
        movapd nb303nf_three(%rsp),%xmm4
        subpd %xmm2,%xmm4       ## 3-rsq*lu*lu 
        mulpd %xmm3,%xmm4       ## lu*( 3-rsq*lu*lu) 
        mulpd nb303nf_half(%rsp),%xmm4   ## rinv 
        movapd %xmm4,nb303nf_rinvH2(%rsp)   ## rinv 
        mulpd %xmm4,%xmm5
        movapd %xmm5,nb303nf_rH2(%rsp)   ## r 

        ## do M interactions 
        ## rM is still in xmm7 
        mulpd nb303nf_tsc(%rsp),%xmm7
        cvttpd2pi %xmm7,%mm6    ## mm6 = lu idx 
        cvtpi2pd %mm6,%xmm6
        subpd %xmm6,%xmm7
        movapd %xmm7,%xmm1      ## xmm1=eps 
        movapd %xmm1,%xmm2
        mulpd  %xmm2,%xmm2      ## xmm2=eps2 

        pslld $2,%mm6           ## idx *= 4 
        movq nb303nf_VFtab(%rbp),%rsi
        movd %mm6,%eax
        psrlq $32,%mm6
        movd %mm6,%ebx          ## indices in eax/ebx 

        movapd (%rsi,%rax,8),%xmm4      ## Y1 F1        
        movapd (%rsi,%rbx,8),%xmm3      ## Y2 F2 
        movapd %xmm4,%xmm5
        unpcklpd %xmm3,%xmm4    ## Y1 Y2 
        unpckhpd %xmm3,%xmm5    ## F1 F2 

        movapd 16(%rsi,%rax,8),%xmm6    ## G1 H1        
        movapd 16(%rsi,%rbx,8),%xmm3    ## G2 H2 
        movapd %xmm6,%xmm7
        unpcklpd %xmm3,%xmm6    ## G1 G2 
        unpckhpd %xmm3,%xmm7    ## H1 H2 
        ## coulomb table ready, in xmm4-xmm7            
        mulpd  %xmm1,%xmm6      ## xmm6=Geps 
        mulpd  %xmm2,%xmm7      ## xmm7=Heps2 
        addpd  %xmm6,%xmm5
        addpd  %xmm7,%xmm5      ## xmm5=Fp      
        movapd nb303nf_qqM(%rsp),%xmm3
        mulpd  %xmm1,%xmm5 ## xmm5=eps*Fp 
        addpd  %xmm4,%xmm5 ## xmm5=VV 
        mulpd  %xmm3,%xmm5 ## vcoul=qq*VV  
    ## at this point mm5 contains vcoul 
    ## increment vcoul - then we can get rid of mm5 
    addpd  nb303nf_vctot(%rsp),%xmm5