nb_kernel332_ia32_3dnow.s

最著名最快的分子模拟软件

        pfsub %mm7,%mm4
        pfmul nb332_tsc(%esp),%mm4
        pfmul %mm1,%mm4   ## mm4 is total fscal (for the hydrogens) now         

        ## spread oxygen fscalar to both positions 
        punpckldq %mm3,%mm3
        ## calc vectorial force for O 
        movq nb332_dxO(%esp),%mm0
        movd nb332_dzO(%esp),%mm1
        pfmul %mm3,%mm0
        pfmul %mm3,%mm1

        ## calc vectorial force for H's 
        movq nb332_dxH(%esp),%mm5
        movq nb332_dyH(%esp),%mm6
        movq nb332_dzH(%esp),%mm7
        pfmul %mm4,%mm5
        pfmul %mm4,%mm6
        pfmul %mm4,%mm7

        ## update iO particle force 
        movq nb332_fixO(%esp),%mm2
        movd nb332_fizO(%esp),%mm3
        pfadd %mm0,%mm2
        pfadd %mm1,%mm3
        movq %mm2,nb332_fixO(%esp)
        movd %mm3,nb332_fizO(%esp)

        ## update iH forces 
        movq nb332_fixH(%esp),%mm2
        movq nb332_fiyH(%esp),%mm3
        movq nb332_fizH(%esp),%mm4
        pfadd %mm5,%mm2
        pfadd %mm6,%mm3
        pfadd %mm7,%mm4
        movq %mm2,nb332_fixH(%esp)
        movq %mm3,nb332_fiyH(%esp)
        movq %mm4,nb332_fizH(%esp)

        ## pack j forces from H in the same form as the oxygen force. 
        pfacc %mm6,%mm5         ## mm5(l)=fjx(H1+ h2) mm5(h)=fjy(H1+ h2) 
        pfacc %mm7,%mm7         ## mm7(l)=fjz(H1+ h2) 

        pfadd %mm5,%mm0         ## add up total force on j particle.  
        pfadd %mm7,%mm1

        ## update j particle force 
        movq 24(%edi,%eax,4),%mm2
        movd 32(%edi,%eax,4),%mm3
        pfsub %mm0,%mm2
        pfsub %mm1,%mm3
        movq %mm2,24(%edi,%eax,4)
        movd %mm3,32(%edi,%eax,4)

        ##  done  - one more? 
        decl nb332_innerk(%esp)
        jz  _nb_kernel332_ia32_3dnow.nb332_updateouterdata
        jmp _nb_kernel332_ia32_3dnow.nb332_inner_loop
