nb_kernel311_ia32_3dnow.s

最著名最快的分子模拟软件

        pfadd %mm5,%mm7 ## mm7=FF 

        pfmul %mm0,%mm5 ## mm5=eps*Fp 
        pfadd %mm4,%mm5 ##  mm5= VV 

        pfmul nb311_qqO(%esp),%mm5      ## vcoul=qq*VV 
        pfmul nb311_qqO(%esp),%mm7      ## fijC=qq*FF 
        ## update vctot directly, use mm3 for fscal sum. 
        pfadd nb311_vctot(%esp),%mm5
        movq %mm5,nb311_vctot(%esp)

        movq %mm7,%mm3
        pfmul nb311_tsc(%esp),%mm3

        ## nontabulated LJ - mm1 is invsqrt. - keep mm1! 
        movq %mm1,%mm0
        pfmul %mm0,%mm0         ## mm0 is invsq 
        movq %mm0,%mm2
        pfmul %mm0,%mm2
        pfmul %mm0,%mm2         ## mm2 = rinvsix 
        movq %mm2,%mm4
        pfmul %mm4,%mm4         ## mm4=rinvtwelve 

        pfmul nb311_c12(%esp),%mm4
        pfmul nb311_c6(%esp),%mm2
        movq %mm4,%mm5
        pfsub %mm2,%mm5         ## mm5=Vvdw12-Vvdw6 

        pfmul nb311_six(%esp),%mm2
        pfmul nb311_twelve(%esp),%mm4
        pfsub %mm2,%mm4
        pfmul %mm1,%mm4   ## mm4=(12*Vvdw12-6*Vvdw6)*rinv11 

        pfsubr %mm4,%mm3
        pfmul %mm1,%mm3   ## mm3 is total fscal (for the oxygen) now 

        ## update Vvdwtot  
        pfadd nb311_Vvdwtot(%esp),%mm5        ## add the earlier value 
        movq %mm5,nb311_Vvdwtot(%esp)         ## store the sum       

        ## Ready with the oxygen - potential is updated, fscal is in mm3. 
        ## now do the two hydrogens. 
        movq nb311_tmprsqH(%esp),%mm0   ## mm0=rsqH 

        pfrsqrt %mm0,%mm1
        pswapd %mm0,%mm0
        pfrsqrt %mm0,%mm2
        pswapd %mm0,%mm0
        punpckldq %mm2,%mm1     ## seeds are in mm1 now, and rsq in mm0. 

        movq %mm1,%mm2
        pfmul %mm1,%mm1
    pfrsqit1 %mm0,%mm1
    pfrcpit2 %mm2,%mm1  ## mm1=invsqrt 

        pfmul %mm1,%mm0         ## mm0=r 
        pfmul nb311_tsc(%esp),%mm0
        pf2iw %mm0,%mm4
        movq %mm4,nb311_n1(%esp)
        pi2fd %mm4,%mm4
        pfsub %mm4,%mm0              ## now mm0 is eps and mm4 n0 
        movq  %mm0,%mm2
        pfmul %mm2,%mm2         ## mm0 is eps, mm2 eps2 

        ## coulomb table 
        movl nb311_VFtab(%ebp),%edx
        movl nb311_n1(%esp),%ecx
        shll $2,%ecx
        ## load all values we need 
        movd (%edx,%ecx,4),%mm4
        movd 4(%edx,%ecx,4),%mm5
        movd 8(%edx,%ecx,4),%mm6
        movd 12(%edx,%ecx,4),%mm7
        movl nb311_n1+4(%esp),%ecx
        shll $2,%ecx
        punpckldq (%edx,%ecx,4),%mm4
        punpckldq 4(%edx,%ecx,4),%mm5
        punpckldq 8(%edx,%ecx,4),%mm6
        punpckldq 12(%edx,%ecx,4),%mm7

        pfmul %mm0,%mm6 ## mm6 = Geps           
        pfmul %mm2,%mm7 ## mm7 = Heps2 

        pfadd %mm6,%mm5
        pfadd %mm7,%mm5 ## mm5 = Fp 

        pfmul nb311_two(%esp),%mm7      ## two*Heps2 
        pfadd %mm6,%mm7
        pfadd %mm5,%mm7 ## mm7=FF 

        pfmul %mm0,%mm5 ## mm5=eps*Fp 
        pfadd %mm4,%mm5 ##  mm5= VV 

        pfmul nb311_qqH(%esp),%mm5      ## vcoul=qq*VV 
        pfmul nb311_qqH(%esp),%mm7      ## fijC=qq*FF 
        ## update vctot 
        pfadd nb311_vctot(%esp),%mm5
        movq %mm5,nb311_vctot(%esp)

        ## change sign of fijC and multiply by rinv 
    pxor %mm4,%mm4
        pfsub %mm7,%mm4
        pfmul nb311_tsc(%esp),%mm4
        pfmul %mm1,%mm4   ## mm4 is total fscal (for the hydrogens) now         

        ## spread oxygen fscalar to both positions 
        punpckldq %mm3,%mm3
        ## calc vectorial force for O 
        prefetchw (%edi,%eax,4) ## prefetch faction to cache  
        movq nb311_dxO(%esp),%mm0
        movd nb311_dzO(%esp),%mm1
        pfmul %mm3,%mm0
        pfmul %mm3,%mm1

        ## calc vectorial force for H's 
        movq nb311_dxH(%esp),%mm5
        movq nb311_dyH(%esp),%mm6
        movq nb311_dzH(%esp),%mm7
        pfmul %mm4,%mm5
        pfmul %mm4,%mm6
        pfmul %mm4,%mm7

        ## update iO particle force 
        movq nb311_fixO(%esp),%mm2
        movd nb311_fizO(%esp),%mm3
        pfadd %mm0,%mm2
        pfadd %mm1,%mm3
        movq %mm2,nb311_fixO(%esp)
        movd %mm3,nb311_fizO(%esp)

        ## update iH forces 
        movq nb311_fixH(%esp),%mm2
        movq nb311_fiyH(%esp),%mm3
        movq nb311_fizH(%esp),%mm4
        pfadd %mm5,%mm2
        pfadd %mm6,%mm3
        pfadd %mm7,%mm4
        movq %mm2,nb311_fixH(%esp)
        movq %mm3,nb311_fiyH(%esp)
        movq %mm4,nb311_fizH(%esp)

        ## pack j forces from H in the same form as the oxygen force. 
        pfacc %mm6,%mm5         ## mm5(l)=fjx(H1+ h2) mm5(h)=fjy(H1+ h2) 
        pfacc %mm7,%mm7         ## mm7(l)=fjz(H1+ h2) 

        pfadd %mm5,%mm0         ## add up total force on j particle.  
        pfadd %mm7,%mm1

        ## update j particle force 
        movq (%edi,%eax,4),%mm2
        movd 8(%edi,%eax,4),%mm3
        pfsub %mm0,%mm2
        pfsub %mm1,%mm3
        movq %mm2,(%edi,%eax,4)
        movd %mm3,8(%edi,%eax,4)

        ##  done  - one more? 
        decl nb311_innerk(%esp)
        jz  _nb_kernel311_ia32_3dnow.nb311_updateouterdata
        jmp _nb_kernel311_ia32_3dnow.nb311_inner_loop
