nb_kernel113_x86_64_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,022 行 · 第 1/5 页

        mulpd  %xmm5,%xmm5

        addpd  %xmm4,%xmm3
        addpd  %xmm5,%xmm3

    ## calc 1/rsq
    cvtpd2ps %xmm3,%xmm6
    rcpps %xmm6,%xmm6
    cvtps2pd %xmm6,%xmm6    ## lu in low xmm6 

    ## 1/x lookup seed in xmm6 
    movapd nb113_two(%rsp),%xmm4
    movapd %xmm3,%xmm5      ## rsq
    mulpd %xmm6,%xmm3       ## lu*rsq 
    subpd %xmm3,%xmm4       ## 2-lu*rsq 
    mulpd %xmm4,%xmm6       ## (new lu) 

    movapd nb113_two(%rsp),%xmm4
    mulpd %xmm6,%xmm5       ## lu*rsq 
    subpd %xmm5,%xmm4       ## 2-lu*rsq 
    mulpd %xmm6,%xmm4       ## xmm4=rinvsq 

    movapd %xmm4,%xmm3      ## rinvsq
    mulpd  %xmm4,%xmm4      ## rinv4
    mulpd  %xmm3,%xmm4      ## rinv6
    movapd %xmm4,%xmm5
    mulpd  %xmm5,%xmm5      ## rinv12
    mulpd  nb113_c6(%rsp),%xmm4
    mulpd  nb113_c12(%rsp),%xmm5
    movapd %xmm5,%xmm6
    subpd  %xmm4,%xmm6 ## Vvdw=vvdw12-vvdw6
    mulpd  nb113_six(%rsp),%xmm4
    mulpd  nb113_twelve(%rsp),%xmm5
    subpd  %xmm4,%xmm5
    mulpd  %xmm5,%xmm3  ## fscal

    addpd  nb113_Vvdwtot(%rsp),%xmm6
    movapd %xmm6,nb113_Vvdwtot(%rsp)

    mulpd  %xmm3,%xmm13 ## fx
    mulpd  %xmm3,%xmm14 ## fy
    mulpd  %xmm3,%xmm15 ## fz

    ## save j force temporarily
    movapd %xmm13,nb113_fjx(%rsp)
    movapd %xmm14,nb113_fjy(%rsp)
    movapd %xmm15,nb113_fjz(%rsp)

    ## increment i O force
    addpd nb113_fixO(%rsp),%xmm13
    addpd nb113_fiyO(%rsp),%xmm14
    addpd nb113_fizO(%rsp),%xmm15
    movapd %xmm13,nb113_fixO(%rsp)
    movapd %xmm14,nb113_fiyO(%rsp)
    movapd %xmm15,nb113_fizO(%rsp)
    ## finished O LJ interaction.


    ## do H1, H2, and M interactions in parallel.
    ## xmm0-xmm2 still contain j coordinates.        
    movapd %xmm0,%xmm3
    movapd %xmm1,%xmm4
    movapd %xmm2,%xmm5
    movapd %xmm0,%xmm6
    movapd %xmm1,%xmm7
    movapd %xmm2,%xmm8

    subpd nb113_ixH1(%rsp),%xmm0
    subpd nb113_iyH1(%rsp),%xmm1
    subpd nb113_izH1(%rsp),%xmm2
    subpd nb113_ixH2(%rsp),%xmm3
    subpd nb113_iyH2(%rsp),%xmm4
    subpd nb113_izH2(%rsp),%xmm5
    subpd nb113_ixM(%rsp),%xmm6
    subpd nb113_iyM(%rsp),%xmm7
    subpd nb113_izM(%rsp),%xmm8

        movapd %xmm0,nb113_dxH1(%rsp)
        movapd %xmm1,nb113_dyH1(%rsp)
        movapd %xmm2,nb113_dzH1(%rsp)
        mulpd  %xmm0,%xmm0
        mulpd  %xmm1,%xmm1
        mulpd  %xmm2,%xmm2
        movapd %xmm3,nb113_dxH2(%rsp)
        movapd %xmm4,nb113_dyH2(%rsp)
        movapd %xmm5,nb113_dzH2(%rsp)
        mulpd  %xmm3,%xmm3
        mulpd  %xmm4,%xmm4
        mulpd  %xmm5,%xmm5
        movapd %xmm6,nb113_dxM(%rsp)
        movapd %xmm7,nb113_dyM(%rsp)
        movapd %xmm8,nb113_dzM(%rsp)
        mulpd  %xmm6,%xmm6
        mulpd  %xmm7,%xmm7
        mulpd  %xmm8,%xmm8
        addpd  %xmm1,%xmm0
        addpd  %xmm2,%xmm0
        addpd  %xmm4,%xmm3
        addpd  %xmm5,%xmm3
    addpd  %xmm7,%xmm6
    addpd  %xmm8,%xmm6

        ## start doing invsqrt for j atoms
    cvtpd2ps %xmm0,%xmm1
    cvtpd2ps %xmm3,%xmm4
    cvtpd2ps %xmm6,%xmm7
        rsqrtps %xmm1,%xmm1
        rsqrtps %xmm4,%xmm4
    rsqrtps %xmm7,%xmm7
    cvtps2pd %xmm1,%xmm1
    cvtps2pd %xmm4,%xmm4
    cvtps2pd %xmm7,%xmm7

        movapd  %xmm1,%xmm2
        movapd  %xmm4,%xmm5
    movapd  %xmm7,%xmm8

        mulpd   %xmm1,%xmm1 ## lu*lu
        mulpd   %xmm4,%xmm4 ## lu*lu
    mulpd   %xmm7,%xmm7 ## lu*lu

        movapd  nb113_three(%rsp),%xmm9
        movapd  %xmm9,%xmm10
    movapd  %xmm9,%xmm11

        mulpd   %xmm0,%xmm1 ## rsq*lu*lu
        mulpd   %xmm3,%xmm4 ## rsq*lu*lu 
    mulpd   %xmm6,%xmm7 ## rsq*lu*lu

        subpd   %xmm1,%xmm9
        subpd   %xmm4,%xmm10
    subpd   %xmm7,%xmm11 ## 3-rsq*lu*lu

        mulpd   %xmm2,%xmm9
        mulpd   %xmm5,%xmm10
    mulpd   %xmm8,%xmm11 ## lu*(3-rsq*lu*lu)

        movapd  nb113_half(%rsp),%xmm15
        mulpd   %xmm15,%xmm9 ## first iteration for rinvH1
        mulpd   %xmm15,%xmm10 ## first iteration for rinvH2
    mulpd   %xmm15,%xmm11 ## first iteration for rinvM

    ## second iteration step    
        movapd  %xmm9,%xmm2
        movapd  %xmm10,%xmm5
    movapd  %xmm11,%xmm8

        mulpd   %xmm2,%xmm2 ## lu*lu
        mulpd   %xmm5,%xmm5 ## lu*lu
    mulpd   %xmm8,%xmm8 ## lu*lu

        movapd  nb113_three(%rsp),%xmm1
        movapd  %xmm1,%xmm4
    movapd  %xmm1,%xmm7

        mulpd   %xmm0,%xmm2 ## rsq*lu*lu
        mulpd   %xmm3,%xmm5 ## rsq*lu*lu 
    mulpd   %xmm6,%xmm8 ## rsq*lu*lu

        subpd   %xmm2,%xmm1
        subpd   %xmm5,%xmm4
    subpd   %xmm8,%xmm7 ## 3-rsq*lu*lu

        mulpd   %xmm1,%xmm9
        mulpd   %xmm4,%xmm10
    mulpd   %xmm7,%xmm11 ## lu*(3-rsq*lu*lu)

        movapd  nb113_half(%rsp),%xmm15
        mulpd   %xmm15,%xmm9 ##  rinvH1
        mulpd   %xmm15,%xmm10 ##   rinvH2
    mulpd   %xmm15,%xmm11 ##   rinvM

        ## interactions 
    movapd %xmm9,%xmm0
    movapd %xmm10,%xmm1
    movapd %xmm11,%xmm2
    mulpd  %xmm9,%xmm9
    mulpd  %xmm10,%xmm10
    mulpd  %xmm11,%xmm11
    mulpd  nb113_qqH(%rsp),%xmm0
    mulpd  nb113_qqH(%rsp),%xmm1
    mulpd  nb113_qqM(%rsp),%xmm2
    mulpd  %xmm0,%xmm9
    mulpd  %xmm1,%xmm10
    mulpd  %xmm2,%xmm11

    addpd nb113_vctot(%rsp),%xmm0
    addpd %xmm2,%xmm1
    addpd %xmm1,%xmm0
    movapd %xmm0,nb113_vctot(%rsp)

    ## move j forces to xmm0-xmm2
    movq nb113_faction(%rbp),%rdi
        movlpd (%rdi,%rax,8),%xmm0
        movlpd 8(%rdi,%rax,8),%xmm1
        movlpd 16(%rdi,%rax,8),%xmm2
        movhpd (%rdi,%rbx,8),%xmm0
        movhpd 8(%rdi,%rbx,8),%xmm1
        movhpd 16(%rdi,%rbx,8),%xmm2

    movapd %xmm9,%xmm7
    movapd %xmm9,%xmm8
    movapd %xmm11,%xmm13
    movapd %xmm11,%xmm14
    movapd %xmm11,%xmm15
    movapd %xmm10,%xmm11
    movapd %xmm10,%xmm12

    ## add forces from O interaction
    addpd nb113_fjx(%rsp),%xmm0
    addpd nb113_fjy(%rsp),%xmm1
    addpd nb113_fjz(%rsp),%xmm2

        mulpd nb113_dxH1(%rsp),%xmm7
        mulpd nb113_dyH1(%rsp),%xmm8
        mulpd nb113_dzH1(%rsp),%xmm9
        mulpd nb113_dxH2(%rsp),%xmm10
        mulpd nb113_dyH2(%rsp),%xmm11
        mulpd nb113_dzH2(%rsp),%xmm12
        mulpd nb113_dxM(%rsp),%xmm13
        mulpd nb113_dyM(%rsp),%xmm14
        mulpd nb113_dzM(%rsp),%xmm15

    addpd %xmm7,%xmm0
    addpd %xmm8,%xmm1
    addpd %xmm9,%xmm2
    addpd nb113_fixH1(%rsp),%xmm7
    addpd nb113_fiyH1(%rsp),%xmm8
    addpd nb113_fizH1(%rsp),%xmm9

    addpd %xmm10,%xmm0
    addpd %xmm11,%xmm1
    addpd %xmm12,%xmm2
    addpd nb113_fixH2(%rsp),%xmm10
    addpd nb113_fiyH2(%rsp),%xmm11
    addpd nb113_fizH2(%rsp),%xmm12

    addpd %xmm13,%xmm0
    addpd %xmm14,%xmm1
    addpd %xmm15,%xmm2
    addpd nb113_fixM(%rsp),%xmm13
    addpd nb113_fiyM(%rsp),%xmm14
    addpd nb113_fizM(%rsp),%xmm15

    movapd %xmm7,nb113_fixH1(%rsp)
    movapd %xmm8,nb113_fiyH1(%rsp)
    movapd %xmm9,nb113_fizH1(%rsp)
    movapd %xmm10,nb113_fixH2(%rsp)
    movapd %xmm11,nb113_fiyH2(%rsp)
    movapd %xmm12,nb113_fizH2(%rsp)
    movapd %xmm13,nb113_fixM(%rsp)
    movapd %xmm14,nb113_fiyM(%rsp)
    movapd %xmm15,nb113_fizM(%rsp)

    ## store back j forces from xmm0-xmm2
        movlpd %xmm0,(%rdi,%rax,8)
        movlpd %xmm1,8(%rdi,%rax,8)
        movlpd %xmm2,16(%rdi,%rax,8)
        movhpd %xmm0,(%rdi,%rbx,8)
        movhpd %xmm1,8(%rdi,%rbx,8)
        movhpd %xmm2,16(%rdi,%rbx,8)

        ## should we do one more iteration? 
        subl $2,nb113_innerk(%rsp)
        jl   _nb_kernel113_x86_64_sse2.nb113_checksingle
        jmp  _nb_kernel113_x86_64_sse2.nb113_unroll_loop
