configure.ac

linux下的多线程调试工具

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59)
AC_INIT(ptt, 1.0, [e-mail])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([config])
AM_INIT_AUTOMAKE(ptt, 1.0)
AC_CONFIG_SRCDIR([src/daemon/nptl_trace.c])
AC_CONFIG_HEADER([config.h])

# PTT configuration options

AC_ARG_WITH([ptt-trace-info],
    AC_HELP_STRING([--with-ptt-trace-info],
                   [compute information about PTT trace mechanism. should be useful only for PTT developers]),
                   [useptt_info=$withval],
                   [useptt_info=no])
if test "$useptt_info" = yes; then
    AC_DEFINE(PTT_TRACE_INFO,,information about PTT trace mechanism)
fi

AC_ARG_WITH([ptt-friendly-glibc],
    AC_HELP_STRING([--with-ptt-friendly-glibc=GLIBDIR],
                   [system glibc installed in GLIBDIR has support for PTT]),
                   [friend=$withval],
                   [friend=no])
AM_CONDITIONAL(FRIEND, test $friend != "no")
case "$friend" in
    ''|yes) AC_MSG_ERROR(--with-ptt-friend-glibc requires an argument (directory where libpthread.so and libpthread_ptt.so are installed)) ;;
    no) ;;
    *) if test ! -f "$friend/libpthread.so.0"; then
           AC_MSG_ERROR($friend doesn't contain libpthread.so.0)
       fi
       if test ! -f "$friend/libpthread_ptt.so.0"; then
           AC_MSG_ERROR($friend doesn't contain libpthread_ptt.so.0)
       fi
       ;;
esac
        
# Checks for programs.
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET

# Checks for libraries.
AC_CHECK_LIB([rt], [main])

# Checks for header files.
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS([fcntl.h limits.h stdlib.h string.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_C_VOLATILE

# Checks for library functions.
AC_FUNC_ERROR_AT_LINE
AC_FUNC_FORK
AC_FUNC_MALLOC
AC_FUNC_MMAP
AC_TYPE_SIGNAL
AC_FUNC_STRFTIME
AC_FUNC_VPRINTF
AC_CHECK_FUNCS([memset setenv strchr strdup strtol])

# Modify scripts/ptt_trace_skel according to installation parameters
AC_DEFUN([AC_DEFINE_DIR], [
    prefix_NONE=
    exec_prefix_NONE=
    test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
    test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
    dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
    dnl refers to ${prefix}.  Thus we have to use `eval' twice.
    eval ac_define_dir="\"[$]$2\""
    eval ac_define_dir="\"$ac_define_dir\""
    AC_SUBST($1, "$ac_define_dir")
    AC_DEFINE_UNQUOTED($1, "$ac_define_dir", [$3])
    test "$prefix_NONE" && prefix=NONE
    test "$exec_prefix_NONE" && exec_prefix=NONE
])
AC_DEFINE_DIR([LIBDIR],[libdir],[installation directory for libraires])
AC_DEFINE_DIR([BINDIR],[bindir],[installation directory for executables])
if test "$friend" != "no" ; then
    LIBDIR=$friend
    SKEL=scripts/ptt_trace_friendly_skel
else
    SKEL=scripts/ptt_trace_skel
fi
SCRIPT=scripts/ptt_trace
TMP=scripts/ptt_trace_tmp
sed s!path_to_bindir!$BINDIR! $SKEL > $SCRIPT
sed s!path_to_libdir!$LIBDIR! $SCRIPT > $TMP
mv $TMP $SCRIPT

AC_CONFIG_FILES([Makefile
                 man/Makefile
                 scripts/Makefile
                 src/include/Makefile
                 src/daemon/Makefile
                 src/decode/Makefile
                 test/Makefile
                 test/prog/Makefile])
if test "$friend" = "no" ; then
    AC_CONFIG_FILES([lib/Makefile])
fi

AC_OUTPUT