nb_kernel130_x86_64_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,416 行 · 第 1/3 页

;#
;# $Id: nb_kernel130_x86_64_sse2.intel_syntax.s,v 1.1.2.2 2006/09/22 08:40:32 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as




.globl nb_kernel130_x86_64_sse2
.globl _nb_kernel130_x86_64_sse2
nb_kernel130_x86_64_sse2:	
_nb_kernel130_x86_64_sse2:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb130_fshift,           16
.equiv          nb130_gid,              24
.equiv          nb130_pos,              32
.equiv          nb130_faction,          40
.equiv          nb130_charge,           48
.equiv          nb130_p_facel,          56
.equiv          nb130_argkrf,           64
.equiv          nb130_argcrf,           72  
.equiv          nb130_Vc,               80
.equiv          nb130_type,             88
.equiv          nb130_p_ntype,          96
.equiv          nb130_vdwparam,         104
.equiv          nb130_Vvdw,             112
.equiv          nb130_p_tabscale,       120
.equiv          nb130_VFtab,            128
.equiv          nb130_invsqrta,         136
.equiv          nb130_dvda,             144
.equiv          nb130_p_gbtabscale,     152
.equiv          nb130_GBtab,            160
.equiv          nb130_p_nthreads,       168
.equiv          nb130_count,            176
.equiv          nb130_mtx,              184
.equiv          nb130_outeriter,        192
.equiv          nb130_inneriter,        200
.equiv          nb130_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb130_ix,               0
.equiv          nb130_iy,               16
.equiv          nb130_iz,               32
.equiv          nb130_iq,               48
.equiv          nb130_dx,               64
.equiv          nb130_dy,               80
.equiv          nb130_dz,               96
.equiv          nb130_c6,               112
.equiv          nb130_c12,              128
.equiv          nb130_tsc,              144
.equiv          nb130_fstmp,            160
.equiv          nb130_vctot,            176
.equiv          nb130_Vvdwtot,          192
.equiv          nb130_fix,              208
.equiv          nb130_fiy,              224
.equiv          nb130_fiz,              240
.equiv          nb130_half,             256
.equiv          nb130_three,            272
.equiv          nb130_two,              288
.equiv          nb130_krf,              304
.equiv          nb130_crf,              320
.equiv          nb130_nri,              336
.equiv          nb130_iinr,             344
.equiv          nb130_jindex,           352
.equiv          nb130_jjnr,             360
.equiv          nb130_shift,            368
.equiv          nb130_shiftvec,         376
.equiv          nb130_facel,            384
.equiv          nb130_innerjjnr,        392
.equiv          nb130_is3,              400
.equiv          nb130_ii3,              404
.equiv          nb130_ntia,             408
.equiv          nb130_innerk,           412
.equiv          nb130_n,                416
.equiv          nb130_nn1,              420
.equiv          nb130_ntype,            424
.equiv          nb130_nouter,           428
.equiv          nb130_ninner,           432
	push rbp
	mov  rbp, rsp
	push rbx
	
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 456		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb130_nouter], eax
	mov [rsp + nb130_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb130_nri], edi
	mov [rsp + nb130_iinr], rsi
	mov [rsp + nb130_jindex], rdx
	mov [rsp + nb130_jjnr], rcx
	mov [rsp + nb130_shift], r8
	mov [rsp + nb130_shiftvec], r9
	mov rdi, [rbp + nb130_p_ntype]
	mov edi, [rdi]
	mov [rsp + nb130_ntype], edi
	mov rsi, [rbp + nb130_p_facel]
	movsd xmm0, [rsi]
	movsd [rsp + nb130_facel], xmm0

	mov rax, [rbp + nb130_p_tabscale]
	movsd xmm3, [rax]
	shufpd xmm3, xmm3, 0
	movapd [rsp + nb130_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double half IEEE (hex)
	mov ebx, 0x3fe00000
	mov [rsp + nb130_half], eax
	mov [rsp + nb130_half+4], ebx
	movsd xmm1, [rsp + nb130_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# one
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# two
	addpd  xmm3, xmm2	;# three
	movapd [rsp + nb130_half], xmm1
	movapd [rsp + nb130_two], xmm2
	movapd [rsp + nb130_three], xmm3

.nb130_threadloop:
        mov   rsi, [rbp + nb130_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb130_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb130_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb130_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb130_n], eax
        mov [rsp + nb130_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb130_outerstart
        jmp .nb130_end

.nb130_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb130_nouter]
	mov [rsp + nb130_nouter], ebx

.nb130_outer:
	mov   rax, [rsp + nb130_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [rax+rsi*4]		;# ebx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb130_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb130_shiftvec]   ;# eax = base of shiftvec[] 

	movsd xmm0, [rax + rbx*8]
	movsd xmm1, [rax + rbx*8 + 8]
	movsd xmm2, [rax + rbx*8 + 16] 

	mov   rcx, [rsp + nb130_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [rcx+rsi*4]	    ;# ebx =ii 

	mov   rdx, [rbp + nb130_charge]
	movsd xmm3, [rdx + rbx*8]	
	mulsd xmm3, [rsp + nb130_facel]
	shufpd xmm3, xmm3, 0

    	mov   rdx, [rbp + nb130_type] 
    	mov   edx, [rdx + rbx*4]
    	imul  edx, [rsp + nb130_ntype]
    	shl   edx, 1
    	mov   [rsp + nb130_ntia], edx
		
	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb130_pos]    ;# eax = base of pos[]  

	addsd xmm0, [rax + rbx*8]
	addsd xmm1, [rax + rbx*8 + 8]
	addsd xmm2, [rax + rbx*8 + 16]

	movapd [rsp + nb130_iq], xmm3
	
	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0

	movapd [rsp + nb130_ix], xmm0
	movapd [rsp + nb130_iy], xmm1
	movapd [rsp + nb130_iz], xmm2

	mov   [rsp + nb130_ii3], ebx
	
	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [rsp + nb130_vctot], xmm4
	movapd [rsp + nb130_Vvdwtot], xmm4
	movapd [rsp + nb130_fix], xmm4
	movapd [rsp + nb130_fiy], xmm4
	movapd [rsp + nb130_fiz], xmm4
	
	mov   rax, [rsp + nb130_jindex]
	mov   ecx, [rax + rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rsi, [rbp + nb130_pos]
	mov   rdi, [rbp + nb130_faction]	
	mov   rax, [rsp + nb130_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb130_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [rsp + nb130_ninner]
	mov   [rsp + nb130_ninner], ecx
	add   edx, 0
	mov   [rsp + nb130_innerk], edx    ;# number of innerloop atoms 
	jge   .nb130_unroll_loop
	jmp   .nb130_checksingle
.nb130_unroll_loop:	
	;# twice unrolled innerloop here 
	mov   rdx, [rsp + nb130_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]              
	add qword ptr [rsp + nb130_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov rsi, [rbp + nb130_charge]    ;# base of charge[] 
	
	movlpd xmm3, [rsi + rax*8]
	movhpd xmm3, [rsi + rbx*8]

	mulpd xmm3, [rsp + nb130_iq]		;# qq 
	
	mov rsi, [rbp + nb130_type]
	mov r8d, [rsi + rax*4]
	mov r9d, [rsi + rbx*4]
	mov rsi, [rbp + nb130_vdwparam]
	shl r8d, 1
	shl r9d, 1
	mov edi, [rsp + nb130_ntia]
	add r8d, edi
	add r9d, edi

	movlpd xmm6, [rsi + r8*8]	;# c6
	movhpd xmm6, [rsi + r9*8]	
	movlpd xmm7, [rsi + r8*8 + 8]	;# c12 
	movhpd xmm7, [rsi + r9*8 + 8]	
	movapd [rsp + nb130_c6], xmm6
	movapd [rsp + nb130_c12], xmm7
	
	mov rsi, [rbp + nb130_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	

	;# move two coordinates to xmm4-xmm6 	
	movlpd xmm4, [rsi + rax*8]
	movlpd xmm5, [rsi + rax*8 + 8]
	movlpd xmm6, [rsi + rax*8 + 16]
	movhpd xmm4, [rsi + rbx*8]
	movhpd xmm5, [rsi + rbx*8 + 8]
	movhpd xmm6, [rsi + rbx*8 + 16]		
	
	;# calc dr 
	subpd xmm4, [rsp + nb130_ix]
	subpd xmm5, [rsp + nb130_iy]
	subpd xmm6, [rsp + nb130_iz]

	;# store dr 
	movapd [rsp + nb130_dx], xmm4
	movapd [rsp + nb130_dy], xmm5
	movapd [rsp + nb130_dz], xmm6
	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm4, xmm5
	addpd xmm4, xmm6
	;# rsq in xmm4 

	cvtpd2ps xmm5, xmm4	
	rsqrtps xmm5, xmm5
	cvtps2pd xmm2, xmm5	;# lu in low xmm2 

	;# lookup seed in xmm2 
	movapd xmm5, xmm2	;# copy of lu 
	mulpd xmm2, xmm2	;# lu*lu 
	movapd xmm1, [rsp + nb130_three]
	mulpd xmm2, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [rsp + nb130_half]
	subpd xmm1, xmm2	;# 30-rsq*lu*lu 
	mulpd xmm1, xmm5	
	mulpd xmm1, xmm0	;# xmm0=iter1 of rinv (new lu) 

	movapd xmm5, xmm1	;# copy of lu 
	mulpd xmm1, xmm1	;# lu*lu 
	movapd xmm2, [rsp + nb130_three]
	mulpd xmm1, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [rsp + nb130_half]
	subpd xmm2, xmm1	;# 30-rsq*lu*lu 
	mulpd xmm2, xmm5	
	mulpd xmm0, xmm2	;# xmm0=rinv 
	movapd xmm6, xmm0
	movapd xmm1, xmm4
	mulpd  xmm6, xmm3   ;# vcoul = rinv*qq
	movapd xmm3, xmm6
	mulpd  xmm3, xmm0
	
    ;# fstmp in xmm3
    
	addpd  xmm6, [rsp + nb130_vctot]
	movapd [rsp + nb130_vctot], xmm6

	;# LJ table interaction. xmm0=rinv, xmm4=rsq
	
	mulpd xmm4, xmm0	;# xmm4=r 
	mulpd xmm4, [rsp + nb130_tsc]
	
	cvttpd2pi mm6, xmm4	;# mm6 = lu idx 
	cvtpi2pd xmm5, mm6
	subpd xmm4, xmm5
	movapd xmm1, xmm4	;# xmm1=eps 

	pslld mm6, 3		;# idx *= 8 
	
	mov  rsi, [rbp + nb130_VFtab]
	movd r8d, mm6
	psrlq mm6, 32
	movd r9d, mm6

	;# load both disp. and rep. tables in parallel
	movlpd xmm4,  [rsi + r8*8]	    
	movlpd xmm5,  [rsi + r8*8 + 8]	
	movlpd xmm6,  [rsi + r8*8 + 16]	
	movlpd xmm7,  [rsi + r8*8 + 24]	
	movlpd xmm8,  [rsi + r8*8 + 32]	
	movlpd xmm9,  [rsi + r8*8 + 40]	
	movlpd xmm10, [rsi + r8*8 + 48]	
	movlpd xmm11, [rsi + r8*8 + 56]	
	movhpd xmm4,  [rsi + r9*8]	    
	movhpd xmm5,  [rsi + r9*8 + 8]	
	movhpd xmm6,  [rsi + r9*8 + 16]	
	movhpd xmm7,  [rsi + r9*8 + 24]	
	movhpd xmm8,  [rsi + r9*8 + 32]	
	movhpd xmm9,  [rsi + r9*8 + 40]	
	movhpd xmm10, [rsi + r9*8 + 48]	
	movhpd xmm11, [rsi + r9*8 + 56]	
	;# dispersion table ready in xmm4-xmm7, repulsion in xmm8-xmm11
    
    mulpd  xmm7, xmm1    ;# Heps
    mulpd  xmm11, xmm1 
    mulpd  xmm6, xmm1   ;# Geps
    mulpd  xmm10, xmm1 
    mulpd  xmm7, xmm1   ;# Heps2
    mulpd  xmm11, xmm1 
    addpd  xmm5, xmm6  ;# F+Geps
    addpd  xmm9, xmm10 
    addpd  xmm5, xmm7   ;# F+Geps+Heps2 = Fp
    addpd  xmm9, xmm11 
    addpd  xmm7, xmm7    ;# 2*Heps2
    addpd  xmm11, xmm11
    addpd  xmm7, xmm6   ;# 2*Heps2+Geps
    addpd  xmm11, xmm10
    
    addpd  xmm7, xmm5  ;# FF = Fp + 2*Heps2 + Geps
    addpd  xmm11, xmm9
    mulpd  xmm5, xmm1  ;# eps*Fp
    mulpd  xmm9, xmm1
    movapd xmm12, [rsp + nb130_c6]
    movapd xmm13, [rsp + nb130_c12]
    addpd  xmm5, xmm4 ;# VV
    addpd  xmm9, xmm8

    mulpd  xmm5, xmm12  ;# VV*c6 = vnb6
    mulpd  xmm9, xmm13  ;# VV*c12 = vnb12
    addpd  xmm5, xmm9
    addpd  xmm5, [rsp + nb130_Vvdwtot]
    movapd [rsp + nb130_Vvdwtot], xmm5
        
    mulpd  xmm7, xmm12   ;# FF*c6 = fnb6
    mulpd  xmm11, xmm13   ;# FF*c12  = fnb12
    addpd  xmm7, xmm11
    
    mulpd  xmm7, [rsp + nb130_tsc]
    subpd  xmm3, xmm7
    mulpd  xmm3, xmm0   ;# fscal

    movapd xmm9, xmm3
    movapd xmm10, xmm3
    movapd xmm11, xmm3
    
    movapd xmm12, [rsp + nb130_fix]
    movapd xmm13, [rsp + nb130_fiy]
    movapd xmm14, [rsp + nb130_fiz]
    
    mulpd  xmm9,  [rsp + nb130_dx]
    mulpd  xmm10, [rsp + nb130_dy]
    mulpd  xmm11, [rsp + nb130_dz]

    ;# accumulate i forces
    addpd xmm12, xmm9
    addpd xmm13, xmm10
    addpd xmm14, xmm11
    movapd [rsp + nb130_fix], xmm12
    movapd [rsp + nb130_fiy], xmm13
    movapd [rsp + nb130_fiz], xmm14
    
	;# the fj's - start by accumulating forces from memory 
    mov rdi, [rbp + nb130_faction]
	movlpd xmm3, [rdi + rax*8]
	movlpd xmm4, [rdi + rax*8 + 8]
	movlpd xmm5, [rdi + rax*8 + 16]
	movhpd xmm3, [rdi + rbx*8]
	movhpd xmm4, [rdi + rbx*8 + 8]
	movhpd xmm5, [rdi + rbx*8 + 16]