nb_kernel110_ia32_3dnow.s

最著名最快的分子模拟软件

        movq %mm3,nb110_vctot(%esp)         ## store the sum       

        ## spread fscalar to both positions 
        movq %mm0,%mm1
        punpckldq %mm0,%mm0
        punpckhdq %mm1,%mm1

        ## calc vector force 
        prefetchw (%edi,%eax,4) ## prefetch the 1st faction to cache 
        movq nb110_dx1(%esp),%mm2       ## fetch dr 
        movd nb110_dz1(%esp),%mm3

        ## update Vvdwtot 
        pfadd nb110_Vvdwtot(%esp),%mm6        ## add the earlier value 
        movq %mm6,nb110_Vvdwtot(%esp)         ## store the sum       

        prefetchw (%edi,%ebx,4) ## prefetch the 2nd faction to cache 
        pfmul %mm0,%mm2         ## mult by fs  
        pfmul %mm0,%mm3

        movq nb110_dx2(%esp),%mm4       ## fetch dr 
        movd nb110_dz2(%esp),%mm5
        pfmul %mm1,%mm4         ## mult by fs  
        pfmul %mm1,%mm5
        ## update i forces 

        movq nb110_fix(%esp),%mm0
        movd nb110_fiz(%esp),%mm1
        pfadd %mm2,%mm0
        pfadd %mm3,%mm1

        pfadd %mm4,%mm0
        pfadd %mm5,%mm1
        movq %mm0,nb110_fix(%esp)
        movd %mm1,nb110_fiz(%esp)
        ## update j forces 

        movq (%edi,%eax,4),%mm0
        movd 8(%edi,%eax,4),%mm1
        movq (%edi,%ebx,4),%mm6
        movd 8(%edi,%ebx,4),%mm7

        pfsub %mm2,%mm0
        pfsub %mm3,%mm1
        pfsub %mm4,%mm6
        pfsub %mm5,%mm7

        movq %mm0,(%edi,%eax,4)
        movd %mm1,8(%edi,%eax,4)
        movq %mm6,(%edi,%ebx,4)
        movd %mm7,8(%edi,%ebx,4)

        ## should we do one more iteration? 
        subl $2,nb110_innerk(%esp)
        jl    _nb_kernel110_ia32_3dnow.nb110_finish_inner
        jmp   _nb_kernel110_ia32_3dnow.nb110_unroll_loop
_nb_kernel110_ia32_3dnow.nb110_finish_inner: 
        andl $1,nb110_innerk(%esp)
        jnz  _nb_kernel110_ia32_3dnow.nb110_single_inner
        jmp  _nb_kernel110_ia32_3dnow.nb110_updateouterdata
