nb_kernel310_ia32_3dnow.s

最著名最快的分子模拟软件

        prefetchw (%edi,%eax,4) ## prefetch the 1st faction to cache 
        movq nb310_dx1(%esp),%mm2       ## fetch dr 
        movd nb310_dz1(%esp),%mm3

        ## update Vvdwtot 
        pfadd nb310_Vvdwtot(%esp),%mm4        ## add the earlier value 
        movq %mm4,nb310_Vvdwtot(%esp)         ## store the sum       

        prefetchw (%edi,%ebx,4) ## prefetch the 2nd faction to cache 
        pfmul %mm0,%mm2         ## mult by fs  
        pfmul %mm0,%mm3

        movq nb310_dx2(%esp),%mm4       ## fetch dr 
        movd nb310_dz2(%esp),%mm5
        pfmul %mm1,%mm4         ## mult by fs  
        pfmul %mm1,%mm5
        ## update i forces 

        movq nb310_fix(%esp),%mm0
        movd nb310_fiz(%esp),%mm1
        pfadd %mm2,%mm0
        pfadd %mm3,%mm1

        pfadd %mm4,%mm0
        pfadd %mm5,%mm1
        movq %mm0,nb310_fix(%esp)
        movd %mm1,nb310_fiz(%esp)
        ## update j forces 

        movq (%edi,%eax,4),%mm0
        movd 8(%edi,%eax,4),%mm1
        movq (%edi,%ebx,4),%mm6
        movd 8(%edi,%ebx,4),%mm7

        pfsub %mm2,%mm0
        pfsub %mm3,%mm1
        pfsub %mm4,%mm6
        pfsub %mm5,%mm7

        movq %mm0,(%edi,%eax,4)
        movd %mm1,8(%edi,%eax,4)
        movq %mm6,(%edi,%ebx,4)
        movd %mm7,8(%edi,%ebx,4)

        ## should we do one more iteration? 
        subl $2,nb310_innerk(%esp)
        jl    _nb_kernel310_ia32_3dnow.nb310_finish_inner
        jmp   _nb_kernel310_ia32_3dnow.nb310_unroll_loop
_nb_kernel310_ia32_3dnow.nb310_finish_inner: 
        andl $1,nb310_innerk(%esp)
        jnz  _nb_kernel310_ia32_3dnow.nb310_single_inner
        jmp  _nb_kernel310_ia32_3dnow.nb310_updateouterdata
