nb_kernel332_ia32_3dnow.intel_syntax.s

最著名最快的分子模拟软件

	pfadd mm7, mm5	;# mm7=FF 

	pfmul mm5, mm0  ;# mm5=eps*Fp 
	pfadd mm5, mm4	;#  mm5= VV 

	pfmul mm5, [esp + nb332_qqHH]	;# vcoul=qq*VV 
	pfmul mm7, [esp + nb332_qqHH]	;# fijC=qq*FF 
	;# update vctot 
	pfadd mm5, [esp + nb332_vctot]
	movq [esp + nb332_vctot], mm5
	
	;# change sign of fijC and multiply by rinv 
    pxor mm4,mm4
	pfsub mm4, mm7	
	pfmul mm4, [esp + nb332_tsc]
 	pfmul mm4, mm1    ;# mm4 is total fscal (for the hydrogens) now 	

	;# spread oxygen fscalar to both positions 
	punpckldq mm3,mm3
	;# calc vectorial force for O 
	movq mm0,  [esp + nb332_dxO]
	movd mm1,  [esp + nb332_dzO]
	pfmul mm0, mm3
	pfmul mm1, mm3

	;# calc vectorial force for H's 
	movq mm5, [esp + nb332_dxH]
	movq mm6, [esp + nb332_dyH]
	movq mm7, [esp + nb332_dzH]
	pfmul mm5, mm4
	pfmul mm6, mm4
	pfmul mm7, mm4
	
	;# update iO particle force 
	movq mm2,  [esp + nb332_fixO]
	movd mm3,  [esp + nb332_fizO]
	pfadd mm2, mm0
	pfadd mm3, mm1
	movq [esp + nb332_fixO], mm2
	movd [esp + nb332_fizO], mm3

	;# update iH forces 
	movq mm2, [esp + nb332_fixH]
	movq mm3, [esp + nb332_fiyH]
	movq mm4, [esp + nb332_fizH]
	pfadd mm2, mm5
	pfadd mm3, mm6
	pfadd mm4, mm7
	movq [esp + nb332_fixH], mm2
	movq [esp + nb332_fiyH], mm3
	movq [esp + nb332_fizH], mm4	

	;# pack j forces from H in the same form as the oxygen force. 
	pfacc mm5, mm6		;# mm5(l)=fjx(H1+ h2) mm5(h)=fjy(H1+ h2) 
	pfacc mm7, mm7		;# mm7(l)=fjz(H1+ h2) 
	
	pfadd mm0, mm5		;# add up total force on j particle.  
	pfadd mm1, mm7

	;# update j particle force 
	movq mm2,  [edi + eax*4 + 24]
	movd mm3,  [edi + eax*4 + 32]
	pfsub mm2, mm0
	pfsub mm3, mm1
	movq [edi + eax*4 + 24], mm2
	movd [edi + eax*4 + 32], mm3
	
	;#  done  - one more? 
	dec dword ptr [esp + nb332_innerk]
	jz  .nb332_updateouterdata
	jmp .nb332_inner_loop	