_nb_kernel110_ia32_3dnow.nb110_single_inner: 
        ## a single j particle iteration here - compare with the unrolled code for comments 
        movl  nb110_innerjjnr(%esp),%eax
        movl  (%eax),%eax       ## eax=jnr offset 

        movl nb110_charge(%ebp),%ecx
        movd nb110_iq(%esp),%mm5
        movd (%ecx,%eax,4),%mm3
        pfmul %mm5,%mm3         ## mm3=qq 

        movl nb110_vdwparam(%ebp),%esi
        movl nb110_type(%ebp),%ecx
        movl (%ecx,%eax,4),%edx          ## type [jnr1] 
        shll %edx
        addl nb110_ntia(%esp),%edx           ## tja = ntia + 2*type 
        movd (%esi,%edx,4),%mm5         ## mm5 = 1st c6                 
        movq %mm5,nb110_c6(%esp)
        movd 4(%esi,%edx,4),%mm5        ## mm5 = 1st c12                
        movq %mm5,nb110_c12(%esp)


        movl  nb110_pos(%ebp),%esi
        leal  (%eax,%eax,2),%eax

        movq  nb110_ix(%esp),%mm0
        movd  nb110_iz(%esp),%mm1
        movq  (%esi,%eax,4),%mm4
        movd  8(%esi,%eax,4),%mm5
        pfsubr %mm0,%mm4
        pfsubr %mm1,%mm5
        movq  %mm4,nb110_dx1(%esp)
        pfmul %mm4,%mm4
        movd  %mm5,nb110_dz1(%esp)
        pfmul %mm5,%mm5
        pfacc %mm5,%mm4
        pfacc %mm5,%mm4         ## mm0=rsq 

    pfrsqrt %mm4,%mm0
    movq %mm0,%mm2
    pfmul %mm0,%mm0
    pfrsqit1 %mm4,%mm0
    pfrcpit2 %mm2,%mm0  ## mm1=invsqrt 
        movq  %mm0,%mm1
        pfmul %mm0,%mm0         ## mm0=invsq 
        ## calculate potentials and scalar force 
        movq %mm0,%mm4
        pfmul %mm0,%mm4
        pfmul %mm0,%mm4                 ## mm4=rinvsix 
        movq  %mm4,%mm5
        pfmul %mm5,%mm5             ## mm5=rinvtwelve 

        pfmul %mm1,%mm3         ## mm3 has vcoul for both interactions 
        movq  %mm3,%mm7     ## use mm7 for sum to make fscal  

        pfmul nb110_c12(%esp),%mm5
        pfmul nb110_c6(%esp),%mm4
        movq %mm5,%mm6  ## mm6 is Vvdw12-Vvdw6  
        pfsub %mm4,%mm6

        pfmul nb110_six(%esp),%mm4

        pfmul nb110_twelve(%esp),%mm5
        pfsub %mm4,%mm7
        pfadd %mm5,%mm7
        pfmul %mm7,%mm0   ## mm0 is total fscal now 

        ## update vctot 
        pfadd nb110_vctot(%esp),%mm3
        movq %mm3,nb110_vctot(%esp)

        ## update Vvdwtot 
        pfadd nb110_Vvdwtot(%esp),%mm6        ## add the earlier value 
        movq %mm6,nb110_Vvdwtot(%esp)         ## store the sum       

        ## spread fscalar to both positions 
        punpckldq %mm0,%mm0
        ## calc vectorial force 
        prefetchw (%edi,%eax,4) ## prefetch faction to cache  
        movq nb110_dx1(%esp),%mm2
        movd nb110_dz1(%esp),%mm3


        pfmul %mm0,%mm2
        pfmul %mm0,%mm3

        ## update i particle force 
        movq nb110_fix(%esp),%mm0
        movd nb110_fiz(%esp),%mm1
        pfadd %mm2,%mm0
        pfadd %mm3,%mm1
        movq %mm0,nb110_fix(%esp)
        movd %mm1,nb110_fiz(%esp)
        ## update j particle force 
        movq (%edi,%eax,4),%mm0
        movd 8(%edi,%eax,4),%mm1
        pfsub %mm2,%mm0
        pfsub %mm3,%mm1
        movq %mm0,(%edi,%eax,4)
        movd %mm1,8(%edi,%eax,4)
        ## done! 