_nb_kernel310_ia32_3dnow.nb310_single_inner: 
        ## a single j particle iteration here - compare with the unrolled code for comments. 
        movl  nb310_innerjjnr(%esp),%eax
        movl  (%eax),%eax       ## eax=jnr offset 

        movl nb310_charge(%ebp),%ecx
        movd nb310_iq(%esp),%mm5
        movd (%ecx,%eax,4),%mm3
        pfmul %mm5,%mm3         ## mm3=qq 

        movl nb310_vdwparam(%ebp),%esi
        movl nb310_type(%ebp),%ecx
        movl (%ecx,%eax,4),%edx          ## type [jnr1] 
        shll %edx
        addl nb310_ntia(%esp),%edx           ## tja = ntia + 2*type 
        movd (%esi,%edx,4),%mm5         ## mm5 = 1st c6                 
        movq %mm5,nb310_c6(%esp)
        movd 4(%esi,%edx,4),%mm5        ## mm5 = 1st c12                
        movq %mm5,nb310_c12(%esp)


        movl  nb310_pos(%ebp),%esi
        leal  (%eax,%eax,2),%eax

        movq  nb310_ix(%esp),%mm0
        movd  nb310_iz(%esp),%mm1
        movq  (%esi,%eax,4),%mm4
        movd  8(%esi,%eax,4),%mm5
        pfsubr %mm0,%mm4
        pfsubr %mm1,%mm5
        movq  %mm4,nb310_dx1(%esp)
        pfmul %mm4,%mm4
        movd  %mm5,nb310_dz1(%esp)
        pfmul %mm5,%mm5
        pfacc %mm5,%mm4
        pfacc %mm5,%mm4         ## mm4=rsq 

        pfrsqrt %mm4,%mm0
        movq %mm0,%mm2
        pfmul %mm0,%mm0
        pfrsqit1 %mm4,%mm0
        pfrcpit2 %mm2,%mm0      ## mm1=invsqrt 
        pfmul %mm0,%mm4
        movq %mm4,%mm1
        ## mm0 is invsqrt, and mm1 r. 
        ## calculate potentials and scalar force 
        pfmul nb310_tsc(%esp),%mm1      ## mm1=rt 
        pf2iw %mm1,%mm4
        movd %mm4,nb310_n1(%esp)
        pi2fd %mm4,%mm4
        pfsub %mm4,%mm1              ## now mm1 is eps and mm4 is n0 

        movq %mm1,%mm2
        pfmul %mm2,%mm2 ## mm1 is eps, mm2 is eps2 

        ## coulomb table 
        movl nb310_VFtab(%ebp),%edx
        movl nb310_n1(%esp),%ecx
        shll $2,%ecx
        ## load all the table values we need 
        movd (%edx,%ecx,4),%mm4
        movd 4(%edx,%ecx,4),%mm5
        movd 8(%edx,%ecx,4),%mm6
        movd 12(%edx,%ecx,4),%mm7

        pfmul %mm1,%mm6 ## mm6 = Geps           
        pfmul %mm2,%mm7 ## mm7 = Heps2 

        pfadd %mm6,%mm5
        pfadd %mm7,%mm5 ## mm5 = Fp 

        pfmul nb310_two(%esp),%mm7      ## two*Heps2 
        pfadd %mm6,%mm7
        pfadd %mm5,%mm7 ## mm7=FF 

        pfmul %mm1,%mm5 ## mm5=eps*Fp 
        pfadd %mm4,%mm5 ##  mm5= VV 

        pfmul %mm3,%mm5 ## vcoul=qq*VV 
        pfmul %mm7,%mm3 ## fijC=FF*qq  

        ## at this point mm5 contains vcoul and mm3 fijC 

        movq %mm0,%mm1
        pfmul %mm1,%mm1 ## mm1=invsq 
        movq %mm1,%mm2
        pfmul %mm1,%mm2
        pfmul %mm1,%mm2 ## mm2=rinvsix 
        movq  %mm2,%mm1
        pfmul %mm1,%mm1 ## mm1=rinvtwelve 

        pfmul nb310_tsc(%esp),%mm3

        pfmul nb310_c12(%esp),%mm1

        pfmul nb310_c6(%esp),%mm2

        movq %mm1,%mm4
        pfsub %mm2,%mm4 ## mm4 = Vvdw12-Vvdw6 

        pfmul nb310_six(%esp),%mm2
        pfmul nb310_twelve(%esp),%mm1

        pfsub %mm2,%mm1
        pfmul %mm0,%mm1 ## mm1= (12*Vvdw12-6*Vvdw6)*rinv11 

        pfsub %mm3,%mm1

        ## update vctot 
        pfadd nb310_vctot(%esp),%mm5        ## add the earlier value 
        movq %mm5,nb310_vctot(%esp)         ## store the sum       

        pfmul %mm1,%mm0   ## mm0 is total fscal now     

        ## spread fscalar to both positions 
        punpckldq %mm0,%mm0
        ## calc vectorial force 
        prefetchw (%edi,%eax,4) ## prefetch faction to cache  
        movq nb310_dx1(%esp),%mm2
        movd nb310_dz1(%esp),%mm3

        ## update Vvdwtot 
        pfadd nb310_Vvdwtot(%esp),%mm4        ## add the earlier value 
        movq %mm4,nb310_Vvdwtot(%esp)         ## store the sum       

        pfmul %mm0,%mm2
        pfmul %mm0,%mm3

        ## update i particle force 
        movq nb310_fix(%esp),%mm0
        movd nb310_fiz(%esp),%mm1
        pfadd %mm2,%mm0
        pfadd %mm3,%mm1
        movq %mm0,nb310_fix(%esp)
        movd %mm1,nb310_fiz(%esp)
        ## update j particle force 
        movq (%edi,%eax,4),%mm0
        movd 8(%edi,%eax,4),%mm1
        pfsub %mm2,%mm0
        pfsub %mm3,%mm1
        movq %mm0,(%edi,%eax,4)
        movd %mm1,8(%edi,%eax,4)
        ## done! 