_nb_kernel311_ia32_3dnow.nb311_updateouterdata: 
        movl  nb311_ii3(%esp),%ecx

        movq  (%edi,%ecx,4),%mm6       ## increment iO force  
        movd  8(%edi,%ecx,4),%mm7
        pfadd nb311_fixO(%esp),%mm6
        pfadd nb311_fizO(%esp),%mm7
        movq  %mm6,(%edi,%ecx,4)
        movd  %mm7,8(%edi,%ecx,4)

        movq  nb311_fixH(%esp),%mm0
        movq  nb311_fiyH(%esp),%mm3
        movq  nb311_fizH(%esp),%mm1
        movq  %mm0,%mm2
        punpckldq %mm3,%mm0     ## mm0(l)=fxH1, mm0(h)=fyH1 
        punpckhdq %mm3,%mm2     ## mm2(l)=fxH2, mm2(h)=fyH2 
        movq %mm1,%mm3
        pswapd %mm3,%mm3
        ## mm1 is fzH1 
        ## mm3 is fzH2 

        movq  12(%edi,%ecx,4),%mm6          ## increment iH1 force  
        movd  20(%edi,%ecx,4),%mm7
        pfadd %mm0,%mm6
        pfadd %mm1,%mm7
        movq  %mm6,12(%edi,%ecx,4)
        movd  %mm7,20(%edi,%ecx,4)

        movq  24(%edi,%ecx,4),%mm6          ## increment iH2 force 
        movd  32(%edi,%ecx,4),%mm7
        pfadd %mm2,%mm6
        pfadd %mm3,%mm7
        movq  %mm6,24(%edi,%ecx,4)
        movd  %mm7,32(%edi,%ecx,4)


        movl  nb311_fshift(%ebp),%ebx      ## increment fshift force 
        movl  nb311_is3(%esp),%edx

        movq  (%ebx,%edx,4),%mm6
        movd  8(%ebx,%edx,4),%mm7
        pfadd nb311_fixO(%esp),%mm6
        pfadd nb311_fizO(%esp),%mm7
        pfadd %mm0,%mm6
        pfadd %mm1,%mm7
        pfadd %mm2,%mm6
        pfadd %mm3,%mm7
        movq  %mm6,(%ebx,%edx,4)
        movd  %mm7,8(%ebx,%edx,4)

        ## get n from stack
        movl nb311_n(%esp),%esi
        ## get group index for i particle 
        movl  nb311_gid(%ebp),%edx              ## base of gid[]
        movl  (%edx,%esi,4),%edx                ## ggid=gid[n]

        movq  nb311_vctot(%esp),%mm7
        pfacc %mm7,%mm7           ## get and sum the two parts of total potential 

        movl  nb311_Vc(%ebp),%eax
        movd  (%eax,%edx,4),%mm6
        pfadd %mm7,%mm6
        movd  %mm6,(%eax,%edx,4)          ## increment vc[gid] 

        movq  nb311_Vvdwtot(%esp),%mm7
        pfacc %mm7,%mm7           ## same for Vvdw 

        movl  nb311_Vvdw(%ebp),%eax
        movd  (%eax,%edx,4),%mm6
        pfadd %mm7,%mm6
        movd  %mm6,(%eax,%edx,4)          ## increment Vvdw[gid] 
        ## finish if last 
        movl nb311_nn1(%esp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel311_ia32_3dnow.nb311_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb311_n(%esp)
        jmp _nb_kernel311_ia32_3dnow.nb311_outer
_nb_kernel311_ia32_3dnow.nb311_outerend: 
        ## check if more outer neighborlists remain
        movl  nb311_nri(%esp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel311_ia32_3dnow.nb311_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel311_ia32_3dnow.nb311_threadloop
_nb_kernel311_ia32_3dnow.nb311_end: 
        femms
        movl nb311_nouter(%esp),%eax
        movl nb311_ninner(%esp),%ebx
        movl nb311_outeriter(%ebp),%ecx
        movl nb311_inneriter(%ebp),%edx
        movl %eax,(%ecx)
        movl %ebx,(%edx)

        addl $264,%esp
        popl %edi
        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret


.globl nb_kernel311nf_ia32_3dnow
.globl _nb_kernel311nf_ia32_3dnow
nb_kernel311nf_ia32_3dnow:      
_nb_kernel311nf_ia32_3dnow:     
.set nb311nf_p_nri, 8
.set nb311nf_iinr, 12
.set nb311nf_jindex, 16
.set nb311nf_jjnr, 20
.set nb311nf_shift, 24
.set nb311nf_shiftvec, 28
.set nb311nf_fshift, 32
.set nb311nf_gid, 36
.set nb311nf_pos, 40
.set nb311nf_faction, 44
.set nb311nf_charge, 48
.set nb311nf_p_facel, 52
.set nb311nf_p_krf, 56
.set nb311nf_p_crf, 60
.set nb311nf_Vc, 64
.set nb311nf_type, 68
.set nb311nf_p_ntype, 72
.set nb311nf_vdwparam, 76
.set nb311nf_Vvdw, 80
.set nb311nf_p_tabscale, 84
.set nb311nf_VFtab, 88
.set nb311nf_invsqrta, 92
.set nb311nf_dvda, 96
.set nb311nf_p_gbtabscale, 100
.set nb311nf_GBtab, 104
.set nb311nf_p_nthreads, 108
.set nb311nf_count, 112
.set nb311nf_mtx, 116
.set nb311nf_outeriter, 120
.set nb311nf_inneriter, 124
.set nb311nf_work, 128
                        ## stack offsets for local variables 
.set nb311nf_is3, 0
.set nb311nf_ii3, 4
.set nb311nf_ixO, 8
.set nb311nf_iyO, 12
.set nb311nf_izO, 16
.set nb311nf_ixH, 20
.set nb311nf_iyH, 28
.set nb311nf_izH, 36
.set nb311nf_iqO, 44
.set nb311nf_iqH, 52
.set nb311nf_qqO, 60
.set nb311nf_qqH, 68
.set nb311nf_vctot, 76
.set nb311nf_Vvdwtot, 84
.set nb311nf_c6, 92
.set nb311nf_c12, 100
.set nb311nf_n1, 108
.set nb311nf_tsc, 116
.set nb311nf_ntia, 124
.set nb311nf_innerjjnr, 128
.set nb311nf_innerk, 132
.set nb311nf_tmprsqH, 136
.set nb311nf_n, 144                         ## idx for outer loop
.set nb311nf_nn1, 148                       ## number of outer iterations
.set nb311nf_nri, 152
.set nb311nf_nouter, 156
.set nb311nf_ninner, 160
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $164,%esp          ## local stack space 
        femms

        movl nb311nf_p_nri(%ebp),%ecx
        movl nb311nf_p_facel(%ebp),%esi
        movl nb311nf_p_tabscale(%ebp),%edi
        movl (%ecx),%ecx
        movl %ecx,nb311nf_nri(%esp)
        movd  (%esi),%mm1       ## facel
        movl nb311nf_p_ntype(%ebp),%esi

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb311nf_nouter(%esp)
        movl %eax,nb311nf_ninner(%esp)