_nb_kernel110_ia32_3dnow.nb110_updateouterdata: 
        movl  nb110_ii3(%esp),%ecx

        movq  (%edi,%ecx,4),%mm6       ## increment i force 
        movd  8(%edi,%ecx,4),%mm7
        pfadd nb110_fix(%esp),%mm6
        pfadd nb110_fiz(%esp),%mm7
        movq  %mm6,(%edi,%ecx,4)
        movd  %mm7,8(%edi,%ecx,4)

        movl  nb110_fshift(%ebp),%ebx      ## increment fshift force 
        movl  nb110_is3(%esp),%edx

        movq  (%ebx,%edx,4),%mm6
        movd  8(%ebx,%edx,4),%mm7
        pfadd nb110_fix(%esp),%mm6
        pfadd nb110_fiz(%esp),%mm7
        movq  %mm6,(%ebx,%edx,4)
        movd  %mm7,8(%ebx,%edx,4)

        ## get n from stack
        movl nb110_n(%esp),%esi
        ## get group index for i particle 
        movl  nb110_gid(%ebp),%edx              ## base of gid[]
        movl  (%edx,%esi,4),%edx                ## ggid=gid[n]

        movq  nb110_vctot(%esp),%mm7
        pfacc %mm7,%mm7           ## get and sum the two parts of total potential 

        movl  nb110_Vc(%ebp),%eax
        movd  (%eax,%edx,4),%mm6
        pfadd %mm7,%mm6
        movd  %mm6,(%eax,%edx,4)          ## increment vc[gid] 

        movq  nb110_Vvdwtot(%esp),%mm7
        pfacc %mm7,%mm7           ## get and sum the two parts of total potential 

        movl  nb110_Vvdw(%ebp),%eax
        movd  (%eax,%edx,4),%mm6
        pfadd %mm7,%mm6
        movd  %mm6,(%eax,%edx,4)          ## increment Vvdw[gid] 

       ## finish if last 
        movl nb110_nn1(%esp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel110_ia32_3dnow.nb110_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb110_n(%esp)
        jmp _nb_kernel110_ia32_3dnow.nb110_outer
_nb_kernel110_ia32_3dnow.nb110_outerend: 
        ## check if more outer neighborlists remain
        movl  nb110_nri(%esp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel110_ia32_3dnow.nb110_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel110_ia32_3dnow.nb110_threadloop
_nb_kernel110_ia32_3dnow.nb110_end: 
        femms

        movl nb110_nouter(%esp),%eax
        movl nb110_ninner(%esp),%ebx
        movl nb110_outeriter(%ebp),%ecx
        movl nb110_inneriter(%ebp),%edx
        movl %eax,(%ecx)
        movl %ebx,(%edx)

        addl $152,%esp
        popl %edi
        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret




.globl nb_kernel110nf_ia32_3dnow
.globl _nb_kernel110nf_ia32_3dnow
nb_kernel110nf_ia32_3dnow:      
_nb_kernel110nf_ia32_3dnow:     
.set nb110nf_p_nri, 8
.set nb110nf_iinr, 12
.set nb110nf_jindex, 16
.set nb110nf_jjnr, 20
.set nb110nf_shift, 24
.set nb110nf_shiftvec, 28
.set nb110nf_fshift, 32
.set nb110nf_gid, 36
.set nb110nf_pos, 40
.set nb110nf_faction, 44
.set nb110nf_charge, 48
.set nb110nf_p_facel, 52
.set nb110nf_p_krf, 56
.set nb110nf_p_crf, 60
.set nb110nf_Vc, 64
.set nb110nf_type, 68
.set nb110nf_p_ntype, 72
.set nb110nf_vdwparam, 76
.set nb110nf_Vvdw, 80
.set nb110nf_p_tabscale, 84
.set nb110nf_VFtab, 88
.set nb110nf_invsqrta, 92
.set nb110nf_dvda, 96
.set nb110nf_p_gbtabscale, 100
.set nb110nf_GBtab, 104
.set nb110nf_p_nthreads, 108
.set nb110nf_count, 112
.set nb110nf_mtx, 116
.set nb110nf_outeriter, 120
.set nb110nf_inneriter, 124
.set nb110nf_work, 128
        ## stack offsets for local variables 
.set nb110nf_is3, 0
.set nb110nf_ii3, 4
.set nb110nf_ix, 8
.set nb110nf_iy, 12
.set nb110nf_iz, 16
.set nb110nf_iq, 20
.set nb110nf_vctot, 28
.set nb110nf_Vvdwtot, 36
.set nb110nf_c6, 44
.set nb110nf_c12, 52
.set nb110nf_ntia, 60
.set nb110nf_innerjjnr, 64
.set nb110nf_innerk, 68
.set nb110nf_n, 72                         ## idx for outer loop
.set nb110nf_nn1, 76                       ## number of outer iterations
.set nb110nf_nri, 80
.set nb110nf_facel, 84
.set nb110nf_ntype, 88
.set nb110nf_nouter, 92
.set nb110nf_ninner, 96
        pushl %ebp
        movl %esp,%ebp

        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $100,%esp          ## local stack space 
        femms
        movl nb110nf_p_nri(%ebp),%ecx
        movl nb110nf_p_ntype(%ebp),%edx
        movl nb110nf_p_facel(%ebp),%esi
        movl (%ecx),%ecx
        movl (%edx),%edx
        movl (%esi),%esi
        movl %ecx,nb110nf_nri(%esp)
        movl %edx,nb110nf_ntype(%esp)
        movl %esi,nb110nf_facel(%esp)