nb_kernel310_ia32_3dnow.s

最著名最快的分子模拟软件

##
## $Id: nb_kernel310_ia32_3dnow.s,v 1.1.2.2 2007/11/28 09:34:39 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel310_ia32_3dnow
.globl _nb_kernel310_ia32_3dnow
nb_kernel310_ia32_3dnow:        
_nb_kernel310_ia32_3dnow:       
.set nb310_p_nri, 8
.set nb310_iinr, 12
.set nb310_jindex, 16
.set nb310_jjnr, 20
.set nb310_shift, 24
.set nb310_shiftvec, 28
.set nb310_fshift, 32
.set nb310_gid, 36
.set nb310_pos, 40
.set nb310_faction, 44
.set nb310_charge, 48
.set nb310_p_facel, 52
.set nb310_p_krf, 56
.set nb310_p_crf, 60
.set nb310_Vc, 64
.set nb310_type, 68
.set nb310_p_ntype, 72
.set nb310_vdwparam, 76
.set nb310_Vvdw, 80
.set nb310_p_tabscale, 84
.set nb310_VFtab, 88
.set nb310_invsqrta, 92
.set nb310_dvda, 96
.set nb310_p_gbtabscale, 100
.set nb310_GBtab, 104
.set nb310_p_nthreads, 108
.set nb310_count, 112
.set nb310_mtx, 116
.set nb310_outeriter, 120
.set nb310_inneriter, 124
.set nb310_work, 128
        ## stack offsets for local variables 
