nb_kernel232_x86_64_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,301 行 · 第 1/5 页

##
## $Id: nb_kernel232_x86_64_sse2.s,v 1.4.2.3 2006/09/22 08:40:34 lindahl Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##




.globl nb_kernel232_x86_64_sse2
.globl _nb_kernel232_x86_64_sse2
nb_kernel232_x86_64_sse2:       
_nb_kernel232_x86_64_sse2:      
##      Room for return address and rbp (16 bytes)
.set nb232_fshift, 16
.set nb232_gid, 24
.set nb232_pos, 32
.set nb232_faction, 40
.set nb232_charge, 48
.set nb232_p_facel, 56
.set nb232_argkrf, 64
.set nb232_argcrf, 72
.set nb232_Vc, 80
.set nb232_type, 88
.set nb232_p_ntype, 96
.set nb232_vdwparam, 104
.set nb232_Vvdw, 112
.set nb232_p_tabscale, 120
.set nb232_VFtab, 128
.set nb232_invsqrta, 136
.set nb232_dvda, 144
.set nb232_p_gbtabscale, 152
.set nb232_GBtab, 160
.set nb232_p_nthreads, 168
.set nb232_count, 176
.set nb232_mtx, 184
.set nb232_outeriter, 192
.set nb232_inneriter, 200
.set nb232_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb232_ixO, 0
.set nb232_iyO, 16
.set nb232_izO, 32
.set nb232_ixH1, 48
.set nb232_iyH1, 64
.set nb232_izH1, 80
.set nb232_ixH2, 96
.set nb232_iyH2, 112
.set nb232_izH2, 128
.set nb232_jxO, 144
.set nb232_jyO, 160
.set nb232_jzO, 176
.set nb232_jxH1, 192
.set nb232_jyH1, 208
.set nb232_jzH1, 224
.set nb232_jxH2, 240
.set nb232_jyH2, 256
.set nb232_jzH2, 272
.set nb232_dxOO, 288
.set nb232_dyOO, 304
.set nb232_dzOO, 320
.set nb232_dxOH1, 336
.set nb232_dyOH1, 352
.set nb232_dzOH1, 368
.set nb232_dxOH2, 384
.set nb232_dyOH2, 400
.set nb232_dzOH2, 416
.set nb232_dxH1O, 432
.set nb232_dyH1O, 448
.set nb232_dzH1O, 464
.set nb232_dxH1H1, 480
.set nb232_dyH1H1, 496
.set nb232_dzH1H1, 512
.set nb232_dxH1H2, 528
.set nb232_dyH1H2, 544
.set nb232_dzH1H2, 560
.set nb232_dxH2O, 576
.set nb232_dyH2O, 592
.set nb232_dzH2O, 608
.set nb232_dxH2H1, 624
.set nb232_dyH2H1, 640
.set nb232_dzH2H1, 656
.set nb232_dxH2H2, 672
.set nb232_dyH2H2, 688
.set nb232_dzH2H2, 704
.set nb232_qqOO, 720
.set nb232_qqOH, 736
.set nb232_qqHH, 752
.set nb232_c6, 768
.set nb232_c12, 784
.set nb232_tsc, 800
.set nb232_fstmp, 816
.set nb232_vctot, 832
.set nb232_Vvdwtot, 848
.set nb232_fixO, 864
.set nb232_fiyO, 880
.set nb232_fizO, 896
.set nb232_fixH1, 912
.set nb232_fiyH1, 928
.set nb232_fizH1, 944
.set nb232_fixH2, 960
.set nb232_fiyH2, 976
.set nb232_fizH2, 992
.set nb232_fjxO, 1008
.set nb232_fjyO, 1024
.set nb232_fjzO, 1040
.set nb232_fjxH1, 1056
.set nb232_fjyH1, 1072
.set nb232_fjzH1, 1088
.set nb232_fjxH2, 1104
.set nb232_fjyH2, 1120
.set nb232_fjzH2, 1136
.set nb232_half, 1152
.set nb232_three, 1168
.set nb232_rsqOO, 1184
.set nb232_rsqOH1, 1200
.set nb232_rsqOH2, 1216
.set nb232_rsqH1O, 1232
.set nb232_rsqH1H1, 1248
.set nb232_rsqH1H2, 1264
.set nb232_rsqH2O, 1280
.set nb232_rsqH2H1, 1296
.set nb232_rsqH2H2, 1312
.set nb232_rinvOO, 1328
.set nb232_rinvOH1, 1344
.set nb232_rinvOH2, 1360
.set nb232_rinvH1O, 1376
.set nb232_rinvH1H1, 1392
.set nb232_rinvH1H2, 1408
.set nb232_rinvH2O, 1424
.set nb232_rinvH2H1, 1440
.set nb232_rinvH2H2, 1456
.set nb232_two, 1472
.set nb232_krf, 1488
.set nb232_crf, 1504
.set nb232_nri, 1520
.set nb232_iinr, 1528
.set nb232_jindex, 1536
.set nb232_jjnr, 1544
.set nb232_shift, 1552
.set nb232_shiftvec, 1560
.set nb232_facel, 1568
.set nb232_innerjjnr, 1576
.set nb232_is3, 1584
.set nb232_ii3, 1588
.set nb232_innerk, 1592
.set nb232_n, 1596
.set nb232_nn1, 1600
.set nb232_nouter, 1604
.set nb232_ninner, 1608
        push %rbp
        movq %rsp,%rbp
        push %rbx
        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $1624,%rsp         ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb232_nouter(%rsp)
        movl %eax,nb232_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb232_nri(%rsp)
        movq %rsi,nb232_iinr(%rsp)
        movq %rdx,nb232_jindex(%rsp)
        movq %rcx,nb232_jjnr(%rsp)
        movq %r8,nb232_shift(%rsp)
        movq %r9,nb232_shiftvec(%rsp)
        movq nb232_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd %xmm0,nb232_facel(%rsp)

        movq nb232_p_tabscale(%rbp),%rax
        movsd (%rax),%xmm3
        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb232_tsc(%rsp)

        movq nb232_argkrf(%rbp),%rsi
        movq nb232_argcrf(%rbp),%rdi
        movsd (%rsi),%xmm1
        movsd (%rdi),%xmm2
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        movapd %xmm1,nb232_krf(%rsp)
        movapd %xmm2,nb232_crf(%rsp)

        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double half IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb232_half(%rsp)
        movl %ebx,nb232_half+4(%rsp)
        movsd nb232_half(%rsp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## one
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## two
        addpd  %xmm2,%xmm3      ## three
        movapd %xmm1,nb232_half(%rsp)
        movapd %xmm2,nb232_two(%rsp)
        movapd %xmm3,nb232_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb232_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]        
        movl  (%rcx),%ebx           ## ebx =ii 

        movq  nb232_charge(%rbp),%rdx
        movsd (%rdx,%rbx,8),%xmm3
        movsd %xmm3,%xmm4
        movsd 8(%rdx,%rbx,8),%xmm5

        movsd nb232_facel(%rsp),%xmm6
        mulsd  %xmm3,%xmm3
        mulsd  %xmm5,%xmm4
        mulsd  %xmm5,%xmm5
        mulsd  %xmm6,%xmm3
        mulsd  %xmm6,%xmm4
        mulsd  %xmm6,%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb232_qqOO(%rsp)
        movapd %xmm4,nb232_qqOH(%rsp)
        movapd %xmm5,nb232_qqHH(%rsp)

        xorpd %xmm0,%xmm0
        movq  nb232_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        movq nb232_p_ntype(%rbp),%rdi
        imull (%rdi),%ecx     ## rcx = ntia = 2*ntype*type[ii0] 
        addl  %ecx,%edx
        movq  nb232_vdwparam(%rbp),%rax
        movlpd (%rax,%rdx,8),%xmm0
        movlpd 8(%rax,%rdx,8),%xmm1
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        movapd %xmm0,nb232_c6(%rsp)
        movapd %xmm1,nb232_c12(%rsp)

