nb_kernel103_x86_64_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,622 行 · 第 1/3 页

    movapd [rsp + nb103_fizM], xmm15
   
    ;# store back j forces from xmm0-xmm2
	movlpd [rdi + rax*8], xmm0
	movlpd [rdi + rax*8 + 8], xmm1
	movlpd [rdi + rax*8 + 16], xmm2
	movhpd [rdi + rbx*8], xmm0
	movhpd [rdi + rbx*8 + 8], xmm1
	movhpd [rdi + rbx*8 + 16], xmm2

	;# should we do one more iteration? 
	sub dword ptr [rsp + nb103_innerk],  2
	jl    .nb103_checksingle
	jmp   .nb103_unroll_loop
.nb103_checksingle:				
	mov   edx, [rsp + nb103_innerk]
	and   edx, 1
	jnz    .nb103_dosingle
	jmp    .nb103_updateouterdata
.nb103_dosingle:
	mov   rdx, [rsp + nb103_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	

	mov rsi, [rbp + nb103_charge]    ;# base of charge[] 
	xorpd xmm6, xmm6
	movlpd xmm6, [rsi + rax*8]	;# jq A 
	
	movapd xmm3, [rsp + nb103_iqM]
	movapd xmm4, [rsp + nb103_iqH]
	mulsd xmm3, xmm6		;# qqM
	mulsd xmm4, xmm6		;# qqH 
	
	movapd  [rsp + nb103_qqM], xmm3
	movapd  [rsp + nb103_qqH], xmm4	

	mov rsi, [rbp + nb103_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 

	;# move coordinates to xmm4-xmm6 & xmm0-xmm2 	
	movlpd xmm4, [rsi + rax*8]
	movlpd xmm5, [rsi + rax*8 + 8]
	movlpd xmm6, [rsi + rax*8 + 16]
    movapd xmm0, xmm4
    movapd xmm1, xmm5
    movapd xmm2, xmm6
    
	;# calc dr 
	subsd xmm4, [rsp + nb103_ixM]
	subsd xmm5, [rsp + nb103_iyM]
	subsd xmm6, [rsp + nb103_izM]

	;# store dr 
	movapd [rsp + nb103_dxM], xmm4
	movapd [rsp + nb103_dyM], xmm5
	movapd [rsp + nb103_dzM], xmm6
	;# square it 
	mulsd xmm4,xmm4
	mulsd xmm5,xmm5
	mulsd xmm6,xmm6
	addsd xmm4, xmm5
	addsd xmm4, xmm6
	movapd xmm7, xmm4
	;# rsqM in xmm7 

	;# move j coords to xmm4-xmm6 
	movapd xmm4, xmm0
	movapd xmm5, xmm1
	movapd xmm6, xmm2

	;# calc dr 
	subsd xmm4, [rsp + nb103_ixH1]
	subsd xmm5, [rsp + nb103_iyH1]
	subsd xmm6, [rsp + nb103_izH1]

	;# store dr 
	movapd [rsp + nb103_dxH1], xmm4
	movapd [rsp + nb103_dyH1], xmm5
	movapd [rsp + nb103_dzH1], xmm6
	;# square it 
	mulsd xmm4,xmm4
	mulsd xmm5,xmm5
	mulsd xmm6,xmm6
	addsd xmm6, xmm5
	addsd xmm6, xmm4
	;# rsqH1 in xmm6 

	;# move j coords to xmm3-xmm5 
	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2

	;# calc dr 
	subsd xmm3, [rsp + nb103_ixH2]
	subsd xmm4, [rsp + nb103_iyH2]
	subsd xmm5, [rsp + nb103_izH2]

	;# store dr 
	movapd [rsp + nb103_dxH2], xmm3
	movapd [rsp + nb103_dyH2], xmm4
	movapd [rsp + nb103_dzH2], xmm5
	;# square it 
	mulsd xmm3,xmm3
	mulsd xmm4,xmm4
	mulsd xmm5,xmm5
	addsd xmm5, xmm4
	addsd xmm5, xmm3
	;# rsqH2 in xmm5, rsqH1 in xmm6, rsqO in xmm7 

	;# start with rsqM - put seed in xmm2 
	cvtsd2ss xmm2, xmm7	
	rsqrtss xmm2, xmm2
	cvtss2sd xmm2, xmm2

	movapd  xmm3, xmm2
	mulsd   xmm2, xmm2
	movapd  xmm4, [rsp + nb103_three]
	mulsd   xmm2, xmm7	;# rsq*lu*lu 
	subsd   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulsd   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulsd   xmm4, [rsp + nb103_half] ;# iter1 ( new lu) 

	movapd xmm3, xmm4
	mulsd xmm4, xmm4	;# lu*lu 
	mulsd xmm7, xmm4	;# rsq*lu*lu 
	movapd xmm4, [rsp + nb103_three]
	subsd xmm4, xmm7	;# 3-rsq*lu*lu 
	mulsd xmm4, xmm3	;# lu*(	3-rsq*lu*lu) 
	mulsd xmm4, [rsp + nb103_half] ;# rinv 
	movapd  xmm7, xmm4	;# rinvM in xmm7 
	
	;# rsqH1 - seed in xmm2 
	cvtsd2ss xmm2, xmm6	
	rsqrtss xmm2, xmm2
	cvtss2sd xmm2, xmm2

	movapd  xmm3, xmm2
	mulsd   xmm2, xmm2
	movapd  xmm4, [rsp + nb103_three]
	mulsd   xmm2, xmm6	;# rsq*lu*lu 
	subsd   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulsd   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulsd   xmm4, [rsp + nb103_half] ;# iter1 ( new lu) 

	movapd xmm3, xmm4
	mulsd xmm4, xmm4	;# lu*lu 
	mulsd xmm6, xmm4	;# rsq*lu*lu 
	movapd xmm4, [rsp + nb103_three]
	subsd xmm4, xmm6	;# 3-rsq*lu*lu 
	mulsd xmm4, xmm3	;# lu*(	3-rsq*lu*lu) 
	mulsd xmm4, [rsp + nb103_half] ;# rinv 
	movapd  xmm6, xmm4	;# rinvH1 in xmm6 
	
	;# rsqH2 - seed in xmm2 
	cvtsd2ss xmm2, xmm5	
	rsqrtss xmm2, xmm2
	cvtss2sd xmm2, xmm2

	movapd  xmm3, xmm2
	mulsd   xmm2, xmm2
	movapd  xmm4, [rsp + nb103_three]
	mulsd   xmm2, xmm5	;# rsq*lu*lu 
	subsd   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulsd   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulsd   xmm4, [rsp + nb103_half] ;# iter1 ( new lu) 

	movapd xmm3, xmm4
	mulsd xmm4, xmm4	;# lu*lu 
	mulsd xmm5, xmm4	;# rsq*lu*lu 
	movapd xmm4, [rsp + nb103_three]
	subsd xmm4, xmm5	;# 3-rsq*lu*lu 
	mulsd xmm4, xmm3	;# lu*(	3-rsq*lu*lu) 
	mulsd xmm4, [rsp + nb103_half] ;# rinv 
	movapd  xmm5, xmm4	;# rinvH2 in xmm5 

	;# do M interactions 
	movapd  xmm4, xmm7	
	mulsd   xmm4, xmm4	;# xmm7=rinv, xmm4=rinvsq 
	mulsd  xmm7, [rsp + nb103_qqM]	;# xmm7=vcoul 
	
	mulsd  xmm4, xmm7	;# total fsM in xmm4 

	addsd  xmm7, [rsp + nb103_vctot]
	
	movlpd [rsp + nb103_vctot], xmm7

	movapd xmm0, [rsp + nb103_dxM]
	movapd xmm1, [rsp + nb103_dyM]
	movapd xmm2, [rsp + nb103_dzM]
	mulsd  xmm0, xmm4
	mulsd  xmm1, xmm4
	mulsd  xmm2, xmm4

	;# update M forces 
	movapd xmm3, [rsp + nb103_fixM]
	movapd xmm4, [rsp + nb103_fiyM]
	movapd xmm7, [rsp + nb103_fizM]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm7, xmm2
	movlpd [rsp + nb103_fixM], xmm3
	movlpd [rsp + nb103_fiyM], xmm4
	movlpd [rsp + nb103_fizM], xmm7
	;# update j forces with water M 
	movlpd [rsp + nb103_fjx], xmm0
	movlpd [rsp + nb103_fjy], xmm1
	movlpd [rsp + nb103_fjz], xmm2

	;# H1 interactions 
	movapd  xmm4, xmm6	
	mulsd   xmm4, xmm4	;# xmm6=rinv, xmm4=rinvsq 
	mulsd  xmm6, [rsp + nb103_qqH]	;# xmm6=vcoul 
	mulsd  xmm4, xmm6		;# total fsH1 in xmm4 
	
	addsd  xmm6, [rsp + nb103_vctot]

	movapd xmm0, [rsp + nb103_dxH1]
	movapd xmm1, [rsp + nb103_dyH1]
	movapd xmm2, [rsp + nb103_dzH1]
	movlpd [rsp + nb103_vctot], xmm6
	mulsd  xmm0, xmm4
	mulsd  xmm1, xmm4
	mulsd  xmm2, xmm4

	;# update H1 forces 
	movapd xmm3, [rsp + nb103_fixH1]
	movapd xmm4, [rsp + nb103_fiyH1]
	movapd xmm7, [rsp + nb103_fizH1]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm7, xmm2
	movlpd [rsp + nb103_fixH1], xmm3
	movlpd [rsp + nb103_fiyH1], xmm4
	movlpd [rsp + nb103_fizH1], xmm7
	;# update j forces with water H1 
	addsd  xmm0, [rsp + nb103_fjx]
	addsd  xmm1, [rsp + nb103_fjy]
	addsd  xmm2, [rsp + nb103_fjz]
	movsd [rsp + nb103_fjx], xmm0
	movsd [rsp + nb103_fjy], xmm1
	movsd [rsp + nb103_fjz], xmm2

	;# H2 interactions 
	movapd  xmm4, xmm5	
	mulsd   xmm4, xmm4	;# xmm5=rinv, xmm4=rinvsq 
	mulsd  xmm5, [rsp + nb103_qqH]	;# xmm5=vcoul 
	mulsd  xmm4, xmm5		;# total fsH1 in xmm4 
	
	addsd  xmm5, [rsp + nb103_vctot]

	movapd xmm0, [rsp + nb103_dxH2]
	movapd xmm1, [rsp + nb103_dyH2]
	movapd xmm2, [rsp + nb103_dzH2]
	movlpd [rsp + nb103_vctot], xmm5
	mulsd  xmm0, xmm4
	mulsd  xmm1, xmm4
	mulsd  xmm2, xmm4

	;# update H2 forces 
	movapd xmm3, [rsp + nb103_fixH2]
	movapd xmm4, [rsp + nb103_fiyH2]
	movapd xmm7, [rsp + nb103_fizH2]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm7, xmm2
	movlpd [rsp + nb103_fixH2], xmm3
	movlpd [rsp + nb103_fiyH2], xmm4
	movlpd [rsp + nb103_fizH2], xmm7

	mov rdi, [rbp + nb103_faction]
	;# update j forces 
	addsd  xmm0, [rsp + nb103_fjx]
	addsd  xmm1, [rsp + nb103_fjy]
	addsd  xmm2, [rsp + nb103_fjz]

	movlpd xmm3, [rdi + rax*8]
	movlpd xmm4, [rdi + rax*8 + 8]
	movlpd xmm5, [rdi + rax*8 + 16]
	addsd xmm3, xmm0
	addsd xmm4, xmm1
	addsd xmm5, xmm2
	movlpd [rdi + rax*8], xmm3
	movlpd [rdi + rax*8 + 8], xmm4
	movlpd [rdi + rax*8 + 16], xmm5

.nb103_updateouterdata:
	mov   ecx, [rsp + nb103_ii3]
	mov   rdi, [rbp + nb103_faction]
	mov   rsi, [rbp + nb103_fshift]
	mov   edx, [rsp + nb103_is3]

	;# accumulate H1i forces in xmm0, xmm1, xmm2 
	movapd xmm0, [rsp + nb103_fixH1]
	movapd xmm1, [rsp + nb103_fiyH1]
	movapd xmm2, [rsp + nb103_fizH1]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addsd  xmm0, xmm3
	addsd  xmm1, xmm4
	addsd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	;# increment i force 
	movsd  xmm3, [rdi + rcx*8 + 24]
	movsd  xmm4, [rdi + rcx*8 + 32]
	movsd  xmm5, [rdi + rcx*8 + 40]
	subsd  xmm3, xmm0
	subsd  xmm4, xmm1
	subsd  xmm5, xmm2
	movsd  [rdi + rcx*8 + 24],     xmm3
	movsd  [rdi + rcx*8 + 32], xmm4
	movsd  [rdi + rcx*8 + 40], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	movapd xmm6, xmm0
	movsd xmm7, xmm2
	unpcklpd xmm6, xmm1

	;# accumulate H2i forces in xmm0, xmm1, xmm2 
	movapd xmm0, [rsp + nb103_fixH2]
	movapd xmm1, [rsp + nb103_fiyH2]
	movapd xmm2, [rsp + nb103_fizH2]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addsd  xmm0, xmm3
	addsd  xmm1, xmm4
	addsd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	;# increment i force 
	movsd  xmm3, [rdi + rcx*8 + 48]
	movsd  xmm4, [rdi + rcx*8 + 56]
	movsd  xmm5, [rdi + rcx*8 + 64]
	subsd  xmm3, xmm0
	subsd  xmm4, xmm1
	subsd  xmm5, xmm2
	movsd  [rdi + rcx*8 + 48], xmm3
	movsd  [rdi + rcx*8 + 56], xmm4
	movsd  [rdi + rcx*8 + 64], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	addsd xmm7, xmm2
	unpcklpd xmm0, xmm1
	addpd xmm6, xmm0

	;# accumulate H2i forces in xmm0, xmm1, xmm2 
	movapd xmm0, [rsp + nb103_fixM]
	movapd xmm1, [rsp + nb103_fiyM]
	movapd xmm2, [rsp + nb103_fizM]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addsd  xmm0, xmm3
	addsd  xmm1, xmm4
	addsd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	movapd xmm3, xmm0	
	movapd xmm4, xmm1	
	movapd xmm5, xmm2	

	;# increment i force 
	movsd  xmm3, [rdi + rcx*8 + 72]
	movsd  xmm4, [rdi + rcx*8 + 80]
	movsd  xmm5, [rdi + rcx*8 + 88]
	subsd  xmm3, xmm0
	subsd  xmm4, xmm1
	subsd  xmm5, xmm2
	movsd  [rdi + rcx*8 + 72], xmm3
	movsd  [rdi + rcx*8 + 80], xmm4
	movsd  [rdi + rcx*8 + 88], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	addsd xmm7, xmm2
	unpcklpd xmm0, xmm1
	addpd xmm6, xmm0

	;# increment fshift force 
	movlpd xmm3, [rsi + rdx*8]
	movhpd xmm3, [rsi + rdx*8 + 8]
	movsd  xmm4, [rsi + rdx*8 + 16]
	subpd  xmm3, xmm6
	subsd  xmm4, xmm7
	movlpd [rsi + rdx*8],      xmm3
	movhpd [rsi + rdx*8 + 8],  xmm3
	movsd  [rsi + rdx*8 + 16], xmm4

	;# get n from stack
	mov esi, [rsp + nb103_n]
        ;# get group index for i particle 
        mov   rdx, [rbp + nb103_gid]      	;# base of gid[]
        mov   edx, [rdx + rsi*4]		;# ggid=gid[n]

	;# accumulate total potential energy and update it 
	movapd xmm7, [rsp + nb103_vctot]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	        
	;# add earlier value from mem 
	mov   rax, [rbp + nb103_Vc]
	addsd xmm7, [rax + rdx*8] 
	;# move back to mem 
	movsd [rax + rdx*8], xmm7 	
	
        ;# finish if last 
        mov ecx, [rsp + nb103_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jz .nb103_outerend

        ;# not last, iterate outer loop once more!  
        mov [rsp + nb103_n], esi
        jmp .nb103_outer
.nb103_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [rsp + nb103_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jz .nb103_end
        ;# non-zero, do one more workunit
        jmp   .nb103_threadloop
.nb103_end:
	mov eax, [rsp + nb103_nouter]
	mov ebx, [rsp + nb103_ninner]
	mov rcx, [rbp + nb103_outeriter]
	mov rdx, [rbp + nb103_inneriter]
	mov [rcx], eax
	mov [rdx], ebx

	add rsp, 696
	emms


        pop r15
        pop r14
        pop r13
        pop r12

	pop rbx
	pop	rbp
	ret



.globl nb_kernel103nf_x86_64_sse2
.globl _nb_kernel103nf_x86_64_sse2
nb_kernel103nf_x86_64_sse2:	
_nb_kernel103nf_x86_64_sse2:	
.equiv          nb103nf_fshift,         16
.equiv          nb103nf_gid,            24
.equiv          nb103nf_pos,            32
.equiv          nb103nf_faction,        40
.equiv          nb103nf_charge,         48
.equiv          nb103nf_p_facel,        56
.equiv          nb103nf_argkrf,         64
.equiv          nb103nf_argcrf,         72
.equiv          nb103nf_Vc,             80
.equiv          nb103nf_type,           88
.equiv          nb103nf_p_ntype,        96
.equiv          nb103nf_vdwparam,       104
.equiv          nb103nf_Vvdw,           112
.equiv          nb103nf_p_tabscale,     120
.equiv          nb103nf_VFtab,          128
.equiv          nb103nf_invsqrta,       136
.equiv          nb103nf_dvda,           144
.equiv          nb103nf_p_gbtabscale,   152
.equiv          nb103nf_GBtab,          160
.equiv          nb103nf_p_nthreads,     168
.equiv          nb103nf_count,          176
.equiv          nb103nf_mtx,            184
.equiv          nb103nf_outeriter,      192
.equiv          nb103nf_inneriter,      200
.equiv          nb103nf_work,           208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb103nf_ixM,            0
.equiv          nb103nf_iyM,            16
.equiv          nb103nf_izM,            32
.equiv          nb103nf_ixH1,           48
.equiv          nb103nf_iyH1,           64
.equiv          nb103nf_izH1,           80
.equiv          nb103nf_ixH2,           96
.equiv          nb103nf_iyH2,           112
.equiv          nb103nf_izH2,           128
.equiv          nb103nf_iqM,            144
.equiv          nb103nf_iqH,            160
.equiv          nb103nf_qqM,            176
.equiv          nb103nf_qqH,            192
.equiv          nb103nf_vctot,          208
.equiv          nb103nf_half,           224
.equiv          nb103nf_three,          240
.equiv          nb103nf_is3,            256
.equiv          nb103nf_ii3,            260
.equiv          nb103nf_nri,            264
.equiv          nb103nf_iinr,           272
.equiv          nb103nf_jindex,         280
.equiv          nb103nf_jjnr,           288
.equiv          nb103nf_shift,          296
.equiv          nb103nf_shiftvec,       304
.equiv          nb103nf_facel,          312
.equiv          nb103nf_innerjjnr,      320
.equiv          nb103nf_innerk,         328
.equiv          nb103nf_n,              332
.equiv          nb103nf_nn1,            336
.equiv          nb103nf_nouter,         340
.equiv          nb103nf_ninner,         344
	push rbp
	mov  rbp, rsp
	push rbx
	
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 360		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb103nf_nouter], eax
	mov [rsp + nb103nf_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb103nf_nri], edi
	mov [rsp + nb103nf_iinr], rsi
	mov [rsp + nb103nf_jindex], rdx
	mov [rsp + nb103nf_jjnr], rcx
	mov [rsp + nb103nf_shift], r8
	mov [rsp + nb103nf_shiftvec], r9
	mov rsi, [rbp + nb103nf_p_facel]
	movsd xmm0, [rsi]
	movsd [rsp + nb103nf_facel], xmm0


	;# create constant floating-point factors on stack