.set nb310_is3, 0
.set nb310_ii3, 4
.set nb310_ix, 8
.set nb310_iy, 12
.set nb310_iz, 16
.set nb310_iq, 20
.set nb310_vctot, 28
.set nb310_Vvdwtot, 36
.set nb310_c6, 44
.set nb310_c12, 52
.set nb310_six, 60
.set nb310_twelve, 68
.set nb310_two, 76
.set nb310_n1, 84
.set nb310_tsc, 92
.set nb310_ntia, 100
.set nb310_innerjjnr, 104
.set nb310_innerk, 108
.set nb310_fix, 112
.set nb310_fiy, 116
.set nb310_fiz, 120
.set nb310_dx1, 124
.set nb310_dy1, 128
.set nb310_dz1, 132
.set nb310_dx2, 136
.set nb310_dy2, 140
.set nb310_dz2, 144
.set nb310_n, 148                           ## idx for outer loop
.set nb310_nn1, 152                         ## number of outer iterations
.set nb310_nri, 156
.set nb310_facel, 160
.set nb310_ntype, 164
.set nb310_nouter, 168
.set nb310_ninner, 172
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $176,%esp          ## local stack space 
        femms
        ## move data to local stack
        movl nb310_p_nri(%ebp),%ecx
        movl nb310_p_ntype(%ebp),%edx
        movl nb310_p_facel(%ebp),%esi
        movl nb310_p_tabscale(%ebp),%edi
        movl (%ecx),%ecx
        movl (%edx),%edx
        movl (%esi),%esi
        movl %ecx,nb310_nri(%esp)
        movl %edx,nb310_ntype(%esp)
        movl %esi,nb310_facel(%esp)

        movd  (%edi),%mm3
        punpckldq %mm3,%mm3
        movq  %mm3,nb310_tsc(%esp)
        movl $0x40000000,%eax  ## 2.0
        movl %eax,nb310_two(%esp)
        movl %eax,nb310_two+4(%esp)
        movl $0x40c00000,%ebx ## 6.0
        movl %ebx,nb310_six(%esp)
        movl %ebx,nb310_six+4(%esp)
        movl $0x41400000,%ecx  ## 12.0
        movl %ecx,nb310_twelve(%esp)
        movl %ecx,nb310_twelve+4(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb310_nouter(%esp)
        movl %eax,nb310_ninner(%esp)

_nb_kernel310_ia32_3dnow.nb310_threadloop: 
        movl  nb310_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel310_ia32_3dnow.nb310_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel310_ia32_3dnow.nb310_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb310_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb310_n(%esp)
        movl %ebx,nb310_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel310_ia32_3dnow.nb310_outerstart
        jmp _nb_kernel310_ia32_3dnow.nb310_end

_nb_kernel310_ia32_3dnow.nb310_outerstart: 
        ## ebx contains number of outer iterations
        addl nb310_nouter(%esp),%ebx
        movl %ebx,nb310_nouter(%esp)

_nb_kernel310_ia32_3dnow.nb310_outer: 
        movl  nb310_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb310_is3(%esp)      ## store is3 

        movl  nb310_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movq  (%eax,%ebx,4),%mm0        ## move shX/shY to mm0 and shZ to mm1 
        movd  8(%eax,%ebx,4),%mm1

        movl  nb310_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx    ## ebx=ii 

        movl  nb310_charge(%ebp),%edx
        movd  (%edx,%ebx,4),%mm2    ## mm2=charge[ii] 
        pfmul nb310_facel(%esp),%mm2
        punpckldq %mm2,%mm2         ## spread to both halves 
        movq  %mm2,nb310_iq(%esp)           ## iq =facel*charge[ii] 

        movl  nb310_type(%ebp),%edx
        movl  (%edx,%ebx,4),%edx
        imull nb310_ntype(%esp),%edx
        shll  %edx
        movl  %edx,nb310_ntia(%esp)

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb310_pos(%ebp),%eax      ## eax = base of pos[] 

        pfadd (%eax,%ebx,4),%mm0    ## ix = shX + posX (and iy too) 
        movd  8(%eax,%ebx,4),%mm3       ## cant use direct memory add for 4 bytes (iz) 
        movl  %ebx,nb310_ii3(%esp)
        pfadd %mm3,%mm1
        movq  %mm0,nb310_ix(%esp)
        movd  %mm1,nb310_iz(%esp)

        ## clear total potential and i forces 
        pxor  %mm7,%mm7
        movq  %mm7,nb310_vctot(%esp)
        movq  %mm7,nb310_Vvdwtot(%esp)
        movq  %mm7,nb310_fix(%esp)
        movd  %mm7,nb310_fiz(%esp)

        movl  nb310_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb310_pos(%ebp),%esi
        movl  nb310_faction(%ebp),%edi
        movl  nb310_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb310_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb310_ninner(%esp),%ecx
        movl  %ecx,nb310_ninner(%esp)
        movl  %edx,nb310_innerk(%esp)      ## number of innerloop atoms 
        addl  $0,%edx
        jge   _nb_kernel310_ia32_3dnow.nb310_unroll_loop
        jmp   _nb_kernel310_ia32_3dnow.nb310_finish_inner
_nb_kernel310_ia32_3dnow.nb310_unroll_loop: 
        ## paired innerloop starts here 
        movl  nb310_innerjjnr(%esp),%ecx       ## pointer to jjnr[k] 
        movl  (%ecx),%eax
        movl  4(%ecx),%ebx           ## eax/ebx=jnr 
        addl $8,nb310_innerjjnr(%esp)             ## advance pointer (unrolled 2) 
        prefetch 16(%ecx)            ## prefetch data - trial and error says 16 is best 

        movl nb310_charge(%ebp),%ecx     ## base of charge[] 
        movq nb310_iq(%esp),%mm5
        movd (%ecx,%eax,4),%mm3      ## charge[jnr1] 
        punpckldq (%ecx,%ebx,4),%mm3     ## move charge 2 to high part of mm3 
        pfmul %mm5,%mm3              ## mm3 now has qq for both particles 

        movl nb310_type(%ebp),%ecx
        movl (%ecx,%eax,4),%edx          ## type [jnr1] 
        movl (%ecx,%ebx,4),%ecx      ## type [jnr2] 

        movl nb310_vdwparam(%ebp),%esi          ## base of vdwparam  
        shll %edx
        shll %ecx
        addl nb310_ntia(%esp),%edx           ## tja = ntia + 2*type 
        addl nb310_ntia(%esp),%ecx

        movq (%esi,%edx,4),%mm5         ## mm5 = 1st c6 / c12           
        movq (%esi,%ecx,4),%mm7         ## mm7 = 2nd c6 / c12   
        movq %mm5,%mm6
        punpckldq %mm7,%mm5             ## mm5 = 1st c6 / 2nd c6 
        punpckhdq %mm7,%mm6             ## mm6 = 1st c12 / 2nd c12 
        movq %mm5,nb310_c6(%esp)
        movq %mm6,nb310_c12(%esp)

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        movl  nb310_pos(%ebp),%esi

        movq  nb310_ix(%esp),%mm0
        movd  nb310_iz(%esp),%mm1
        movq  (%esi,%eax,4),%mm4     ## fetch first j coordinates 
        movd  8(%esi,%eax,4),%mm5
        pfsubr %mm0,%mm4             ## dr = ir - jr  
        pfsubr %mm1,%mm5
        movq  %mm4,nb310_dx1(%esp)           ## store dr 
        movd  %mm5,nb310_dz1(%esp)
        pfmul %mm4,%mm4              ## square dx,dy,dz                          
        pfmul %mm5,%mm5
        pfacc %mm5,%mm4              ## accumulate to get dx*dx+ dy*dy+ dz*dz 
        pfacc %mm5,%mm4              ## first rsq in lower mm4 

        movq  (%esi,%ebx,4),%mm6     ## fetch second j coordinates  
        movd  8(%esi,%ebx,4),%mm7

        pfsubr %mm0,%mm6             ## dr = ir - jr  
        pfsubr %mm1,%mm7
        movq  %mm6,nb310_dx2(%esp)           ## store dr 
        movd  %mm7,nb310_dz2(%esp)
        pfmul %mm6,%mm6              ## square dx,dy,dz 
        pfmul %mm7,%mm7
        pfacc %mm7,%mm6              ## accumulate to get dx*dx+ dy*dy+ dz*dz 
        pfacc %mm7,%mm6              ## second rsq in lower mm6 

        pfrsqrt %mm4,%mm0            ## lookup inverse square root seed 
        pfrsqrt %mm6,%mm1


        punpckldq %mm1,%mm0
        punpckldq %mm6,%mm4             ## now 4 has rsq and 0 the seed for both pairs. 
        movq %mm0,%mm2                  ## amd 3dnow N-R iteration to get full precision. 
        pfmul %mm0,%mm0
        pfrsqit1 %mm4,%mm0
        pfrcpit2 %mm2,%mm0
        pfmul %mm0,%mm4
        movq %mm4,%mm1
        ## mm0 is invsqrt, and mm1 r. 
        ## do potential and fscal 
        pfmul nb310_tsc(%esp),%mm1      ## mm1=rt 
        pf2iw %mm1,%mm4
        movq %mm4,nb310_n1(%esp)
        pi2fd %mm4,%mm4
        pfsub %mm4,%mm1              ## now mm1 is eps and mm4 is n0 

        movq %mm1,%mm2
        pfmul %mm2,%mm2 ## mm1 is eps, mm2 is eps2 

        movl nb310_VFtab(%ebp),%edx
        movl nb310_n1(%esp),%ecx
        shll $2,%ecx
        ## coulomb table 
        ## load all the table values we need 
        movd (%edx,%ecx,4),%mm4
        movd 4(%edx,%ecx,4),%mm5
        movd 8(%edx,%ecx,4),%mm6
        movd 12(%edx,%ecx,4),%mm7
        movl nb310_n1+4(%esp),%ecx
        shll $2,%ecx
        punpckldq (%edx,%ecx,4),%mm4
        punpckldq 4(%edx,%ecx,4),%mm5
        punpckldq 8(%edx,%ecx,4),%mm6
        punpckldq 12(%edx,%ecx,4),%mm7

        pfmul %mm1,%mm6 ## mm6 = Geps           
        pfmul %mm2,%mm7 ## mm7 = Heps2 

        pfadd %mm6,%mm5
        pfadd %mm7,%mm5 ## mm5 = Fp 

        pfmul nb310_two(%esp),%mm7      ## two*Heps2 
        pfadd %mm6,%mm7
        pfadd %mm5,%mm7 ## mm7=FF 

        pfmul %mm1,%mm5 ## mm5=eps*Fp 
        pfadd %mm4,%mm5 ##  mm5= VV 

        pfmul %mm3,%mm5 ## vcoul=qq*VV 
        pfmul %mm7,%mm3 ## fijC=FF*qq  

        movq %mm0,%mm1
        pfmul %mm1,%mm1 ## mm1=invsq 
        movq %mm1,%mm2
        pfmul %mm1,%mm2
        pfmul %mm1,%mm2 ## mm2=rinvsix 
        movq  %mm2,%mm1
        pfmul %mm1,%mm1 ## mm1=rinvtwelve 

        pfmul nb310_tsc(%esp),%mm3

        pfmul nb310_c12(%esp),%mm1

        pfmul nb310_c6(%esp),%mm2

        movq %mm1,%mm4
        pfsub %mm2,%mm4 ## mm4 = Vvdw12-Vvdw6 

        pfmul nb310_six(%esp),%mm2
        pfmul nb310_twelve(%esp),%mm1

        pfsub %mm2,%mm1
        pfmul %mm0,%mm1 ## mm1= (12*Vvdw12-6*Vvdw6)*rinv11 

        pfsub %mm3,%mm1

        ## update vctot 
        pfadd nb310_vctot(%esp),%mm5        ## add the earlier value 
        movq %mm5,nb310_vctot(%esp)         ## store the sum       

        pfmul %mm1,%mm0   ## mm0 is total fscal now     

        prefetchw nb310_dx1(%esp)       ## prefetch i forces to cache 

        ## spread fscalar to both positions 
        movq %mm0,%mm1
        punpckldq %mm0,%mm0
        punpckhdq %mm1,%mm1

        ## calc vector force