_nb_kernel332_ia32_3dnow.nb332_updateouterdata: 
        movl  nb332_ii3(%esp),%ecx

        movq  (%edi,%ecx,4),%mm6       ## increment iO force  
        movd  8(%edi,%ecx,4),%mm7
        pfadd nb332_fixO(%esp),%mm6
        pfadd nb332_fizO(%esp),%mm7
        movq  %mm6,(%edi,%ecx,4)
        movd  %mm7,8(%edi,%ecx,4)

        movq  nb332_fixH(%esp),%mm0
        movq  nb332_fiyH(%esp),%mm3
        movq  nb332_fizH(%esp),%mm1
        movq  %mm0,%mm2
        punpckldq %mm3,%mm0     ## mm0(l)=fxH1, mm0(h)=fyH1 
        punpckhdq %mm3,%mm2     ## mm2(l)=fxH2, mm2(h)=fyH2 
        movq %mm1,%mm3
        pswapd %mm3,%mm3
        ## mm1 is fzH1 
        ## mm3 is fzH2 

        movq  12(%edi,%ecx,4),%mm6          ## increment iH1 force  
        movd  20(%edi,%ecx,4),%mm7
        pfadd %mm0,%mm6
        pfadd %mm1,%mm7
        movq  %mm6,12(%edi,%ecx,4)
        movd  %mm7,20(%edi,%ecx,4)

        movq  24(%edi,%ecx,4),%mm6          ## increment iH2 force 
        movd  32(%edi,%ecx,4),%mm7
        pfadd %mm2,%mm6
        pfadd %mm3,%mm7
        movq  %mm6,24(%edi,%ecx,4)
        movd  %mm7,32(%edi,%ecx,4)


        movl  nb332_fshift(%ebp),%ebx      ## increment fshift force 
        movl  nb332_is3(%esp),%edx

        movq  (%ebx,%edx,4),%mm6
        movd  8(%ebx,%edx,4),%mm7
        pfadd nb332_fixO(%esp),%mm6
        pfadd nb332_fizO(%esp),%mm7
        pfadd %mm0,%mm6
        pfadd %mm1,%mm7
        pfadd %mm2,%mm6
        pfadd %mm3,%mm7
        movq  %mm6,(%ebx,%edx,4)
        movd  %mm7,8(%ebx,%edx,4)

        ## get n from stack
        movl nb332_n(%esp),%esi
        ## get group index for i particle 
        movl  nb332_gid(%ebp),%edx              ## base of gid[]
        movl  (%edx,%esi,4),%edx                ## ggid=gid[n]

        movq  nb332_vctot(%esp),%mm7
        pfacc %mm7,%mm7           ## get and sum the two parts of total potential 

        movl  nb332_Vc(%ebp),%eax
        movd  (%eax,%edx,4),%mm6
        pfadd %mm7,%mm6
        movd  %mm6,(%eax,%edx,4)          ## increment vc[gid] 

        movq  nb332_Vvdwtot(%esp),%mm7
        pfacc %mm7,%mm7           ## get and sum the two parts of total potential 

        movl  nb332_Vvdw(%ebp),%eax
        movd  (%eax,%edx,4),%mm6
        pfadd %mm7,%mm6
        movd  %mm6,(%eax,%edx,4)          ## increment Vvdwtot[gid] 
        ## finish if last 
        movl nb332_nn1(%esp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel332_ia32_3dnow.nb332_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb332_n(%esp)
        jmp _nb_kernel332_ia32_3dnow.nb332_outer
_nb_kernel332_ia32_3dnow.nb332_outerend: 
        ## check if more outer neighborlists remain
        movl  nb332_nri(%esp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel332_ia32_3dnow.nb332_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel332_ia32_3dnow.nb332_threadloop
_nb_kernel332_ia32_3dnow.nb332_end: 
        femms
        movl nb332_nouter(%esp),%eax
        movl nb332_ninner(%esp),%ebx
        movl nb332_outeriter(%ebp),%ecx
        movl nb332_inneriter(%ebp),%edx
        movl %eax,(%ecx)
        movl %ebx,(%edx)

        addl $232,%esp
        popl %edi
        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret



.globl nb_kernel332nf_ia32_3dnow
.globl _nb_kernel332nf_ia32_3dnow
nb_kernel332nf_ia32_3dnow:      
_nb_kernel332nf_ia32_3dnow:     
.set nb332nf_p_nri, 8
.set nb332nf_iinr, 12
.set nb332nf_jindex, 16
.set nb332nf_jjnr, 20
.set nb332nf_shift, 24
.set nb332nf_shiftvec, 28
.set nb332nf_fshift, 32
.set nb332nf_gid, 36
.set nb332nf_pos, 40
.set nb332nf_faction, 44
.set nb332nf_charge, 48
.set nb332nf_p_facel, 52
.set nb332nf_p_krf, 56
.set nb332nf_p_crf, 60
.set nb332nf_Vc, 64
.set nb332nf_type, 68
.set nb332nf_p_ntype, 72
.set nb332nf_vdwparam, 76
.set nb332nf_Vvdw, 80
.set nb332nf_p_tabscale, 84
.set nb332nf_VFtab, 88
.set nb332nf_invsqrta, 92
.set nb332nf_dvda, 96
.set nb332nf_p_gbtabscale, 100
.set nb332nf_GBtab, 104
.set nb332nf_p_nthreads, 108
.set nb332nf_count, 112
.set nb332nf_mtx, 116
.set nb332nf_outeriter, 120
.set nb332nf_inneriter, 124
.set nb332nf_work, 128
                        ## stack offsets for local variables 
.set nb332nf_is3, 0
.set nb332nf_ii3, 4
.set nb332nf_ixO, 8
.set nb332nf_iyO, 12
.set nb332nf_izO, 16
.set nb332nf_ixH, 20
.set nb332nf_iyH, 28
.set nb332nf_izH, 36
.set nb332nf_qqOO, 44
.set nb332nf_qqOH, 52
.set nb332nf_qqHH, 60
.set nb332nf_c6, 68
.set nb332nf_c12, 76
.set nb332nf_n1, 84
.set nb332nf_tsc, 92
.set nb332nf_vctot, 100
.set nb332nf_Vvdwtot, 108
.set nb332nf_innerjjnr, 116
.set nb332nf_innerk, 120
.set nb332nf_tmprsqH, 124
.set nb332nf_n, 132                         ## idx for outer loop
.set nb332nf_nn1, 136                       ## number of outer iterations
.set nb332nf_nri, 140
.set nb332nf_nouter, 144
.set nb332nf_ninner, 148
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $152,%esp          ## local stack space 
        femms
        movl nb332nf_p_nri(%ebp),%ecx
        movl nb332nf_p_facel(%ebp),%esi
        movl nb332nf_p_tabscale(%ebp),%edi
        movl (%ecx),%ecx
        movl %ecx,nb332nf_nri(%esp)
        movd  (%esi),%mm1       ## facel
        movl nb332nf_p_ntype(%ebp),%esi

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb332nf_nouter(%esp)
        movl %eax,nb332nf_ninner(%esp)

        ## assume we have at least one i particle - start directly      

        movl  nb332nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx),%ebx           ## ebx=ii 

        movl  nb332nf_charge(%ebp),%edx
        movd  (%edx,%ebx,4),%mm2    ## mm2=charge[ii0] (O) 
        movd  4(%edx,%ebx,4),%mm3       ## mm2=charge[ii0+1] (H)  
        movq  %mm2,%mm4
        pfmul %mm1,%mm4
        movq  %mm3,%mm6
        pfmul %mm1,%mm6
        movq  %mm4,%mm5
        pfmul %mm2,%mm4                 ## mm4=qqOO*facel 
        pfmul %mm3,%mm5                 ## mm5=qqOH*facel 
        pfmul %mm3,%mm6                 ## mm6=qqHH*facel 
        punpckldq %mm5,%mm5         ## spread to both halves 
        punpckldq %mm6,%mm6         ## spread to both halves 
        movq  %mm4,nb332nf_qqOO(%esp)
        movq  %mm5,nb332nf_qqOH(%esp)
        movq  %mm6,nb332nf_qqHH(%esp)
        movl  nb332nf_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        imull (%esi),%ecx
        addl  %ecx,%edx
        movl  nb332nf_vdwparam(%ebp),%eax
        movd  (%eax,%edx,4),%mm0
        movd  4(%eax,%edx,4),%mm1
        movq  %mm0,nb332nf_c6(%esp)
        movq  %mm1,nb332nf_c12(%esp)
        movd  (%edi),%mm3
        punpckldq %mm3,%mm3
        movq  %mm3,nb332nf_tsc(%esp)
_nb_kernel332nf_ia32_3dnow.nb332nf_threadloop: 
        movl  nb332nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel332nf_ia32_3dnow.nb332nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel332nf_ia32_3dnow.nb332nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb332nf_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb332nf_n(%esp)
        movl %ebx,nb332nf_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel332nf_ia32_3dnow.nb332nf_outerstart
        jmp _nb_kernel332nf_ia32_3dnow.nb332nf_end

_nb_kernel332nf_ia32_3dnow.nb332nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb332nf_nouter(%esp),%ebx
        movl %ebx,nb332nf_nouter(%esp)

_nb_kernel332nf_ia32_3dnow.nb332nf_outer: 
        movl  nb332nf_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb332nf_is3(%esp)            ## store is3 

        movl  nb332nf_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movq  (%eax,%ebx,4),%mm5        ## move shX/shY to mm5 and shZ to mm6. 
        movd  8(%eax,%ebx,4),%mm6
        movq  %mm5,%mm0
        movq  %mm5,%mm1
        movq  %mm6,%mm2
        punpckldq %mm0,%mm0         ## also expand shX,Y,Z in mm0--mm2. 
        punpckhdq %mm1,%mm1
        punpckldq %mm2,%mm2

        movl  nb332nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx,%esi,4),%ebx    ## ebx=ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb332nf_pos(%ebp),%eax      ## eax = base of pos[] 

        pfadd (%eax,%ebx,4),%mm5    ## ix = shX + posX (and iy too) 
        movd  8(%eax,%ebx,4),%mm7       ## cant use direct memory add for 4 bytes (iz) 
        movl  %ebx,nb332nf_ii3(%esp)        ## (use mm7 as temp. storage for iz.) 
        pfadd %mm7,%mm6
        movq  %mm5,nb332nf_ixO(%esp)
        movq  %mm6,nb332nf_izO(%esp)

        movd  12(%eax,%ebx,4),%mm3
        movd  16(%eax,%ebx,4),%mm4
        movd  20(%eax,%ebx,4),%mm5
        punpckldq  24(%eax,%ebx,4),%mm3
        punpckldq  28(%eax,%ebx,4),%mm4
        punpckldq  32(%eax,%ebx,4),%mm5    ## coords of H1 in low mm3-mm5, H2 in high 

        pfadd %mm3,%mm0
        pfadd %mm4,%mm1
        pfadd %mm5,%mm2
        movq %mm0,nb332nf_ixH(%esp)
        movq %mm1,nb332nf_iyH(%esp)
        movq %mm2,nb332nf_izH(%esp)

        ## clear vctot and i forces 
        pxor  %mm7,%mm7
        movq  %mm7,nb332nf_vctot(%esp)
        movq  %mm7,nb332nf_Vvdwtot(%esp)

        movl  nb332nf_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx     ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 
        movl  %edx,nb332nf_innerk(%esp)
        addl  nb332nf_ninner(%esp),%edx
        movl  %edx,nb332nf_ninner(%esp)

        movl  nb332nf_pos(%ebp),%esi
        movl  nb332nf_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb332nf_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
