nb_kernel331_ia32_3dnow.intel_syntax.s

最著名最快的分子模拟软件

	;# update vctot directly, use mm3 for fscal sum. 
	pfadd mm5, [esp + nb331_vctot]
	movq [esp + nb331_vctot], mm5
	movq mm3, mm7
	
	;# dispersion table 
	;# load all the table values we need 
	movd mm4, [edx + ecx*4 + 16]
	movd mm5, [edx + ecx*4 + 20]
	movd mm6, [edx + ecx*4 + 24]
	movd mm7, [edx + ecx*4 + 28]
	pfmul mm6, mm0  ;# mm6 = Geps 		
	pfmul mm7, mm2	;# mm7 = Heps2 
	pfadd mm5, mm6
	pfadd mm5, mm7	;# mm5 = Fp 
	pfmul mm7, [esp + nb331_two]	;# two*Heps2 
	pfadd mm7, mm6
	pfadd mm7, mm5	;# mm7=FF 
	pfmul mm5, mm0  ;# mm5=eps*Fp 
	pfadd mm5, mm4	;#  mm5= VV 	

	movq mm4, [esp + nb331_c6]
	pfmul mm7, mm4	;# fijD 
	pfmul mm5, mm4	;# Vvdw6            
	pfadd mm3, mm7	;# add to fscal  

	;# update Vvdwtot to release mm5! 
	pfadd mm5, [esp + nb331_Vvdwtot]      ;# add the earlier value 
	movq [esp + nb331_Vvdwtot], mm5       ;# store the sum       

	;# repulsion table 
	;# load all the table values we need 
	movd mm4, [edx + ecx*4 + 32]
	movd mm5, [edx + ecx*4 + 36]
	movd mm6, [edx + ecx*4 + 40]
	movd mm7, [edx + ecx*4 + 44]

	pfmul mm6, mm0  ;# mm6 = Geps 		
	pfmul mm7, mm2	;# mm7 = Heps2 
	pfadd mm5, mm6
	pfadd mm5, mm7	;# mm5 = Fp 
	pfmul mm7, [esp + nb331_two]	;# two*Heps2 
	pfadd mm7, mm6
	pfadd mm7, mm5	;# mm7=FF 
	pfmul mm5, mm0  ;# mm5=eps*Fp 
	pfadd mm5, mm4	;#  mm5= VV 

	movq mm6, [esp + nb331_c12]
	pfmul mm7, mm6	;# fijR 
	pfmul mm5, mm6	;# Vvdw12 
	pfadd mm3, mm7	;# total fscal fijC+ fijD+ fijR 

	;# change sign of fscal and multiply with rinv  
    pxor mm0,mm0
	pfsubr mm3, mm0	
	pfmul mm3, [esp + nb331_tsc]
 	pfmul mm3, mm1    ;# mm3 is total fscal (for the oxygen) now 
	
	;# update Vvdwtot  
	pfadd mm5, [esp + nb331_Vvdwtot]      ;# add the earlier value 
	movq [esp + nb331_Vvdwtot], mm5       ;# store the sum       
	
	;# Ready with the oxygen - potential is updated, fscal is in mm3. 
	;# now do the two hydrogens. 
	movq mm0, [esp + nb331_tmprsqH] ;# mm0=rsqH 

	pfrsqrt mm1, mm0
	pswapd mm0,mm0
	pfrsqrt mm2, mm0
	pswapd mm0,mm0
	punpckldq mm1,mm2	;# seeds are in mm1 now, and rsq in mm0. 

	movq mm2, mm1
	pfmul mm1,mm1
    pfrsqit1 mm1,mm0				
    pfrcpit2 mm1,mm2	;# mm1=invsqrt 
	
	pfmul mm0,mm1		;# mm0=r 
	pfmul mm0, [esp + nb331_tsc]
	pf2iw mm4, mm0
	movq [esp + nb331_n1], mm4
	pi2fd mm4,mm4
	pfsub mm0, mm4               ;# now mm0 is eps and mm4 n0 
	movq  mm2, mm0
	pfmul mm2, mm2		;# mm0 is eps, mm2 eps2 
	
	;# coulomb table 
	mov edx, [ebp + nb331_VFtab]
	mov ecx, [esp + nb331_n1]
	lea ecx, [ecx + ecx*2]
	shl ecx, 2
	;# load all values we need 
	movd mm4, [edx + ecx*4]
	movd mm5, [edx + ecx*4 + 4]
	movd mm6, [edx + ecx*4 + 8]
	movd mm7, [edx + ecx*4 + 12]
	mov ecx, [esp + nb331_n1+4]
	lea ecx, [ecx + ecx*2]
	shl ecx, 2
	punpckldq mm4, [edx + ecx*4]
	punpckldq mm5, [edx + ecx*4 + 4]
	punpckldq mm6, [edx + ecx*4 + 8]
	punpckldq mm7, [edx + ecx*4 + 12]

	
	pfmul mm6, mm0  ;# mm6 = Geps 		
	pfmul mm7, mm2	;# mm7 = Heps2 
	
	pfadd mm5, mm6
	pfadd mm5, mm7	;# mm5 = Fp 

	pfmul mm7, [esp + nb331_two]	;# two*Heps2 
	pfadd mm7, mm6
	pfadd mm7, mm5	;# mm7=FF 

	pfmul mm5, mm0  ;# mm5=eps*Fp 
	pfadd mm5, mm4	;#  mm5= VV 

	pfmul mm5, [esp + nb331_qqH]	;# vcoul=qq*VV 
	pfmul mm7, [esp + nb331_qqH]	;# fijC=qq*FF 
	;# update vctot 
	pfadd mm5, [esp + nb331_vctot]
	movq [esp + nb331_vctot], mm5
	
	;# change sign of fijC and multiply by rinv 
    pxor mm4,mm4
	pfsub mm4, mm7	
	pfmul mm4, [esp + nb331_tsc]
 	pfmul mm4, mm1    ;# mm4 is total fscal (for the hydrogens) now 	
	
	;# spread oxygen fscalar to both positions 
	punpckldq mm3,mm3
	;# calc vectorial force for O 
	prefetchw [edi + eax*4]	;# prefetch faction to cache  
	movq mm0,  [esp + nb331_dxO]
	movd mm1,  [esp + nb331_dzO]
	pfmul mm0, mm3
	pfmul mm1, mm3

	;# calc vectorial force for H's 
	movq mm5, [esp + nb331_dxH]
	movq mm6, [esp + nb331_dyH]
	movq mm7, [esp + nb331_dzH]
	pfmul mm5, mm4
	pfmul mm6, mm4
	pfmul mm7, mm4
	
	;# update iO particle force 
	movq mm2,  [esp + nb331_fixO]
	movd mm3,  [esp + nb331_fizO]
	pfadd mm2, mm0
	pfadd mm3, mm1
	movq [esp + nb331_fixO], mm2
	movd [esp + nb331_fizO], mm3

	;# update iH forces 
	movq mm2, [esp + nb331_fixH]
	movq mm3, [esp + nb331_fiyH]
	movq mm4, [esp + nb331_fizH]
	pfadd mm2, mm5
	pfadd mm3, mm6
	pfadd mm4, mm7
	movq [esp + nb331_fixH], mm2
	movq [esp + nb331_fiyH], mm3
	movq [esp + nb331_fizH], mm4
	
	;# pack j forces from H in the same form as the oxygen force. 
	pfacc mm5, mm6		;# mm5(l)=fjx(H1+ h2) mm5(h)=fjy(H1+ h2) 
	pfacc mm7, mm7		;# mm7(l)=fjz(H1+ h2) 
	
	pfadd mm0, mm5		;# add up total force on j particle.  
	pfadd mm1, mm7

	;# update j particle force 
	movq mm2,  [edi + eax*4]
	movd mm3,  [edi + eax*4 + 8]
	pfsub mm2, mm0
	pfsub mm3, mm1
	movq [edi + eax*4], mm2
	movd [edi + eax*4 +8], mm3
	
	;#  done  - one more? 
	dec dword ptr [esp + nb331_innerk]
	jz  .nb331_updateouterdata
	jmp .nb331_inner_loop