_nb_kernel113_x86_64_sse2.nb113_checksingle: 
        movl  nb113_innerk(%rsp),%edx
        andl  $1,%edx
        jnz  _nb_kernel113_x86_64_sse2.nb113_dosingle
        jmp  _nb_kernel113_x86_64_sse2.nb113_updateouterdata
_nb_kernel113_x86_64_sse2.nb113_dosingle: 
        movq  nb113_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        addq $4,nb113_innerjjnr(%rsp)

        movq nb113_charge(%rbp),%rsi     ## base of charge[] 

        xorpd %xmm3,%xmm3
        movlpd (%rsi,%rax,8),%xmm3
        movapd %xmm3,%xmm4
        mulpd  nb113_iqM(%rsp),%xmm3
        mulpd  nb113_iqH(%rsp),%xmm4

        movapd  %xmm3,nb113_qqM(%rsp)
        movapd  %xmm4,nb113_qqH(%rsp)

        movq nb113_type(%rbp),%rsi
        movl (%rsi,%rax,4),%r8d
        movq nb113_vdwparam(%rbp),%rsi
        shll %r8d
        movl nb113_ntia(%rsp),%edi
        addl %edi,%r8d

        movsd (%rsi,%r8,8),%xmm6        ## c6a
    movsd 8(%rsi,%r8,8),%xmm7           ## c12a         
        movapd %xmm6,nb113_c6(%rsp)
        movapd %xmm7,nb113_c12(%rsp)

        movq nb113_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 

        ## move coordinates to xmm0-xmm2  and xmm4-xmm6
        movlpd (%rsi,%rax,8),%xmm4
        movlpd 8(%rsi,%rax,8),%xmm5
        movlpd 16(%rsi,%rax,8),%xmm6
    movapd %xmm4,%xmm0
    movapd %xmm5,%xmm1
    movapd %xmm6,%xmm2

        ## calc dr 
        subsd nb113_ixO(%rsp),%xmm4
        subsd nb113_iyO(%rsp),%xmm5
        subsd nb113_izO(%rsp),%xmm6

        ## store dr 
        movapd %xmm4,nb113_dxO(%rsp)
        movapd %xmm5,nb113_dyO(%rsp)
        movapd %xmm6,nb113_dzO(%rsp)
        ## square it 
        mulsd %xmm4,%xmm4
        mulsd %xmm5,%xmm5
        mulsd %xmm6,%xmm6
        addsd %xmm5,%xmm4
        addsd %xmm6,%xmm4
        movapd %xmm4,%xmm7
        ## rsqO in xmm7 

        ## move j coords to xmm4-xmm6 
        movapd %xmm0,%xmm4
        movapd %xmm1,%xmm5
        movapd %xmm2,%xmm6

        ## calc dr 
        subsd nb113_ixH1(%rsp),%xmm4
        subsd nb113_iyH1(%rsp),%xmm5
        subsd nb113_izH1(%rsp),%xmm6

        ## store dr 
        movapd %xmm4,nb113_dxH1(%rsp)
        movapd %xmm5,nb113_dyH1(%rsp)
        movapd %xmm6,nb113_dzH1(%rsp)
        ## square it 
        mulsd %xmm4,%xmm4
        mulsd %xmm5,%xmm5
        mulsd %xmm6,%xmm6
        addsd %xmm5,%xmm6
        addsd %xmm4,%xmm6
        ## rsqH1 in xmm6 

        ## move j coords to xmm3-xmm5
        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5

        ## calc dr 
        subsd nb113_ixH2(%rsp),%xmm3
        subsd nb113_iyH2(%rsp),%xmm4
        subsd nb113_izH2(%rsp),%xmm5


        ## store dr 
        movapd %xmm3,nb113_dxH2(%rsp)
        movapd %xmm4,nb113_dyH2(%rsp)
        movapd %xmm5,nb113_dzH2(%rsp)
        ## square it 
        mulsd %xmm3,%xmm3
        mulsd %xmm4,%xmm4
        mulsd %xmm5,%xmm5
        addsd %xmm4,%xmm5
        addsd %xmm3,%xmm5

        ## move j coords to xmm4-xmm2
        movapd %xmm0,%xmm4
        movapd %xmm1,%xmm3
    ## xmm2 already contains z

        ## calc dr 
        subsd nb113_ixM(%rsp),%xmm4
        subsd nb113_iyM(%rsp),%xmm3
        subsd nb113_izM(%rsp),%xmm2

        ## store dr 
        movapd %xmm4,nb113_dxM(%rsp)
        movapd %xmm3,nb113_dyM(%rsp)
        movapd %xmm2,nb113_dzM(%rsp)

        ## square it 
        mulpd %xmm2,%xmm2
        mulpd %xmm3,%xmm3
        mulpd %xmm4,%xmm4
        addpd %xmm3,%xmm4
        addpd %xmm2,%xmm4
        ## rsqM in xmm4, rsqH2 in xmm5, rsqH1 in xmm6, rsqO in xmm7 

        ## start with rsqH1 - put seed in xmm2 
        cvtsd2ss %xmm6,%xmm2
        rsqrtss %xmm2,%xmm2
        cvtss2sd %xmm2,%xmm2

        movapd  %xmm2,%xmm3
        mulsd   %xmm2,%xmm2
        movapd  nb113_three(%rsp),%xmm1
        mulsd   %xmm6,%xmm2     ## rsq*lu*lu