_nb_kernel332nf_ia32_3dnow.nb332nf_inner_loop: 
        ## a single j particle iteration here - compare with the unrolled code for comments. 
        movl  nb332nf_innerjjnr(%esp),%eax
        movl  (%eax),%eax       ## eax=jnr offset 
    addl $4,nb332nf_innerjjnr(%esp)             ## advance pointer 

        leal  (%eax,%eax,2),%eax

        movq  (%esi,%eax,4),%mm0
        movd  8(%esi,%eax,4),%mm1
        ## copy & expand to mm2-mm4 for the H interactions 
        movq  %mm0,%mm2
        movq  %mm0,%mm3
        movq  %mm1,%mm4
        punpckldq %mm2,%mm2
        punpckhdq %mm3,%mm3
        punpckldq %mm4,%mm4

        pfsubr nb332nf_ixO(%esp),%mm0
        pfsubr nb332nf_izO(%esp),%mm1

        pfmul %mm0,%mm0
        pfmul %mm1,%mm1
        pfacc %mm0,%mm0
        pfadd %mm1,%mm0         ## mm0=rsqO 

        punpckldq %mm2,%mm2
        punpckldq %mm3,%mm3
        punpckldq %mm4,%mm4 ## mm2-mm4 is jx-jz 
        pfsubr nb332nf_ixH(%esp),%mm2
        pfsubr nb332nf_iyH(%esp),%mm3
        pfsubr nb332nf_izH(%esp),%mm4   ## mm2-mm4 is dxH-dzH 

        pfmul %mm2,%mm2
        pfmul %mm3,%mm3
        pfmul %mm4,%mm4

        pfadd %mm2,%mm3
        pfadd %mm4,%mm3         ## mm3=rsqH 
        movq %mm3,nb332nf_tmprsqH(%esp)

    pfrsqrt %mm0,%mm1

    movq %mm1,%mm2
    pfmul %mm1,%mm1
    pfrsqit1 %mm0,%mm1
    pfrcpit2 %mm2,%mm1  ## mm1=invsqrt  
        pfmul %mm1,%mm0         ## mm0=rsq  

        pfmul nb332nf_tsc(%esp),%mm0
        pf2iw %mm0,%mm4
        movd %mm4,nb332nf_n1(%esp)
        pi2fd %mm4,%mm4
        pfsub %mm4,%mm0              ## now mm0 is eps and mm4 n0 
        movq  %mm0,%mm2
        pfmul %mm2,%mm2         ## mm0 is eps, mm2 eps2 

        ## coulomb table 
        movl nb332nf_VFtab(%ebp),%edx
        movl nb332nf_n1(%esp),%ecx
        leal (%ecx,%ecx,2),%ecx
        shll $2,%ecx