clsdisposes.cls

《超市进销存管理系统的开发与实现》 2、开发工具 Microsoft Visual Basic 6.0 3、运行环境 （1）、硬件环境 486DX/66MHz或更高

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "clsDisposes"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Attribute VB_Ext_KEY = "SavedWithClassBuilder6" ,"Yes"
Attribute VB_Ext_KEY = "Collection" ,"clsDispose"
Attribute VB_Ext_KEY = "Member0" ,"clsDispose"
Attribute VB_Ext_KEY = "Top_Level" ,"Yes"
Option Explicit

'局部变量，保存集合
Private mCol As Collection

Public Function Find(Optional lgnID As Long = -1, Optional lngTypeId As Long = 0) As clsDisposes
  Dim rs As Recordset
  Dim index As Long
  Dim obj As clsDispose
  
  '按输入的参数查询，并返回一个集合类
  Dim strSQL As String
  
  '构造SQL语句
  strSQL = "Select * from Dispose, Merchandise, MerchandiseType WHERE "
  strSQL = strSQL & " M_TypeId_N = MT_ID_N AND D_MerchandiseId_N=M_ID_N "
  If lgnID <> -1 Then
strSQL = strSQL & " AND D_ID_N=" & lgnID
  End If
  If lngTypeId <> 0 Then
    strSQL = strSQL & " AND M_TypeId_N=" & lngTypeId
  End If
    
  strSQL = strSQL & " AND D_ID_N>0"
  
  '清空当前集合
  Me.Clear
  Set rs = g_Conn.Execute(strSQL)
  '往集合中添加查询结果
  For index = 1 To rs.RecordCount
    Set obj = New clsDispose
    With obj
      .ID = rs("D_ID_N").Value
      .MerchandiseID = rs("D_MerchandiseID_N").Value
      .RegDate = rs("D_RegDate_D").Value
      .Count = rs("D_Count_N").Value
      .Reason = rs("D_Reason_S").Value
      .OperatorId = rs("D_OperatorId_S").Value
      .Remark = Trim(rs("D_Remark_R").Value)
      .MerchName = GetValueByID("Merchandise", "M_ID_N", .MerchandiseID, "M_Name_S")
    End With
    Me.AddEx obj
    Set obj = Nothing
    rs.MoveNext
  Next index
  
  Set rs = Nothing
  Set Find = Me
End Function


Public Function FindStorage(Optional IsDesc As Boolean = True, _
                      Optional nCount As Integer = 10) As clsDisposes
  Dim rs As Recordset
  Dim index As Long
  Dim obj As clsDispose
  
  '按输入的参数查询，并返回一个集合类
  Dim strSQL As String
  
  Dim strOrder As String
  If nCount <= 0 Then nCount = 10
  strOrder = IIf(IsDesc, "DESC", "ASC")
  
  '构造SQL语句
  strSQL = "Select M_ID_N, M_Name_S, MT_Name_S, "
  strSQL = strSQL & " COUNT(D_Count_N) AS RegTimes, "
  strSQL = strSQL & " SUM(D_Count_N) AS TotalCount "
  strSQL = strSQL & " FROM Dispose, Merchandise, MerchandiseType "
  strSQL = strSQL & " WHERE "
  strSQL = strSQL & " M_TypeId_N = MT_ID_N AND D_MerchandiseId_N=M_ID_N "
  strSQL = strSQL & " GROUP BY M_ID_N, M_Name_S, MT_Name_S "
  
  '清空当前集合
  Me.Clear
  Set rs = g_Conn.Execute(strSQL)
  rs.Sort = "TotalCount " & strOrder
  Dim aa, bb As Double
  '往集合中添加查询结果
  nCount = IIf(nCount < rs.RecordCount, nCount, rs.RecordCount)
  For index = 1 To nCount
    Set obj = New clsDispose
    With obj
      '此时ID属性中仅存用于区分的商品ID,而非Sell表中的ID
      .ID = rs("M_ID_N").Value
      .MerchName = Trim(rs("M_Name_S").Value)
      .TypeName = Trim(rs("MT_Name_S").Value)
      .RegTimes = rs("RegTimes").Value
      .TotalCount = rs("TotalCount").Value
    End With
    Me.AddEx obj
    Set obj = Nothing
    rs.MoveNext
  Next index
  
  Set rs = Nothing
  Set FindStorage = Me
End Function

Public Sub AddEx(obj As clsDispose)
  mCol.Add obj, "A" & obj.ID
  '在加入对象是，最好同时加入其“KEY”属性
  '“KEY”属性不可以是数字型，因此在前面随便加
  '一个字母，此处加了一个“A”
End Sub

'清除集合中的全部元素
Public Sub Clear()
  '注意！在清除时必须倒序清除，否则要出错！
  Dim i As Long
  For i = mCol.Count To 1 Step -1
    mCol.Remove i
  Next i
End Sub

Public Function Add(ID As Long, Optional sKey As String) As clsDispose
    '创建新对象
    Dim objNewMember As clsDispose
    Set objNewMember = New clsDispose


    '设置传入方法的属性
    objNewMember.ID = ID
    If Len(sKey) = 0 Then
        mCol.Add objNewMember
    Else
        mCol.Add objNewMember, sKey
    End If


    '返回已创建的对象
    Set Add = objNewMember
    Set objNewMember = Nothing


End Function

Public Property Get Item(vntIndexKey As Variant) As clsDispose
    '引用集合中的一个元素时使用。
    'vntIndexKey 包含集合的索引或关键字，
    '这是为什么要声明为 Variant 的原因
    '语法：Set foo = x.Item(xyz) or Set foo = x.Item(5)
  Set Item = mCol(vntIndexKey)
End Property



Public Property Get Count() As Long
    '检索集合中的元素数时使用。语法：Debug.Print x.Count
    Count = mCol.Count
End Property


Public Sub Remove(vntIndexKey As Variant)
    '删除集合中的元素时使用。
    'vntIndexKey 包含索引或关键字，这是为什么要声明为 Variant 的原因
    '语法：x.Remove(xyz)


    mCol.Remove vntIndexKey
End Sub


Public Property Get NewEnum() As IUnknown
Attribute NewEnum.VB_UserMemId = -4
Attribute NewEnum.VB_MemberFlags = "40"
    '本属性允许用 For...Each 语法枚举该集合。
    Set NewEnum = mCol.[_NewEnum]
End Property


Private Sub Class_Initialize()
    '创建类后创建集合
    Set mCol = New Collection
End Sub


Private Sub Class_Terminate()
    '类终止后破坏集合
    Set mCol = Nothing
End Sub