_nb_kernel310_ia32_3dnow.nb310_updateouterdata: 
        movl  nb310_ii3(%esp),%ecx

        movq  (%edi,%ecx,4),%mm6       ## increment i force 
        movd  8(%edi,%ecx,4),%mm7
        pfadd nb310_fix(%esp),%mm6
        pfadd nb310_fiz(%esp),%mm7
        movq  %mm6,(%edi,%ecx,4)
        movd  %mm7,8(%edi,%ecx,4)

        movl  nb310_fshift(%ebp),%ebx      ## increment fshift force 
        movl  nb310_is3(%esp),%edx

        movq  (%ebx,%edx,4),%mm6
        movd  8(%ebx,%edx,4),%mm7
        pfadd nb310_fix(%esp),%mm6
        pfadd nb310_fiz(%esp),%mm7
        movq  %mm6,(%ebx,%edx,4)
        movd  %mm7,8(%ebx,%edx,4)

        ## get n from stack
        movl nb310_n(%esp),%esi
        ## get group index for i particle 
        movl  nb310_gid(%ebp),%edx              ## base of gid[]
        movl  (%edx,%esi,4),%edx                ## ggid=gid[n]

        movq  nb310_vctot(%esp),%mm7
        pfacc %mm7,%mm7           ## get and sum the two parts of total potential 

        movl  nb310_Vc(%ebp),%eax
        movd  (%eax,%edx,4),%mm6
        pfadd %mm7,%mm6
        movd  %mm6,(%eax,%edx,4)          ## increment vc[gid] 

        movq  nb310_Vvdwtot(%esp),%mm7
        pfacc %mm7,%mm7           ## get and sum the two parts of total potential 

        movl  nb310_Vvdw(%ebp),%eax
        movd  (%eax,%edx,4),%mm6
        pfadd %mm7,%mm6
        movd  %mm6,(%eax,%edx,4)          ## increment Vvdw[gid] 

        ## finish if last 
        movl nb310_nn1(%esp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel310_ia32_3dnow.nb310_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb310_n(%esp)
        jmp _nb_kernel310_ia32_3dnow.nb310_outer
_nb_kernel310_ia32_3dnow.nb310_outerend: 
        ## check if more outer neighborlists remain
        movl  nb310_nri(%esp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel310_ia32_3dnow.nb310_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel310_ia32_3dnow.nb310_threadloop
_nb_kernel310_ia32_3dnow.nb310_end: 
        femms

        movl nb310_nouter(%esp),%eax
        movl nb310_ninner(%esp),%ebx
        movl nb310_outeriter(%ebp),%ecx
        movl nb310_inneriter(%ebp),%edx
        movl %eax,(%ecx)
        movl %ebx,(%edx)

        addl $176,%esp
        popl %edi
        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret







.globl nb_kernel310nf_ia32_3dnow
.globl _nb_kernel310nf_ia32_3dnow
nb_kernel310nf_ia32_3dnow:      
_nb_kernel310nf_ia32_3dnow:     
.set nb310nf_p_nri, 8
.set nb310nf_iinr, 12
.set nb310nf_jindex, 16
.set nb310nf_jjnr, 20
.set nb310nf_shift, 24
.set nb310nf_shiftvec, 28
.set nb310nf_fshift, 32
.set nb310nf_gid, 36
.set nb310nf_pos, 40
.set nb310nf_faction, 44
.set nb310nf_charge, 48
.set nb310nf_p_facel, 52
.set nb310nf_p_krf, 56
.set nb310nf_p_crf, 60
.set nb310nf_Vc, 64
.set nb310nf_type, 68
.set nb310nf_p_ntype, 72
.set nb310nf_vdwparam, 76
.set nb310nf_Vvdw, 80
.set nb310nf_p_tabscale, 84
.set nb310nf_VFtab, 88
.set nb310nf_invsqrta, 92
.set nb310nf_dvda, 96
.set nb310nf_p_gbtabscale, 100
.set nb310nf_GBtab, 104
.set nb310nf_p_nthreads, 108
.set nb310nf_count, 112
.set nb310nf_mtx, 116
.set nb310nf_outeriter, 120
.set nb310nf_inneriter, 124
.set nb310nf_work, 128
        ## stack offsets for local variables 
.set nb310nf_is3, 0
.set nb310nf_ii3, 4
.set nb310nf_ix, 8
.set nb310nf_iy, 12
.set nb310nf_iz, 16
.set nb310nf_iq, 20
.set nb310nf_vctot, 28
.set nb310nf_Vvdwtot, 36
.set nb310nf_c6, 44
.set nb310nf_c12, 52
.set nb310nf_n1, 60
.set nb310nf_tsc, 68
.set nb310nf_ntia, 76
.set nb310nf_innerjjnr, 80
.set nb310nf_innerk, 84
.set nb310nf_n, 88                         ## idx for outer loop
.set nb310nf_nn1, 92                       ## number of outer iterations
.set nb310nf_nri, 96
.set nb310nf_facel, 100
.set nb310nf_ntype, 104
.set nb310nf_nouter, 108
.set nb310nf_ninner, 112
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $116,%esp          ## local stack space 
        femms
        ## move data to local stack  
        movl nb310nf_p_nri(%ebp),%ecx
        movl nb310nf_p_ntype(%ebp),%edx
        movl nb310nf_p_facel(%ebp),%esi
        movl nb310nf_p_tabscale(%ebp),%edi
        movl (%ecx),%ecx
        movl (%edx),%edx
        movl (%esi),%esi
        movl %ecx,nb310nf_nri(%esp)
        movl %edx,nb310nf_ntype(%esp)
        movl %esi,nb310nf_facel(%esp)

        movd  (%edi),%mm3
        punpckldq %mm3,%mm3
        movq  %mm3,nb310nf_tsc(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb310nf_nouter(%esp)
        movl %eax,nb310nf_ninner(%esp)

_nb_kernel310nf_ia32_3dnow.nb310nf_threadloop: 
        movl  nb310nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel310nf_ia32_3dnow.nb310nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance