nb_kernel311_ia32_3dnow.intel_syntax.s

最著名最快的分子模拟软件

	;# coulomb table 
	mov edx, [ebp + nb311_VFtab]
	mov ecx, [esp + nb311_n1]
	shl ecx, 2
	;# load all values we need 
	movd mm4, [edx + ecx*4]
	movd mm5, [edx + ecx*4 + 4]
	movd mm6, [edx + ecx*4 + 8]
	movd mm7, [edx + ecx*4 + 12]
	
	pfmul mm6, mm0  ;# mm6 = Geps 		
	pfmul mm7, mm2	;# mm7 = Heps2 
	
	pfadd mm5, mm6
	pfadd mm5, mm7	;# mm5 = Fp 

	pfmul mm7, [esp + nb311_two]	;# two*Heps2 
	pfadd mm7, mm6
	pfadd mm7, mm5	;# mm7=FF 

	pfmul mm5, mm0  ;# mm5=eps*Fp 
	pfadd mm5, mm4	;#  mm5= VV 

	pfmul mm5, [esp + nb311_qqO]	;# vcoul=qq*VV 
	pfmul mm7, [esp + nb311_qqO]	;# fijC=qq*FF 
	;# update vctot directly, use mm3 for fscal sum. 
	pfadd mm5, [esp + nb311_vctot]
	movq [esp + nb311_vctot], mm5

	movq mm3, mm7
	pfmul mm3, [esp + nb311_tsc]
	
	;# nontabulated LJ - mm1 is invsqrt. - keep mm1! 
	movq mm0, mm1
	pfmul mm0, mm0		;# mm0 is invsq 
	movq mm2, mm0
	pfmul mm2, mm0
	pfmul mm2, mm0		;# mm2 = rinvsix 
	movq mm4, mm2
	pfmul mm4, mm4		;# mm4=rinvtwelve 

	pfmul mm4, [esp + nb311_c12]
	pfmul mm2, [esp + nb311_c6]
	movq mm5, mm4
	pfsub mm5, mm2		;# mm5=Vvdw12-Vvdw6 

	pfmul mm2, [esp + nb311_six]
	pfmul mm4, [esp + nb311_twelve]
	pfsub mm4, mm2
	pfmul mm4, mm1    ;# mm4=(12*Vvdw12-6*Vvdw6)*rinv11 

	pfsubr mm3, mm4 
 	pfmul mm3, mm1    ;# mm3 is total fscal (for the oxygen) now 
	
	;# update Vvdwtot  
	pfadd mm5, [esp + nb311_Vvdwtot]      ;# add the earlier value 
	movq [esp + nb311_Vvdwtot], mm5       ;# store the sum       
	
	;# Ready with the oxygen - potential is updated, fscal is in mm3. 
	;# now do the two hydrogens. 
	movq mm0, [esp + nb311_tmprsqH] ;# mm0=rsqH 

	pfrsqrt mm1, mm0
	pswapd mm0,mm0
	pfrsqrt mm2, mm0
	pswapd mm0,mm0
	punpckldq mm1,mm2	;# seeds are in mm1 now, and rsq in mm0. 

	movq mm2, mm1
	pfmul mm1,mm1
    pfrsqit1 mm1,mm0				
    pfrcpit2 mm1,mm2	;# mm1=invsqrt 
	
	pfmul mm0,mm1		;# mm0=r 
	pfmul mm0, [esp + nb311_tsc]
	pf2iw mm4, mm0
	movq [esp + nb311_n1], mm4
	pi2fd mm4,mm4
	pfsub mm0, mm4               ;# now mm0 is eps and mm4 n0 
	movq  mm2, mm0
	pfmul mm2, mm2		;# mm0 is eps, mm2 eps2 
	
	;# coulomb table 
	mov edx, [ebp + nb311_VFtab]
	mov ecx, [esp + nb311_n1]
	shl ecx, 2
	;# load all values we need 
	movd mm4, [edx + ecx*4]
	movd mm5, [edx + ecx*4 + 4]
	movd mm6, [edx + ecx*4 + 8]
	movd mm7, [edx + ecx*4 + 12]
	mov ecx, [esp + nb311_n1+4]
	shl ecx, 2
	punpckldq mm4, [edx + ecx*4]
	punpckldq mm5, [edx + ecx*4 + 4]
	punpckldq mm6, [edx + ecx*4 + 8]
	punpckldq mm7, [edx + ecx*4 + 12]
	
	pfmul mm6, mm0  ;# mm6 = Geps 		
	pfmul mm7, mm2	;# mm7 = Heps2 
	
	pfadd mm5, mm6
	pfadd mm5, mm7	;# mm5 = Fp 

	pfmul mm7, [esp + nb311_two]	;# two*Heps2 
	pfadd mm7, mm6
	pfadd mm7, mm5	;# mm7=FF 

	pfmul mm5, mm0  ;# mm5=eps*Fp 
	pfadd mm5, mm4	;#  mm5= VV 

	pfmul mm5, [esp + nb311_qqH]	;# vcoul=qq*VV 
	pfmul mm7, [esp + nb311_qqH]	;# fijC=qq*FF 
	;# update vctot 
	pfadd mm5, [esp + nb311_vctot]
	movq [esp + nb311_vctot], mm5
	
	;# change sign of fijC and multiply by rinv 
    pxor mm4,mm4
	pfsub mm4, mm7
	pfmul mm4, [esp + nb311_tsc]	
 	pfmul mm4, mm1    ;# mm4 is total fscal (for the hydrogens) now 	
	
	;# spread oxygen fscalar to both positions 
	punpckldq mm3,mm3
	;# calc vectorial force for O 
	prefetchw [edi + eax*4]	;# prefetch faction to cache  
	movq mm0,  [esp + nb311_dxO]
	movd mm1,  [esp + nb311_dzO]
	pfmul mm0, mm3
	pfmul mm1, mm3

	;# calc vectorial force for H's 
	movq mm5, [esp + nb311_dxH]
	movq mm6, [esp + nb311_dyH]
	movq mm7, [esp + nb311_dzH]
	pfmul mm5, mm4
	pfmul mm6, mm4
	pfmul mm7, mm4
	
	;# update iO particle force 
	movq mm2,  [esp + nb311_fixO]
	movd mm3,  [esp + nb311_fizO]
	pfadd mm2, mm0
	pfadd mm3, mm1
	movq [esp + nb311_fixO], mm2
	movd [esp + nb311_fizO], mm3

	;# update iH forces 
	movq mm2, [esp + nb311_fixH]
	movq mm3, [esp + nb311_fiyH]
	movq mm4, [esp + nb311_fizH]
	pfadd mm2, mm5
	pfadd mm3, mm6
	pfadd mm4, mm7
	movq [esp + nb311_fixH], mm2
	movq [esp + nb311_fiyH], mm3
	movq [esp + nb311_fizH], mm4
	
	;# pack j forces from H in the same form as the oxygen force. 
	pfacc mm5, mm6		;# mm5(l)=fjx(H1+ h2) mm5(h)=fjy(H1+ h2) 
	pfacc mm7, mm7		;# mm7(l)=fjz(H1+ h2) 
	
	pfadd mm0, mm5		;# add up total force on j particle.  
	pfadd mm1, mm7

	;# update j particle force 
	movq mm2,  [edi + eax*4]
	movd mm3,  [edi + eax*4 + 8]
	pfsub mm2, mm0
	pfsub mm3, mm1
	movq [edi + eax*4], mm2
	movd [edi + eax*4 +8], mm3
	
	;#  done  - one more? 
	dec dword ptr [esp + nb311_innerk]
	jz  .nb311_updateouterdata
	jmp .nb311_inner_loop
.nb311_updateouterdata:	
	mov   ecx, [esp + nb311_ii3]

	movq  mm6, [edi + ecx*4]       ;# increment iO force  
	movd  mm7, [edi + ecx*4 + 8]	
	pfadd mm6, [esp + nb311_fixO]
	pfadd mm7, [esp + nb311_fizO]
	movq  [edi + ecx*4],    mm6
	movd  [edi + ecx*4 +8], mm7

	movq  mm0, [esp + nb311_fixH]
	movq  mm3, [esp + nb311_fiyH]
	movq  mm1, [esp + nb311_fizH]
	movq  mm2, mm0
	punpckldq mm0, mm3	;# mm0(l)=fxH1, mm0(h)=fyH1 
	punpckhdq mm2, mm3	;# mm2(l)=fxH2, mm2(h)=fyH2 
	movq mm3, mm1
	pswapd mm3,mm3		
	;# mm1 is fzH1 
	;# mm3 is fzH2 
	
	movq  mm6, [edi + ecx*4 + 12]       ;# increment iH1 force  
	movd  mm7, [edi + ecx*4 + 20] 	
	pfadd mm6, mm0
	pfadd mm7, mm1
	movq  [edi + ecx*4 + 12],  mm6
	movd  [edi + ecx*4 + 20],  mm7
	
	movq  mm6, [edi + ecx*4 + 24]       ;# increment iH2 force 
	movd  mm7, [edi + ecx*4 + 32] 	
	pfadd mm6, mm2
	pfadd mm7, mm3
	movq  [edi + ecx*4 + 24],  mm6
	movd  [edi + ecx*4 + 32],  mm7

	
	mov   ebx, [ebp + nb311_fshift]    ;# increment fshift force 
	mov   edx, [esp + nb311_is3]

	movq  mm6, [ebx + edx*4]	
	movd  mm7, [ebx + edx*4 + 8]	
	pfadd mm6, [esp + nb311_fixO]
	pfadd mm7, [esp + nb311_fizO]
	pfadd mm6, mm0
	pfadd mm7, mm1
	pfadd mm6, mm2
	pfadd mm7, mm3
	movq  [ebx + edx*4],     mm6
	movd  [ebx + edx*4 + 8], mm7
	
	;# get n from stack
	mov esi, [esp + nb311_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb311_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	movq  mm7, [esp + nb311_vctot]     
	pfacc mm7,mm7	          ;# get and sum the two parts of total potential 
	
	mov   eax, [ebp + nb311_Vc]
	movd  mm6, [eax + edx*4] 
	pfadd mm6, mm7
	movd  [eax + edx*4], mm6          ;# increment vc[gid] 

	movq  mm7, [esp + nb311_Vvdwtot]     
	pfacc mm7,mm7	          ;# same for Vvdw 
	
	mov   eax, [ebp + nb311_Vvdw]
	movd  mm6, [eax + edx*4] 
	pfadd mm6, mm7
	movd  [eax + edx*4], mm6          ;# increment Vvdw[gid] 
       	;# finish if last 
        mov ecx, [esp + nb311_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jecxz .nb311_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb311_n], esi
        jmp .nb311_outer
.nb311_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb311_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jecxz .nb311_end
        ;# non-zero, do one more workunit
        jmp   .nb311_threadloop
.nb311_end:
	femms
	mov eax, [esp + nb311_nouter] 	
	mov ebx, [esp + nb311_ninner]
	mov ecx, [ebp + nb311_outeriter]
	mov edx, [ebp + nb311_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	add esp, 264
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret


.globl nb_kernel311nf_ia32_3dnow
.globl _nb_kernel311nf_ia32_3dnow
nb_kernel311nf_ia32_3dnow:	
_nb_kernel311nf_ia32_3dnow:	
.equiv		nb311nf_p_nri,		8
.equiv		nb311nf_iinr,		12
.equiv		nb311nf_jindex,		16
.equiv		nb311nf_jjnr,		20
.equiv		nb311nf_shift,		24
.equiv		nb311nf_shiftvec,	28
.equiv		nb311nf_fshift,		32
.equiv		nb311nf_gid,		36
.equiv		nb311nf_pos,		40		
.equiv		nb311nf_faction,	44
.equiv		nb311nf_charge,		48
.equiv		nb311nf_p_facel,	52
.equiv		nb311nf_p_krf,		56	
.equiv		nb311nf_p_crf,		60	
.equiv		nb311nf_Vc,		64	
.equiv		nb311nf_type,		68
.equiv		nb311nf_p_ntype,	72
.equiv		nb311nf_vdwparam,	76	
.equiv		nb311nf_Vvdw,		80	
.equiv		nb311nf_p_tabscale,	84	
.equiv		nb311nf_VFtab,		88
.equiv		nb311nf_invsqrta,	92	
.equiv		nb311nf_dvda,		96
.equiv          nb311nf_p_gbtabscale,   100
.equiv          nb311nf_GBtab,          104
.equiv          nb311nf_p_nthreads,     108
.equiv          nb311nf_count,          112
.equiv          nb311nf_mtx,            116
.equiv          nb311nf_outeriter,      120
.equiv          nb311nf_inneriter,      124
.equiv          nb311nf_work,           128
			;# stack offsets for local variables 
.equiv		nb311nf_is3,		0
.equiv		nb311nf_ii3,		4
.equiv		nb311nf_ixO,		8
.equiv		nb311nf_iyO,		12
.equiv		nb311nf_izO,		16	
.equiv		nb311nf_ixH,		20  
.equiv		nb311nf_iyH,		28  
.equiv		nb311nf_izH,		36  
.equiv		nb311nf_iqO,		44  
.equiv		nb311nf_iqH,		52  
.equiv		nb311nf_qqO,		60  
.equiv		nb311nf_qqH,		68  
.equiv		nb311nf_vctot,		76  
.equiv		nb311nf_Vvdwtot,	84  
.equiv		nb311nf_c6,		92  
.equiv		nb311nf_c12,		100 
.equiv		nb311nf_n1,		108
.equiv		nb311nf_tsc,		116 
.equiv		nb311nf_ntia,		124 
.equiv		nb311nf_innerjjnr,	128
.equiv		nb311nf_innerk,		132
.equiv		nb311nf_tmprsqH,	136 
.equiv          nb311nf_n,              144 ;# idx for outer loop
.equiv          nb311nf_nn1,            148 ;# number of outer iterations
.equiv          nb311nf_nri,            152
.equiv          nb311nf_nouter,         156
.equiv          nb311nf_ninner,         160
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp, 164		;# local stack space 
	femms

	mov ecx, [ebp + nb311nf_p_nri]
	mov esi, [ebp + nb311nf_p_facel]
	mov edi, [ebp + nb311nf_p_tabscale]
	mov ecx, [ecx]