_nb_kernel232_x86_64_sse2.nb232_threadloop: 
        movq  nb232_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel232_x86_64_sse2.nb232_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel232_x86_64_sse2.nb232_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb232_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb232_n(%rsp)
        movl %ebx,nb232_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel232_x86_64_sse2.nb232_outerstart
        jmp _nb_kernel232_x86_64_sse2.nb232_end

_nb_kernel232_x86_64_sse2.nb232_outerstart: 
        ## ebx contains number of outer iterations
        addl nb232_nouter(%rsp),%ebx
        movl %ebx,nb232_nouter(%rsp)

_nb_kernel232_x86_64_sse2.nb232_outer: 
        movq  nb232_shift(%rsp),%rax        ## eax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## ebx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb232_is3(%rsp)      ## store is3 

        movq  nb232_shiftvec(%rsp),%rax     ## eax = base of shiftvec[] 

        movlpd (%rax,%rbx,8),%xmm0
        movlpd 8(%rax,%rbx,8),%xmm1
        movlpd 16(%rax,%rbx,8),%xmm2

        movq  nb232_iinr(%rsp),%rcx         ## ecx = pointer into iinr[]        
        movl  (%rcx,%rsi,4),%ebx            ## ebx =ii 

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb232_pos(%rbp),%rax      ## eax = base of pos[]  
        movl  %ebx,nb232_ii3(%rsp)

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5
        addsd (%rax,%rbx,8),%xmm3
        addsd 8(%rax,%rbx,8),%xmm4
        addsd 16(%rax,%rbx,8),%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb232_ixO(%rsp)
        movapd %xmm4,nb232_iyO(%rsp)
        movapd %xmm5,nb232_izO(%rsp)

        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 24(%rax,%rbx,8),%xmm0
        addsd 32(%rax,%rbx,8),%xmm1
        addsd 40(%rax,%rbx,8),%xmm2
        addsd 48(%rax,%rbx,8),%xmm3
        addsd 56(%rax,%rbx,8),%xmm4
        addsd 64(%rax,%rbx,8),%xmm5

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm0,nb232_ixH1(%rsp)
        movapd %xmm1,nb232_iyH1(%rsp)
        movapd %xmm2,nb232_izH1(%rsp)
        movapd %xmm3,nb232_ixH2(%rsp)
        movapd %xmm4,nb232_iyH2(%rsp)
        movapd %xmm5,nb232_izH2(%rsp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb232_vctot(%rsp)
        movapd %xmm4,nb232_Vvdwtot(%rsp)
        movapd %xmm4,nb232_fixO(%rsp)
        movapd %xmm4,nb232_fiyO(%rsp)
        movapd %xmm4,nb232_fizO(%rsp)
        movapd %xmm4,nb232_fixH1(%rsp)
        movapd %xmm4,nb232_fiyH1(%rsp)
        movapd %xmm4,nb232_fizH1(%rsp)
        movapd %xmm4,nb232_fixH2(%rsp)
        movapd %xmm4,nb232_fiyH2(%rsp)
        movapd %xmm4,nb232_fizH2(%rsp)

        movq  nb232_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx             ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb232_pos(%rbp),%rsi
        movq  nb232_faction(%rbp),%rdi
        movq  nb232_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb232_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb232_ninner(%rsp),%ecx
        movl  %ecx,nb232_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb232_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel232_x86_64_sse2.nb232_unroll_loop
        jmp   _nb_kernel232_x86_64_sse2.nb232_checksingle
_nb_kernel232_x86_64_sse2.nb232_unroll_loop: 
        ## twice unrolled innerloop here 
        movq  nb232_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx

        addq $8,nb232_innerjjnr(%rsp)                   ## advance pointer (unrolled 2) 

        movq nb232_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx

        ## move j O coordinates to local temp variables 
    movlpd (%rsi,%rax,8),%xmm0
    movlpd 8(%rsi,%rax,8),%xmm1
    movlpd 16(%rsi,%rax,8),%xmm2
    movhpd (%rsi,%rbx,8),%xmm0
    movhpd 8(%rsi,%rbx,8),%xmm1
    movhpd 16(%rsi,%rbx,8),%xmm2

    ## xmm0 = Ox
    ## xmm1 = Oy
    ## xmm2 = Oz

    movapd %xmm0,%xmm3
    movapd %xmm1,%xmm4
    movapd %xmm2,%xmm5
    movapd %xmm0,%xmm6
    movapd %xmm1,%xmm7
    movapd %xmm2,%xmm8

    subpd nb232_ixO(%rsp),%xmm0
    subpd nb232_iyO(%rsp),%xmm1
    subpd nb232_izO(%rsp),%xmm2
    subpd nb232_ixH1(%rsp),%xmm3
    subpd nb232_iyH1(%rsp),%xmm4
    subpd nb232_izH1(%rsp),%xmm5
    subpd nb232_ixH2(%rsp),%xmm6
    subpd nb232_iyH2(%rsp),%xmm7
    subpd nb232_izH2(%rsp),%xmm8

        movapd %xmm0,nb232_dxOO(%rsp)
        movapd %xmm1,nb232_dyOO(%rsp)
        movapd %xmm2,nb232_dzOO(%rsp)
        mulpd  %xmm0,%xmm0
        mulpd  %xmm1,%xmm1
        mulpd  %xmm2,%xmm2
        movapd %xmm3,nb232_dxH1O(%rsp)
        movapd %xmm4,nb232_dyH1O(%rsp)
        movapd %xmm5,nb232_dzH1O(%rsp)
        mulpd  %xmm3,%xmm3
        mulpd  %xmm4,%xmm4
        mulpd  %xmm5,%xmm5
        movapd %xmm6,nb232_dxH2O(%rsp)
        movapd %xmm7,nb232_dyH2O(%rsp)
        movapd %xmm8,nb232_dzH2O(%rsp)
        mulpd  %xmm6,%xmm6
        mulpd  %xmm7,%xmm7
        mulpd  %xmm8,%xmm8
        addpd  %xmm1,%xmm0
        addpd  %xmm2,%xmm0
        addpd  %xmm4,%xmm3
        addpd  %xmm5,%xmm3
    addpd  %xmm7,%xmm6
    addpd  %xmm8,%xmm6

        ## start doing invsqrt for jO atoms
    cvtpd2ps %xmm0,%xmm1
    cvtpd2ps %xmm3,%xmm4
    cvtpd2ps %xmm6,%xmm7
        rsqrtps %xmm1,%xmm1
        rsqrtps %xmm4,%xmm4
    rsqrtps %xmm7,%xmm7
    cvtps2pd %xmm1,%xmm1
    cvtps2pd %xmm4,%xmm4
    cvtps2pd %xmm7,%xmm7

        movapd  %xmm1,%xmm2
        movapd  %xmm4,%xmm5