.nb332_updateouterdata:	
	mov   ecx, [esp + nb332_ii3]

	movq  mm6, [edi + ecx*4]       ;# increment iO force  
	movd  mm7, [edi + ecx*4 + 8]	
	pfadd mm6, [esp + nb332_fixO]
	pfadd mm7, [esp + nb332_fizO]
	movq  [edi + ecx*4],    mm6
	movd  [edi + ecx*4 +8], mm7

	movq  mm0, [esp + nb332_fixH]
	movq  mm3, [esp + nb332_fiyH]
	movq  mm1, [esp + nb332_fizH]
	movq  mm2, mm0
	punpckldq mm0, mm3	;# mm0(l)=fxH1, mm0(h)=fyH1 
	punpckhdq mm2, mm3	;# mm2(l)=fxH2, mm2(h)=fyH2 
	movq mm3, mm1
	pswapd mm3,mm3		
	;# mm1 is fzH1 
	;# mm3 is fzH2 

	movq  mm6, [edi + ecx*4 + 12]       ;# increment iH1 force  
	movd  mm7, [edi + ecx*4 + 20] 	
	pfadd mm6, mm0
	pfadd mm7, mm1
	movq  [edi + ecx*4 + 12],  mm6
	movd  [edi + ecx*4 + 20],  mm7
	
	movq  mm6, [edi + ecx*4 + 24]       ;# increment iH2 force 
	movd  mm7, [edi + ecx*4 + 32] 	
	pfadd mm6, mm2
	pfadd mm7, mm3
	movq  [edi + ecx*4 + 24],  mm6
	movd  [edi + ecx*4 + 32],  mm7

	
	mov   ebx, [ebp + nb332_fshift]    ;# increment fshift force 
	mov   edx, [esp + nb332_is3]

	movq  mm6, [ebx + edx*4]	
	movd  mm7, [ebx + edx*4 + 8]	
	pfadd mm6, [esp + nb332_fixO]
	pfadd mm7, [esp + nb332_fizO]
	pfadd mm6, mm0
	pfadd mm7, mm1
	pfadd mm6, mm2
	pfadd mm7, mm3
	movq  [ebx + edx*4],     mm6
	movd  [ebx + edx*4 + 8], mm7
	
	;# get n from stack
	mov esi, [esp + nb332_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb332_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	movq  mm7, [esp + nb332_vctot]     
	pfacc mm7,mm7	          ;# get and sum the two parts of total potential 

	mov   eax, [ebp + nb332_Vc]
	movd  mm6, [eax + edx*4] 
	pfadd mm6, mm7
	movd  [eax + edx*4], mm6          ;# increment vc[gid] 

	movq  mm7, [esp + nb332_Vvdwtot]     
	pfacc mm7,mm7	          ;# get and sum the two parts of total potential 

	mov   eax, [ebp + nb332_Vvdw]
	movd  mm6, [eax + edx*4] 
	pfadd mm6, mm7
	movd  [eax + edx*4], mm6          ;# increment Vvdwtot[gid] 
       	;# finish if last 
        mov ecx, [esp + nb332_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jecxz .nb332_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb332_n], esi
        jmp .nb332_outer
.nb332_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb332_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jecxz .nb332_end
        ;# non-zero, do one more workunit
        jmp   .nb332_threadloop
.nb332_end:
	femms
	mov eax, [esp + nb332_nouter] 	
	mov ebx, [esp + nb332_ninner]
	mov ecx, [ebp + nb332_outeriter]
	mov edx, [ebp + nb332_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	add esp, 232
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret



.globl nb_kernel332nf_ia32_3dnow
.globl _nb_kernel332nf_ia32_3dnow
nb_kernel332nf_ia32_3dnow:	
_nb_kernel332nf_ia32_3dnow:	
.equiv		nb332nf_p_nri,		8
.equiv		nb332nf_iinr,		12
.equiv		nb332nf_jindex,		16
.equiv		nb332nf_jjnr,		20
.equiv		nb332nf_shift,		24
.equiv		nb332nf_shiftvec,	28
.equiv		nb332nf_fshift,		32
.equiv		nb332nf_gid,		36
.equiv		nb332nf_pos,		40		
.equiv		nb332nf_faction,	44
.equiv		nb332nf_charge,		48
.equiv		nb332nf_p_facel,	52
.equiv		nb332nf_p_krf,		56	
.equiv		nb332nf_p_crf,		60	
.equiv		nb332nf_Vc,		64	
.equiv		nb332nf_type,		68
.equiv		nb332nf_p_ntype,	72
.equiv		nb332nf_vdwparam,	76	
.equiv		nb332nf_Vvdw,		80	
.equiv		nb332nf_p_tabscale,	84	
.equiv		nb332nf_VFtab,		88
.equiv		nb332nf_invsqrta,	92	
.equiv		nb332nf_dvda,		96
.equiv          nb332nf_p_gbtabscale,   100
.equiv          nb332nf_GBtab,          104
.equiv          nb332nf_p_nthreads,     108
.equiv          nb332nf_count,          112
.equiv          nb332nf_mtx,            116
.equiv          nb332nf_outeriter,      120
.equiv          nb332nf_inneriter,      124
.equiv          nb332nf_work,           128
			;# stack offsets for local variables 
.equiv		nb332nf_is3,		0
.equiv		nb332nf_ii3,		4
.equiv		nb332nf_ixO,		8
.equiv		nb332nf_iyO,		12
.equiv		nb332nf_izO,		16	
.equiv		nb332nf_ixH,		20  
.equiv		nb332nf_iyH,		28  
.equiv		nb332nf_izH,		36  
.equiv		nb332nf_qqOO,		44  
.equiv		nb332nf_qqOH,		52  
.equiv		nb332nf_qqHH,		60  
.equiv		nb332nf_c6,		68  
.equiv		nb332nf_c12,		76 
.equiv		nb332nf_n1,		84  
.equiv		nb332nf_tsc,		92 
.equiv		nb332nf_vctot,		100 
.equiv		nb332nf_Vvdwtot,	108 
.equiv		nb332nf_innerjjnr,	116
.equiv		nb332nf_innerk,		120
.equiv		nb332nf_tmprsqH,	124  
.equiv          nb332nf_n,              132 ;# idx for outer loop
.equiv          nb332nf_nn1,            136 ;# number of outer iterations
.equiv          nb332nf_nri,            140
.equiv          nb332nf_nouter,         144
.equiv          nb332nf_ninner,         148
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp, 152		;# local stack space 
	femms
	mov ecx, [ebp + nb332nf_p_nri]
	mov esi, [ebp + nb332nf_p_facel]
	mov edi, [ebp + nb332nf_p_tabscale]
	mov ecx, [ecx]
	mov [esp + nb332nf_nri], ecx
	movd  mm1, [esi] 	;# facel
	mov esi, [ebp + nb332nf_p_ntype]

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb332nf_nouter], eax
	mov [esp + nb332nf_ninner], eax

	;# assume we have at least one i particle - start directly 	

	mov   ecx, [ebp + nb332nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx=ii 

	mov   edx, [ebp + nb332nf_charge]
	movd  mm2, [edx + ebx*4]    ;# mm2=charge[ii0] (O) 
	movd  mm3, [edx + ebx*4 + 4]    ;# mm2=charge[ii0+1] (H)  
	movq  mm4, mm2	
	pfmul mm4, mm1
	movq  mm6, mm3
	pfmul mm6, mm1
	movq  mm5, mm4
	pfmul mm4, mm2			;# mm4=qqOO*facel 
	pfmul mm5, mm3			;# mm5=qqOH*facel 
	pfmul mm6, mm3			;# mm6=qqHH*facel 
	punpckldq mm5,mm5	    ;# spread to both halves 
	punpckldq mm6,mm6	    ;# spread to both halves 
	movq  [esp + nb332nf_qqOO], mm4
	movq  [esp + nb332nf_qqOH], mm5
	movq  [esp + nb332nf_qqHH], mm6
	mov   edx, [ebp + nb332nf_type]
	mov   ecx, [edx + ebx*4]
	shl   ecx, 1
	mov   edx, ecx
	imul  ecx, [esi]
	add   edx, ecx
	mov   eax, [ebp + nb332nf_vdwparam]
	movd  mm0, [eax + edx*4]
	movd  mm1, [eax + edx*4 + 4]
	movq  [esp + nb332nf_c6], mm0
	movq  [esp + nb332nf_c12], mm1
	movd  mm3, [edi]
	punpckldq mm3,mm3
	movq  [esp + nb332nf_tsc], mm3
.nb332nf_threadloop:
        mov   esi, [ebp + nb332nf_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb332nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb332nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb332nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb332nf_n], eax
        mov [esp + nb332nf_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb332nf_outerstart
        jmp .nb332nf_end

.nb332nf_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb332nf_nouter]
        mov [esp + nb332nf_nouter], ebx
	
.nb332nf_outer:
	mov   eax, [ebp + nb332nf_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax+esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb332nf_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb332nf_shiftvec]   ;# eax = base of shiftvec[] 
	
	movq  mm5, [eax + ebx*4]	;# move shX/shY to mm5 and shZ to mm6. 
	movd  mm6, [eax + ebx*4 + 8]
	movq  mm0, mm5
	movq  mm1, mm5
	movq  mm2, mm6
	punpckldq mm0,mm0	    ;# also expand shX,Y,Z in mm0--mm2. 
	punpckhdq mm1,mm1
	punpckldq mm2,mm2		
	
	mov   ecx, [ebp + nb332nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx+esi*4]	    ;# ebx=ii 

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb332nf_pos]    ;# eax = base of pos[] 

	pfadd mm5, [eax + ebx*4]    ;# ix = shX + posX (and iy too) 
	movd  mm7, [eax + ebx*4 + 8]    ;# cant use direct memory add for 4 bytes (iz) 
	mov   [esp + nb332nf_ii3], ebx	    ;# (use mm7 as temp. storage for iz.) 
	pfadd mm6, mm7
	movq  [esp + nb332nf_ixO], mm5	
	movq  [esp + nb332nf_izO], mm6

	movd  mm3, [eax + ebx*4 + 12]
	movd  mm4, [eax + ebx*4 + 16]
	movd  mm5, [eax + ebx*4 + 20]
	punpckldq  mm3, [eax + ebx*4 + 24]
	punpckldq  mm4, [eax + ebx*4 + 28]
	punpckldq  mm5, [eax + ebx*4 + 32] ;# coords of H1 in low mm3-mm5, H2 in high 
	
	pfadd mm0, mm3
	pfadd mm1, mm4
	pfadd mm2, mm5		
	movq [esp + nb332nf_ixH], mm0	
	movq [esp + nb332nf_iyH], mm1	
	movq [esp + nb332nf_izH], mm2	

	;# clear vctot and i forces 
	pxor  mm7,mm7
	movq  [esp + nb332nf_vctot], mm7
	movq  [esp + nb332nf_Vvdwtot], mm7

	mov   eax, [ebp + nb332nf_jindex]
	mov   ecx, [eax+esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 
	mov   [esp + nb332nf_innerk], edx        
	add   edx, [esp + nb332nf_ninner]
	mov   [esp + nb332nf_ninner], edx

	mov   esi, [ebp + nb332nf_pos]	
	mov   eax, [ebp + nb332nf_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb332nf_innerjjnr], eax     ;# pointer to jjnr[nj0] 
.nb332nf_inner_loop:
	;# a single j particle iteration here - compare with the unrolled code for comments. 
	mov   eax, [esp + nb332nf_innerjjnr]
	mov   eax, [eax]	;# eax=jnr offset 
    add dword ptr [esp + nb332nf_innerjjnr],  4 ;# advance pointer 

	lea   eax, [eax + eax*2]

	movq  mm0, [esi + eax*4]
	movd  mm1, [esi + eax*4 + 8]
	;# copy & expand to mm2-mm4 for the H interactions 
	movq  mm2, mm0
	movq  mm3, mm0
	movq  mm4, mm1
	punpckldq mm2,mm2
	punpckhdq mm3,mm3
	punpckldq mm4,mm4
	
	pfsubr mm0, [esp + nb332nf_ixO]
	pfsubr mm1, [esp + nb332nf_izO]
		
	pfmul mm0,mm0
	pfmul mm1,mm1
	pfacc mm0, mm0
	pfadd mm0, mm1		;# mm0=rsqO 
	
	punpckldq mm2, mm2
	punpckldq mm3, mm3
	punpckldq mm4, mm4  ;# mm2-mm4 is jx-jz 
	pfsubr mm2, [esp + nb332nf_ixH]
	pfsubr mm3, [esp + nb332nf_iyH]
	pfsubr mm4, [esp + nb332nf_izH] ;# mm2-mm4 is dxH-dzH 
	
	pfmul mm2,mm2
	pfmul mm3,mm3
	pfmul mm4,mm4

	pfadd mm3,mm2
	pfadd mm3,mm4		;# mm3=rsqH 
	movq [esp + nb332nf_tmprsqH], mm3

    pfrsqrt mm1,mm0

    movq mm2,mm1
    pfmul mm1,mm1
    pfrsqit1 mm1,mm0				
    pfrcpit2 mm1,mm2	;# mm1=invsqrt  
	pfmul mm0, mm1		;# mm0=rsq  

	pfmul mm0, [esp + nb332nf_tsc]
	pf2iw mm4, mm0
	movd [esp + nb332nf_n1], mm4
	pi2fd mm4,mm4
	pfsub mm0, mm4               ;# now mm0 is eps and mm4 n0 
	movq  mm2, mm0
	pfmul mm2, mm2		;# mm0 is eps, mm2 eps2