.nb331_updateouterdata:	
	mov   ecx, [esp + nb331_ii3]

	movq  mm6, [edi + ecx*4]       ;# increment iO force  
	movd  mm7, [edi + ecx*4 + 8]	
	pfadd mm6, [esp + nb331_fixO]
	pfadd mm7, [esp + nb331_fizO]
	movq  [edi + ecx*4],    mm6
	movd  [edi + ecx*4 +8], mm7

	movq  mm0, [esp + nb331_fixH]
	movq  mm3, [esp + nb331_fiyH]
	movq  mm1, [esp + nb331_fizH]
	movq  mm2, mm0
	punpckldq mm0, mm3	;# mm0(l)=fxH1, mm0(h)=fyH1 
	punpckhdq mm2, mm3	;# mm2(l)=fxH2, mm2(h)=fyH2 
	movq mm3, mm1
	pswapd mm3,mm3		
	;# mm1 is fzH1 
	;# mm3 is fzH2 
	
	movq  mm6, [edi + ecx*4 + 12]       ;# increment iH1 force  
	movd  mm7, [edi + ecx*4 + 20] 	
	pfadd mm6, mm0
	pfadd mm7, mm1
	movq  [edi + ecx*4 + 12],  mm6
	movd  [edi + ecx*4 + 20],  mm7
	
	movq  mm6, [edi + ecx*4 + 24]       ;# increment iH2 force 
	movd  mm7, [edi + ecx*4 + 32] 	
	pfadd mm6, mm2
	pfadd mm7, mm3
	movq  [edi + ecx*4 + 24],  mm6
	movd  [edi + ecx*4 + 32],  mm7

	
	mov   ebx, [ebp + nb331_fshift]    ;# increment fshift force 
	mov   edx, [esp + nb331_is3]

	movq  mm6, [ebx + edx*4]	
	movd  mm7, [ebx + edx*4 + 8]	
	pfadd mm6, [esp + nb331_fixO]
	pfadd mm7, [esp + nb331_fizO]
	pfadd mm6, mm0
	pfadd mm7, mm1
	pfadd mm6, mm2
	pfadd mm7, mm3
	movq  [ebx + edx*4],     mm6
	movd  [ebx + edx*4 + 8], mm7
	
	;# get n from stack
	mov esi, [esp + nb331_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb331_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	movq  mm7, [esp + nb331_vctot]     
	pfacc mm7,mm7	          ;# get and sum the two parts of total potential 
	
	mov   eax, [ebp + nb331_Vc]
	movd  mm6, [eax + edx*4] 
	pfadd mm6, mm7
	movd  [eax + edx*4], mm6          ;# increment vc[gid] 

	movq  mm7, [esp + nb331_Vvdwtot]     
	pfacc mm7,mm7	          ;# same for Vvdw 
	
	mov   eax, [ebp + nb331_Vvdw]
	movd  mm6, [eax + edx*4] 
	pfadd mm6, mm7
	movd  [eax + edx*4], mm6          ;# increment Vvdw[gid] 
       	;# finish if last 
        mov ecx, [esp + nb331_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jecxz .nb331_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb331_n], esi
        jmp .nb331_outer
.nb331_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb331_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jecxz .nb331_end
        ;# non-zero, do one more workunit
        jmp   .nb331_threadloop
.nb331_end:
	femms
	mov eax, [esp + nb331_nouter] 	
	mov ebx, [esp + nb331_ninner]
	mov ecx, [ebp + nb331_outeriter]
	mov edx, [ebp + nb331_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	add esp, 248
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret




.globl nb_kernel331nf_ia32_3dnow
.globl _nb_kernel331nf_ia32_3dnow
nb_kernel331nf_ia32_3dnow:	
_nb_kernel331nf_ia32_3dnow:	
.equiv		nb331nf_p_nri,		8
.equiv		nb331nf_iinr,		12
.equiv		nb331nf_jindex,		16
.equiv		nb331nf_jjnr,		20
.equiv		nb331nf_shift,		24
.equiv		nb331nf_shiftvec,	28
.equiv		nb331nf_fshift,		32
.equiv		nb331nf_gid,		36
.equiv		nb331nf_pos,		40		
.equiv		nb331nf_faction,	44
.equiv		nb331nf_charge,		48
.equiv		nb331nf_p_facel,	52
.equiv		nb331nf_p_krf,		56	
.equiv		nb331nf_p_crf,		60	
.equiv		nb331nf_Vc,		64	
.equiv		nb331nf_type,		68
.equiv		nb331nf_p_ntype,	72
.equiv		nb331nf_vdwparam,	76	
.equiv		nb331nf_Vvdw,		80	
.equiv		nb331nf_p_tabscale,	84	
.equiv		nb331nf_VFtab,		88
.equiv		nb331nf_invsqrta,	92	
.equiv		nb331nf_dvda,		96
.equiv          nb331nf_p_gbtabscale,   100
.equiv          nb331nf_GBtab,          104
.equiv          nb331nf_p_nthreads,     108
.equiv          nb331nf_count,          112
.equiv          nb331nf_mtx,            116
.equiv          nb331nf_outeriter,      120
.equiv          nb331nf_inneriter,      124
.equiv          nb331nf_work,           128
			;# stack offsets for local variables 
.equiv		nb331nf_is3,		0
.equiv		nb331nf_ii3,		4
.equiv		nb331nf_ixO,		8
.equiv		nb331nf_iyO,		12
.equiv		nb331nf_izO,		16	
.equiv		nb331nf_ixH,		20  
.equiv		nb331nf_iyH,		28  
.equiv		nb331nf_izH,		36  
.equiv		nb331nf_iqO,		44  
.equiv		nb331nf_iqH,		52  
.equiv		nb331nf_qqO,		60  
.equiv		nb331nf_qqH,		68  
.equiv		nb331nf_vctot,		76  
.equiv		nb331nf_Vvdwtot,	84  
.equiv		nb331nf_c6,		92  
.equiv		nb331nf_c12,		100
.equiv		nb331nf_n1,		108 
.equiv		nb331nf_tsc,		116 
.equiv		nb331nf_ntia,		124 
.equiv		nb331nf_innerjjnr,	128
.equiv		nb331nf_innerk,		132
.equiv		nb331nf_tmprsqH,	136 
.equiv          nb331nf_n,              144 ;# idx for outer loop
.equiv          nb331nf_nn1,            148 ;# number of outer iterations
.equiv          nb331nf_nri,            152
.equiv          nb331nf_nouter,         156
.equiv          nb331nf_ninner,         160
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp, 164		;# local stack space 
	femms

	mov ecx, [ebp + nb331nf_p_nri]
	mov esi, [ebp + nb331nf_p_facel]
	mov edi, [ebp + nb331nf_p_tabscale]
	mov ecx, [ecx]
	mov [esp + nb331nf_nri], ecx
	movd  mm1, [esi] 	;# facel
	mov esi, [ebp + nb331nf_p_ntype]

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb331nf_nouter], eax
	mov [esp + nb331nf_ninner], eax