nb_kernel203_x86_64_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,732 行 · 第 1/4 页

;#
;# $Id: nb_kernel203_x86_64_sse2.intel_syntax.s,v 1.1.2.2 2006/09/22 08:40:33 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as



	

.globl nb_kernel203_x86_64_sse2
.globl _nb_kernel203_x86_64_sse2
nb_kernel203_x86_64_sse2:	
_nb_kernel203_x86_64_sse2:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb203_fshift,           16
.equiv          nb203_gid,              24
.equiv          nb203_pos,              32
.equiv          nb203_faction,          40
.equiv          nb203_charge,           48
.equiv          nb203_p_facel,          56
.equiv          nb203_argkrf,           64
.equiv          nb203_argcrf,           72
.equiv          nb203_Vc,               80
.equiv          nb203_type,             88
.equiv          nb203_p_ntype,          96
.equiv          nb203_vdwparam,         104
.equiv          nb203_Vvdw,             112
.equiv          nb203_p_tabscale,       120
.equiv          nb203_VFtab,            128
.equiv          nb203_invsqrta,         136
.equiv          nb203_dvda,             144
.equiv          nb203_p_gbtabscale,     152
.equiv          nb203_GBtab,            160
.equiv          nb203_p_nthreads,       168
.equiv          nb203_count,            176
.equiv          nb203_mtx,              184
.equiv          nb203_outeriter,        192
.equiv          nb203_inneriter,        200
.equiv          nb203_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb203_ixM,              0
.equiv          nb203_iyM,              16
.equiv          nb203_izM,              32
.equiv          nb203_ixH1,             48
.equiv          nb203_iyH1,             64
.equiv          nb203_izH1,             80
.equiv          nb203_ixH2,             96
.equiv          nb203_iyH2,             112
.equiv          nb203_izH2,             128
.equiv          nb203_iqM,              144
.equiv          nb203_iqH,              160
.equiv          nb203_dxM,              176
.equiv          nb203_dyM,              192
.equiv          nb203_dzM,              208
.equiv          nb203_dxH1,             224
.equiv          nb203_dyH1,             240
.equiv          nb203_dzH1,             256
.equiv          nb203_dxH2,             272
.equiv          nb203_dyH2,             288
.equiv          nb203_dzH2,             304
.equiv          nb203_qqM,              320
.equiv          nb203_qqH,              336
.equiv          nb203_vctot,            352
.equiv          nb203_fixM,             384
.equiv          nb203_fiyM,             400
.equiv          nb203_fizM,             416
.equiv          nb203_fixH1,            432
.equiv          nb203_fiyH1,            448
.equiv          nb203_fizH1,            464
.equiv          nb203_fixH2,            480
.equiv          nb203_fiyH2,            496
.equiv          nb203_fizH2,            512
.equiv          nb203_fjx,              528
.equiv          nb203_fjy,              544
.equiv          nb203_fjz,              560
.equiv          nb203_half,             576
.equiv          nb203_three,            592
.equiv          nb203_two,              608
.equiv          nb203_krf,              624
.equiv          nb203_crf,              640
.equiv          nb203_krsqM,            656
.equiv          nb203_krsqH1,           672
.equiv          nb203_krsqH2,           688
.equiv          nb203_is3,              704
.equiv          nb203_ii3,              708
.equiv          nb203_nri,              712
.equiv          nb203_iinr,             720
.equiv          nb203_jindex,           728
.equiv          nb203_jjnr,             736
.equiv          nb203_shift,            744
.equiv          nb203_shiftvec,         752
.equiv          nb203_facel,            760
.equiv          nb203_innerjjnr,        768
.equiv          nb203_innerk,           776
.equiv          nb203_n,                780
.equiv          nb203_nn1,              784
.equiv          nb203_nouter,           788
.equiv          nb203_ninner,           792
	push rbp
	mov  rbp, rsp
	push rbx
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 808		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb203_nouter], eax
	mov [rsp + nb203_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb203_nri], edi
	mov [rsp + nb203_iinr], rsi
	mov [rsp + nb203_jindex], rdx
	mov [rsp + nb203_jjnr], rcx
	mov [rsp + nb203_shift], r8
	mov [rsp + nb203_shiftvec], r9
	mov rsi, [rbp + nb203_p_facel]
	movsd xmm0, [rsi]
	movsd [rsp + nb203_facel], xmm0

	mov rsi, [rbp + nb203_argkrf]
	mov rdi, [rbp + nb203_argcrf]
	movsd xmm1, [rsi]
	movsd xmm2, [rdi]
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	movapd [rsp + nb203_krf], xmm1
	movapd [rsp + nb203_crf], xmm2

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double half IEEE (hex)
	mov ebx, 0x3fe00000
	mov [rsp + nb203_half], eax
	mov [rsp + nb203_half+4], ebx
	movsd xmm1, [rsp + nb203_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# one
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# two
	addpd  xmm3, xmm2	;# three
	movapd [rsp + nb203_half], xmm1
	movapd [rsp + nb203_two], xmm2
	movapd [rsp + nb203_three], xmm3

	;# assume we have at least one i particle - start directly 
	mov   rcx, [rsp + nb203_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx]	    ;# ebx =ii 

	mov   rdx, [rbp + nb203_charge]
	movsd xmm3, [rdx + rbx*8 + 8]	
	movsd xmm4, [rdx + rbx*8 + 24]	

	movsd xmm5, [rsp + nb203_facel]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [rsp + nb203_iqH], xmm3
	movapd [rsp + nb203_iqM], xmm4
	
.nb203_threadloop:
        mov   rsi, [rbp + nb203_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb203_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb203_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb203_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb203_n], eax
        mov [rsp + nb203_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb203_outerstart
        jmp .nb203_end

.nb203_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb203_nouter]
	mov [rsp + nb203_nouter], ebx

.nb203_outer:
	mov   rax, [rsp + nb203_shift]      ;# rax = pointer into shift[] 
	mov   ebx, [rax + rsi*4]		;# rbx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb203_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb203_shiftvec]   ;# rax = base of shiftvec[] 

	movsd xmm0, [rax + rbx*8]
	movsd xmm1, [rax + rbx*8 + 8]
	movsd xmm2, [rax + rbx*8 + 16] 

	mov   rcx, [rsp + nb203_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx+rsi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2

	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb203_pos]    ;# rax = base of pos[]  
	mov   [rsp + nb203_ii3], ebx

	addsd xmm3, [rax + rbx*8 + 24]
	addsd xmm4, [rax + rbx*8 + 32]
	addsd xmm5, [rax + rbx*8 + 40]		
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb203_ixH1], xmm3
	movapd [rsp + nb203_iyH1], xmm4
	movapd [rsp + nb203_izH1], xmm5

	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm0, [rax + rbx*8 + 48]
	addsd xmm1, [rax + rbx*8 + 56]
	addsd xmm2, [rax + rbx*8 + 64]		
	addsd xmm3, [rax + rbx*8 + 72]
	addsd xmm4, [rax + rbx*8 + 80]
	addsd xmm5, [rax + rbx*8 + 88]		

	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb203_ixH2], xmm0
	movapd [rsp + nb203_iyH2], xmm1
	movapd [rsp + nb203_izH2], xmm2
	movapd [rsp + nb203_ixM], xmm3
	movapd [rsp + nb203_iyM], xmm4
	movapd [rsp + nb203_izM], xmm5

	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [rsp + nb203_vctot], xmm4
	movapd [rsp + nb203_fixM], xmm4
	movapd [rsp + nb203_fiyM], xmm4
	movapd [rsp + nb203_fizM], xmm4
	movapd [rsp + nb203_fixH1], xmm4
	movapd [rsp + nb203_fiyH1], xmm4
	movapd [rsp + nb203_fizH1], xmm4
	movapd [rsp + nb203_fixH2], xmm4
	movapd [rsp + nb203_fiyH2], xmm4
	movapd [rsp + nb203_fizH2], xmm4
	
	mov   rax, [rsp + nb203_jindex]
	mov   ecx, [rax + rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rsi, [rbp + nb203_pos]
	mov   rdi, [rbp + nb203_faction]	
	mov   rax, [rsp + nb203_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb203_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [rsp + nb203_ninner]
	mov   [rsp + nb203_ninner], ecx
	add   edx, 0
	mov   [rsp + nb203_innerk], edx    ;# number of innerloop atoms 
	jge   .nb203_unroll_loop
	jmp   .nb203_checksingle
.nb203_unroll_loop:
	;# twice unrolled innerloop here 
	mov   rdx, [rsp + nb203_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]

	add qword ptr [rsp + nb203_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov rsi, [rbp + nb203_charge]    ;# base of charge[] 
	
	movlpd xmm3, [rsi + rax*8]
	movhpd xmm3, [rsi + rbx*8]
	movapd xmm4, xmm3
	mulpd  xmm3, [rsp + nb203_iqM]
	mulpd  xmm4, [rsp + nb203_iqH]
	movapd  [rsp + nb203_qqM], xmm3
	movapd  [rsp + nb203_qqH], xmm4	

	mov rsi, [rbp + nb203_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	

	;# load j coordinates 
    movlpd xmm0, [rsi + rax*8] 
    movlpd xmm1, [rsi + rax*8 + 8] 
    movlpd xmm2, [rsi + rax*8 + 16] 
    movhpd xmm0, [rsi + rbx*8] 
    movhpd xmm1, [rsi + rbx*8 + 8] 
    movhpd xmm2, [rsi + rbx*8 + 16] 

    ;# xmm0 = jx
    ;# xmm1 = jy
    ;# xmm2 = jz
        
    movapd xmm3, xmm0
    movapd xmm4, xmm1
    movapd xmm5, xmm2
    movapd xmm6, xmm0
    movapd xmm7, xmm1
    movapd xmm8, xmm2
    
    subpd xmm0, [rsp + nb203_ixH1]
    subpd xmm1, [rsp + nb203_iyH1]
    subpd xmm2, [rsp + nb203_izH1]
    subpd xmm3, [rsp + nb203_ixH2]
    subpd xmm4, [rsp + nb203_iyH2]
    subpd xmm5, [rsp + nb203_izH2]
    subpd xmm6, [rsp + nb203_ixM]
    subpd xmm7, [rsp + nb203_iyM]
    subpd xmm8, [rsp + nb203_izM]
    
	movapd [rsp + nb203_dxH1], xmm0
	movapd [rsp + nb203_dyH1], xmm1
	movapd [rsp + nb203_dzH1], xmm2
	mulpd  xmm0, xmm0
	mulpd  xmm1, xmm1
	mulpd  xmm2, xmm2
	movapd [rsp + nb203_dxH2], xmm3
	movapd [rsp + nb203_dyH2], xmm4
	movapd [rsp + nb203_dzH2], xmm5
	mulpd  xmm3, xmm3
	mulpd  xmm4, xmm4
	mulpd  xmm5, xmm5
	movapd [rsp + nb203_dxM], xmm6
	movapd [rsp + nb203_dyM], xmm7
	movapd [rsp + nb203_dzM], xmm8
	mulpd  xmm6, xmm6
	mulpd  xmm7, xmm7
	mulpd  xmm8, xmm8
	addpd  xmm0, xmm1
	addpd  xmm0, xmm2
	addpd  xmm3, xmm4
	addpd  xmm3, xmm5
    addpd  xmm6, xmm7
    addpd  xmm6, xmm8

	;# start doing invsqrt for j atoms
    cvtpd2ps xmm1, xmm0
    cvtpd2ps xmm4, xmm3
    cvtpd2ps xmm7, xmm6
	rsqrtps xmm1, xmm1
	rsqrtps xmm4, xmm4
    rsqrtps xmm7, xmm7
    cvtps2pd xmm1, xmm1
    cvtps2pd xmm4, xmm4
    cvtps2pd xmm7, xmm7
	
	movapd  xmm2, xmm1
	movapd  xmm5, xmm4
    movapd  xmm8, xmm7
    
	mulpd   xmm1, xmm1 ;# lu*lu
	mulpd   xmm4, xmm4 ;# lu*lu
    mulpd   xmm7, xmm7 ;# lu*lu
		
	movapd  xmm9, [rsp + nb203_three]
	movapd  xmm10, xmm9
    movapd  xmm11, xmm9

	mulpd   xmm1, xmm0 ;# rsq*lu*lu
	mulpd   xmm4, xmm3 ;# rsq*lu*lu 
    mulpd   xmm7, xmm6 ;# rsq*lu*lu