nb_kernel211_x86_64_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,949 行 · 第 1/4 页

;#
;# $Id: nb_kernel211_x86_64_sse2.intel_syntax.s,v 1.1.2.2 2006/09/22 08:40:34 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as




.globl nb_kernel211_x86_64_sse2
.globl _nb_kernel211_x86_64_sse2
nb_kernel211_x86_64_sse2:	
_nb_kernel211_x86_64_sse2:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb211_fshift,           16
.equiv          nb211_gid,              24
.equiv          nb211_pos,              32
.equiv          nb211_faction,          40
.equiv          nb211_charge,           48
.equiv          nb211_p_facel,          56
.equiv          nb211_argkrf,           64
.equiv          nb211_argcrf,           72
.equiv          nb211_Vc,               80
.equiv          nb211_type,             88
.equiv          nb211_p_ntype,          96
.equiv          nb211_vdwparam,         104
.equiv          nb211_Vvdw,             112
.equiv          nb211_p_tabscale,       120
.equiv          nb211_VFtab,            128
.equiv          nb211_invsqrta,         136
.equiv          nb211_dvda,             144
.equiv          nb211_p_gbtabscale,     152
.equiv          nb211_GBtab,            160
.equiv          nb211_p_nthreads,       168
.equiv          nb211_count,            176
.equiv          nb211_mtx,              184
.equiv          nb211_outeriter,        192
.equiv          nb211_inneriter,        200
.equiv          nb211_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb211_ixO,              0
.equiv          nb211_iyO,              16
.equiv          nb211_izO,              32
.equiv          nb211_ixH1,             48
.equiv          nb211_iyH1,             64
.equiv          nb211_izH1,             80
.equiv          nb211_ixH2,             96
.equiv          nb211_iyH2,             112
.equiv          nb211_izH2,             128
.equiv          nb211_iqO,              144
.equiv          nb211_iqH,              160
.equiv          nb211_dxO,              176
.equiv          nb211_dyO,              192
.equiv          nb211_dzO,              208
.equiv          nb211_dxH1,             224
.equiv          nb211_dyH1,             240
.equiv          nb211_dzH1,             256
.equiv          nb211_dxH2,             272
.equiv          nb211_dyH2,             288
.equiv          nb211_dzH2,             304
.equiv          nb211_qqO,              320
.equiv          nb211_qqH,              336
.equiv          nb211_c6,               352
.equiv          nb211_c12,              368
.equiv          nb211_six,              384
.equiv          nb211_twelve,           400
.equiv          nb211_vctot,            416
.equiv          nb211_Vvdwtot,          432
.equiv          nb211_fixO,             448
.equiv          nb211_fiyO,             464
.equiv          nb211_fizO,             480
.equiv          nb211_fixH1,            496
.equiv          nb211_fiyH1,            512
.equiv          nb211_fizH1,            528
.equiv          nb211_fixH2,            544
.equiv          nb211_fiyH2,            560
.equiv          nb211_fizH2,            576
.equiv          nb211_fjx,              592
.equiv          nb211_fjy,              608
.equiv          nb211_fjz,              624
.equiv          nb211_half,             640
.equiv          nb211_three,            656
.equiv          nb211_two,              672
.equiv          nb211_krf,              688
.equiv          nb211_crf,              704
.equiv          nb211_krsqO,            720
.equiv          nb211_krsqH1,           736
.equiv          nb211_krsqH2,           752
.equiv          nb211_nri,              768
.equiv          nb211_iinr,             776
.equiv          nb211_jindex,           784
.equiv          nb211_jjnr,             792
.equiv          nb211_shift,            800
.equiv          nb211_shiftvec,         808
.equiv          nb211_facel,            816
.equiv          nb211_innerjjnr,        824
.equiv          nb211_is3,              832
.equiv          nb211_ii3,              836
.equiv          nb211_ntia,             840
.equiv          nb211_innerk,           844
.equiv          nb211_n,                848
.equiv          nb211_nn1,              852
.equiv          nb211_nouter,           856
.equiv          nb211_ninner,           860
	push rbp
	mov  rbp, rsp
	push rbx
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 872		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb211_nouter], eax
	mov [rsp + nb211_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb211_nri], edi
	mov [rsp + nb211_iinr], rsi
	mov [rsp + nb211_jindex], rdx
	mov [rsp + nb211_jjnr], rcx
	mov [rsp + nb211_shift], r8
	mov [rsp + nb211_shiftvec], r9
	mov rsi, [rbp + nb211_p_facel]
	movsd xmm0, [rsi]
	movsd [rsp + nb211_facel], xmm0

	mov rsi, [rbp + nb211_argkrf]
	mov rdi, [rbp + nb211_argcrf]
	movsd xmm1, [rsi]
	movsd xmm2, [rdi]
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	movapd [rsp + nb211_krf], xmm1
	movapd [rsp + nb211_crf], xmm2

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double half IEEE (hex)
	mov ebx, 0x3fe00000
	mov [rsp + nb211_half], eax
	mov [rsp + nb211_half+4], ebx
	movsd xmm1, [rsp + nb211_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# one
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# two
	addpd  xmm3, xmm2	;# three
	movapd xmm4, xmm3
	addpd  xmm4, xmm4       ;# six
	movapd xmm5, xmm4
	addpd  xmm5, xmm5       ;# twelve
	movapd [rsp + nb211_half], xmm1
	movapd [rsp + nb211_two], xmm2
	movapd [rsp + nb211_three], xmm3
	movapd [rsp + nb211_six], xmm4
	movapd [rsp + nb211_twelve], xmm5
	
	;# assume we have at least one i particle - start directly 
	mov   rcx, [rsp + nb211_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx]	    ;# ebx =ii 

	mov   rdx, [rbp + nb211_charge]
	movsd xmm3, [rdx + rbx*8]	
	movsd xmm4, [rdx + rbx*8 + 8]	

	movsd xmm5, [rsp + nb211_facel]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [rsp + nb211_iqO], xmm3
	movapd [rsp + nb211_iqH], xmm4
	
	mov   rdx, [rbp + nb211_type]
	mov   ecx, [rdx + rbx*4]
	shl   ecx, 1
	mov rdi, [rbp + nb211_p_ntype]
	imul  ecx, [rdi]      ;# rcx = ntia = 2*ntype*type[ii0] 
	mov   [rsp + nb211_ntia], ecx		
.nb211_threadloop:
        mov   rsi, [rbp + nb211_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb211_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb211_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb211_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb211_n], eax
        mov [rsp + nb211_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb211_outerstart
        jmp .nb211_end

.nb211_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb211_nouter]
	mov [rsp + nb211_nouter], ebx

.nb211_outer:
	mov   rax, [rsp + nb211_shift]      ;# rax = pointer into shift[] 
	mov   ebx, [rax+rsi*4]		;# rbx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb211_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb211_shiftvec]   ;# rax = base of shiftvec[] 

	movsd xmm0, [rax + rbx*8]
	movsd xmm1, [rax + rbx*8 + 8]
	movsd xmm2, [rax + rbx*8 + 16] 

	mov   rcx, [rsp + nb211_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx+rsi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2

	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb211_pos]    ;# rax = base of pos[]  
	mov   [rsp + nb211_ii3], ebx

	addsd xmm3, [rax + rbx*8]
	addsd xmm4, [rax + rbx*8 + 8]
	addsd xmm5, [rax + rbx*8 + 16]		
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb211_ixO], xmm3
	movapd [rsp + nb211_iyO], xmm4
	movapd [rsp + nb211_izO], xmm5

	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm0, [rax + rbx*8 + 24]
	addsd xmm1, [rax + rbx*8 + 32]
	addsd xmm2, [rax + rbx*8 + 40]		
	addsd xmm3, [rax + rbx*8 + 48]
	addsd xmm4, [rax + rbx*8 + 56]
	addsd xmm5, [rax + rbx*8 + 64]		

	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb211_ixH1], xmm0
	movapd [rsp + nb211_iyH1], xmm1
	movapd [rsp + nb211_izH1], xmm2
	movapd [rsp + nb211_ixH2], xmm3
	movapd [rsp + nb211_iyH2], xmm4
	movapd [rsp + nb211_izH2], xmm5
	
	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [rsp + nb211_vctot], xmm4
	movapd [rsp + nb211_Vvdwtot], xmm4
	movapd [rsp + nb211_fixO], xmm4
	movapd [rsp + nb211_fiyO], xmm4
	movapd [rsp + nb211_fizO], xmm4
	movapd [rsp + nb211_fixH1], xmm4
	movapd [rsp + nb211_fiyH1], xmm4
	movapd [rsp + nb211_fizH1], xmm4
	movapd [rsp + nb211_fixH2], xmm4
	movapd [rsp + nb211_fiyH2], xmm4
	movapd [rsp + nb211_fizH2], xmm4
	
	mov   rax, [rsp + nb211_jindex]
	mov   ecx, [rax+rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rsi, [rbp + nb211_pos]
	mov   rdi, [rbp + nb211_faction]	
	mov   rax, [rsp + nb211_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb211_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [rsp + nb211_ninner]
	mov   [rsp + nb211_ninner], ecx
	add   edx, 0
	mov   [rsp + nb211_innerk], edx    ;# number of innerloop atoms 
	jge   .nb211_unroll_loop
	jmp   .nb211_checksingle
.nb211_unroll_loop:
	;# twice unrolled innerloop here 
	mov   rdx, [rsp + nb211_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]

	add qword ptr [rsp + nb211_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov rsi, [rbp + nb211_charge]    ;# base of charge[] 
	
	movlpd xmm3, [rsi + rax*8]
	movhpd xmm3, [rsi + rbx*8]
	movapd xmm4, xmm3
	mulpd  xmm3, [rsp + nb211_iqO]
	mulpd  xmm4, [rsp + nb211_iqH]

	movapd  [rsp + nb211_qqO], xmm3
	movapd  [rsp + nb211_qqH], xmm4
	
	mov rsi, [rbp + nb211_type]
	mov r8d, [rsi + rax*4]
	mov r9d, [rsi + rbx*4]
	mov rsi, [rbp + nb211_vdwparam]
	shl r8d, 1	
	shl r9d, 1	
	mov edi, [rsp + nb211_ntia]
	add r8d, edi
	add r9d, edi

	movlpd xmm6, [rsi + r8*8]	;# c6a
	movlpd xmm7, [rsi + r9*8]	;# c6b
	movhpd xmm6, [rsi + r8*8 + 8]	;# c6a c12a 
	movhpd xmm7, [rsi + r9*8 + 8]	;# c6b c12b 
	movapd xmm4, xmm6
	unpcklpd xmm4, xmm7
	unpckhpd xmm6, xmm7

	movapd [rsp + nb211_c6], xmm4
	movapd [rsp + nb211_c12], xmm6
	
	mov rsi, [rbp + nb211_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	

	;# move j coordinates to local temp variables 
    movlpd xmm0, [rsi + rax*8] 
    movlpd xmm1, [rsi + rax*8 + 8] 
    movlpd xmm2, [rsi + rax*8 + 16] 
    movhpd xmm0, [rsi + rbx*8] 
    movhpd xmm1, [rsi + rbx*8 + 8] 
    movhpd xmm2, [rsi + rbx*8 + 16] 

    ;# xmm0 = jx
    ;# xmm1 = jy
    ;# xmm2 = jz
        
    movapd xmm3, xmm0
    movapd xmm4, xmm1
    movapd xmm5, xmm2
    movapd xmm6, xmm0
    movapd xmm7, xmm1
    movapd xmm8, xmm2
    
    subpd xmm0, [rsp + nb211_ixO]
    subpd xmm1, [rsp + nb211_iyO]
    subpd xmm2, [rsp + nb211_izO]
    subpd xmm3, [rsp + nb211_ixH1]
    subpd xmm4, [rsp + nb211_iyH1]
    subpd xmm5, [rsp + nb211_izH1]
    subpd xmm6, [rsp + nb211_ixH2]
    subpd xmm7, [rsp + nb211_iyH2]
    subpd xmm8, [rsp + nb211_izH2]
    
	movapd [rsp + nb211_dxO], xmm0
	movapd [rsp + nb211_dyO], xmm1
	movapd [rsp + nb211_dzO], xmm2
	mulpd  xmm0, xmm0
	mulpd  xmm1, xmm1
	mulpd  xmm2, xmm2
	movapd [rsp + nb211_dxH1], xmm3
	movapd [rsp + nb211_dyH1], xmm4
	movapd [rsp + nb211_dzH1], xmm5
	mulpd  xmm3, xmm3
	mulpd  xmm4, xmm4
	mulpd  xmm5, xmm5
	movapd [rsp + nb211_dxH2], xmm6
	movapd [rsp + nb211_dyH2], xmm7
	movapd [rsp + nb211_dzH2], xmm8
	mulpd  xmm6, xmm6
	mulpd  xmm7, xmm7
	mulpd  xmm8, xmm8
	addpd  xmm0, xmm1
	addpd  xmm0, xmm2
	addpd  xmm3, xmm4
	addpd  xmm3, xmm5
    addpd  xmm6, xmm7
    addpd  xmm6, xmm8

	;# start doing invsqrt for j atoms
    cvtpd2ps xmm1, xmm0
    cvtpd2ps xmm4, xmm3
    cvtpd2ps xmm7, xmm6
	rsqrtps xmm1, xmm1
	rsqrtps xmm4, xmm4
    rsqrtps xmm7, xmm7
    cvtps2pd xmm1, xmm1
    cvtps2pd xmm4, xmm4
    cvtps2pd xmm7, xmm7
	
	movapd  xmm2, xmm1
	movapd  xmm5, xmm4
    movapd  xmm8, xmm7
    
	mulpd   xmm1, xmm1 ;# lu*lu
	mulpd   xmm4, xmm4 ;# lu*lu
    mulpd   xmm7, xmm7 ;# lu*lu
		
	movapd  xmm9, [rsp + nb211_three]
	movapd  xmm10, xmm9
    movapd  xmm11, xmm9

	mulpd   xmm1, xmm0 ;# rsq*lu*lu
	mulpd   xmm4, xmm3 ;# rsq*lu*lu 
    mulpd   xmm7, xmm6 ;# rsq*lu*lu
	
	subpd   xmm9, xmm1
	subpd   xmm10, xmm4
    subpd   xmm11, xmm7 ;# 3-rsq*lu*lu

	mulpd   xmm9, xmm2
	mulpd   xmm10, xmm5
    mulpd   xmm11, xmm8 ;# lu*(3-rsq*lu*lu)

	movapd  xmm15, [rsp + nb211_half]
	mulpd   xmm9, xmm15  ;# first iteration for rinvO
	mulpd   xmm10, xmm15 ;# first iteration for rinvH1
    mulpd   xmm11, xmm15 ;# first iteration for rinvH2

    ;# second iteration step