configure.in

EPIC IRC客户端。来源于IRCII客户端但做了很多性能和功能的优化。

  if (max < $3 && $3 < 60) {
	max = $3
  }
}

END {
  for (i=1; i<=max; i++) {
    [if (sig[i] == "")]
      printf "%d", i
    else
      [printf "%s", sig[i]]
    if (i < max)
      printf " "
  }
  printf "\n"
}
'`
shift
case $# in
0)
  if test -f /bin/csh; then
     set X `/bin/csh -cf 'kill -l'`
     shift
     case $* in
     0) 
       set HUP INT QUIT ILL TRAP ABRT EMT FPE KILL BUS SEGV SYS PIPE ALRM TERM
       ;;
    esac
  fi
  ;;
esac

sig_name="ZERO $*"
if test -f source/sig.inc; then
  /bin/rm -f source/sig.inc
fi
[echo $sig_name | sed -e 's/$/"};/' -e 's/ /", "/g' -e 's/^/static char *sys_siglist[] = { "/' >> source/sig.inc]
fi

dnl ----------------------------------------------------------
dnl
dnl Check for 'long long'
dnl

AC_CHECK_SIZEOF(long long, 0)
if test "$ac_cv_sizeof_long_long" != 0; then
	AC_DEFINE(HAVE_LONG_LONG)
fi

dnl ----------------------------------------------------------
dnl
dnl need this for dcc stuff
dnl

AC_CHECK_SIZEOF(unsigned int, 4)
if test "$ac_cv_sizeof_unsigned_int" = 4; then
	AC_DEFINE(UNSIGNED_INT32)
else
	AC_CHECK_SIZEOF(unsigned long, 4)
	if test "$ac_cv_sizeof_unsigned_long" = 4; then
		AC_DEFINE(UNSIGNED_LONG32)
	else
		AC_DEFINE(UNKNOWN_32INT)
	fi
fi

dnl ----------------------------------------------------------
dnl
dnl It makes a big difference if your system's (struct sockaddr)
dnl structures look like this:
dnl
dnl struct sockaddr {
dnl     u_char     sa_len;
dnl     u_char     sa_family;
dnl     char       sa_data[14];
dnl };
dnl
dnl 	or this
dnl
dnl struct sockaddr {
dnl     u_short    sa_family;
dnl     char       sa_data[14];
dnl };
dnl
dnl so check for that here.
dnl
dnl -----------------------------------------------------------

AC_MSG_CHECKING(to see if your struct sockaddr includes a length field)
AC_TRY_RUN([
#include <sys/types.h>
#include <sys/socket.h>
main()
{
	struct sockaddr sa;
	sa.sa_len = 0;
	exit(0);
}
],
  AC_DEFINE(HAVE_SA_LEN)
  AC_MSG_RESULT(yes),
  AC_MSG_RESULT(no), :)

dnl ----------------------------------------------------------
dnl
dnl checks for ipv6-related things
dnl

AC_MSG_CHECKING(whether to support ipv6)
AC_ARG_WITH(ipv6,
[  --with-ipv6       Include IPv6 support],[
	if test "x$withval" = "xno" ; then
		AC_MSG_RESULT(no)
		AC_DEFINE(DO_NOT_USE_IPV6)
	fi
],[AC_MSG_RESULT(yes)])

AC_MSG_CHECKING(for struct sockaddr_storage)
AC_EGREP_HEADER([struct( |	)*sockaddr_storage], sys/socket.h, 
  AC_MSG_RESULT(yes) 
  AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE),
  AC_MSG_RESULT(no))

AC_MSG_CHECKING(for struct sockaddr_in6)
AC_EGREP_HEADER([struct( |	)*sockaddr_in6], netinet/in.h,
  AC_MSG_RESULT(yes)
  AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6),
  AC_MSG_RESULT(no))

AC_MSG_CHECKING(for struct addrinfo)
AC_EGREP_HEADER([struct( |	)*addrinfo], netdb.h,
  AC_MSG_RESULT(yes)
  AC_DEFINE(HAVE_STRUCT_ADDRINFO),
  AC_MSG_RESULT(no))

dnl ----------------------------------------------------------
dnl
dnl Some implementations of getaddrinfo (*cough*KAME*cough*) don't 
dnl support the AF_UNIX protocol family.  For these partially incomplete 
dnl implementations, we must add our own support in a wrapper.
dnl

AC_MSG_CHECKING(to see if your getaddrinfo supports AF_UNIX)
AC_TRY_RUN([
#include <sys/types.h>
#include <sys/socket.h>
#include <netdb.h>
#include <sys/un.h>
#include <stdlib.h>

main()
{
	struct addrinfo hints;
	struct addrinfo *results;
	int	retval;

	memset(&hints, 0, sizeof(hints));
	hints.ai_flags = 0;
	hints.ai_family = AF_UNIX;
	hints.ai_socktype = SOCK_STREAM;
	hints.ai_protocol = 0;

	retval = getaddrinfo(0, "/tmp/.ircd/6667", &hints, &results);
	if (retval != 0)
		exit(1);
	else
		exit(0);
}
],
  AC_MSG_RESULT(yes),
  AC_DEFINE(GETADDRINFO_DOES_NOT_DO_AF_UNIX)
  AC_MSG_RESULT(no. ugh), :)

dnl ----------------------------------------------------------
dnl
dnl Socks4 or Socks5 or neither?
dnl

AC_MSG_CHECKING(whether to support SOCKS)
AC_ARG_WITH(socks,
[  --with-socks[=PATH]     Compile with SOCKS firewall traversal support.],
[ case "$withval" in
  no)
	AC_MSG_RESULT(no)
	;;
  *)
	if test "x$withval" != "xyes"; then
		LIBS="$LIBS -L$withval"
	fi

	AC_MSG_RESULT(yes)
	LIBS="$LIBS -lsocks"
	AC_DEFINE(SOCKS)
	AC_DEFINE(connect, Rconnect)
	AC_DEFINE(getsockname, Rgetsockname)
	AC_DEFINE(bind, Rbind)
	AC_DEFINE(accept, Raccept)
	AC_DEFINE(listen, Rlisten)
	AC_DEFINE(select, Rselect)
	;;
  esac ],
  AC_MSG_RESULT(no)
)

AC_MSG_CHECKING(whether to support SOCKS5)
AC_ARG_WITH(socks5,
[  --with-socks5[=PATH]     Compile with SOCKS5 firewall traversal support.],
[ case "$withval" in
  no)
	AC_MSG_RESULT(no)
	;;
  *)
	if test "x$withval" != "xyes"; then
		LIBS="$LIBS -L$withval"
		CFLAGS="$CFLAGS -I$withval/../include/"
	fi

	AC_MSG_RESULT(yes)
	LIBS="$LIBS -lsocks5"
	AC_DEFINE(SOCKS)
	AC_DEFINE(USE_SOCKS5)
	;;
  esac ],
  AC_MSG_RESULT(no)
)

dnl ----------------------------------------------------------
dnl
dnl Perl support?
dnl

AC_MSG_CHECKING(whether to support Perl)
AC_ARG_WITH(perl,
[  --with-perl[=PATH]       Compile with perl support.],
[ test -z "$withval" && withval=yes ],
)
test "xno" != "x$withval" && for base in $withval /usr/local /usr /
do
	FOUND=
	for ext in so a dll ; do
		test -r $base/lib/libperl.$ext && FOUND=1
		test -r $base/libperl.$ext && FOUND=1
	done
	test -n "$FOUND" || continue
	AC_MSG_RESULT(yes)
	LIBS="$LIBS `perl -MExtUtils::Embed -e ldopts`"
	PERLDOTOH="perl.o"
	AC_DEFINE(PERL)
	break
done
test -z "$PERLDOTOH" && AC_MSG_RESULT(no)
withval=''

dnl ----------------------------------------------------------
dnl
dnl Tcl support?
dnl

AC_MSG_CHECKING(whether to support Tcl)
AC_ARG_WITH(tcl,
[  --with-tcl[=PATH]        Compile with tcl support.],
[ test -z "$withval" && withval=yes ],
)
test "xno" != "x$withval" && for base in $withval /usr/local /usr
do
	for ver in 8.4 8.3 8.2 8.1 8.0
	do
		incdir="$base/include/tcl$ver"
		test -r $incdir/tcl.h || continue
		test -r $base/lib/libtcl$ver.so || ver="`echo $ver | sed -e 's/\.//g'`"
		test -r $base/lib/libtcl$ver.so || continue
		AC_MSG_RESULT(yes)
		CFLAGS="$CFLAGS -I $incdir"
		LIBS="-L$base/lib -ltcl$ver $LIBS"
		TCLDOTOH="tcl.o"
		AC_DEFINE(TCL)
		break 2
	done
done
test -z "$TCLDOTOH" && AC_MSG_RESULT(no)

dnl ----------------------------------------------------------
dnl ----------------------------------------------------------
dnl
dnl closing stuff
dnl
dnl ----------------------------------------------------------
dnl ----------------------------------------------------------


dnl ----------------------------------------------------------
dnl 
dnl set some last minute sanity defaults
dnl

if test -z "$CFLAGS"; then CFLAGS=-g -O; fi
if test -z "$LDFLAGS"; then LDFLAGS= ; fi
if test -z "$PERLDOTOH"; then PERLDOTOH= ; fi
if test -z "$TCLDOTOH"; then TCLDOTOH= ; fi
if test -z "$bindir"; then bindir=\${prefix}/bin; fi
if test -z "$libdir"; then libdir=\${prefix}/lib; fi
if test -z "$irclibdir"; then irclibdir=\${libdir}/irc; fi
if test -z "$libexecdir"; then libexecdir=\${prefix}/libexec; fi

epic=`echo "epic" | sed -e "$program_transform_name"`
if test "$program_prefix" = "NONE" ; then
	program_prefix=
fi

AC_MSG_CHECKING(whether to support bounds checking gcc)
AC_ARG_WITH(bc,
[  --with-bc[=PATH_TO_GCC]  You have bounds checking gcc and want to use it.],
[   case "$withval" in
   no)
        AC_MSG_RESULT(no);
        ;;
   *)
        if test "x$withval" != "xyes" ; then
                CC="$withval"
        fi

        CFLAGS="$CFLAGS -Wall -fbounds-checking"
        LDFLAGS="$LDFLAGS -static"
        AC_MSG_RESULT(yes)
        ;;
   esac ],
   AC_MSG_RESULT(no)
)

AC_MSG_CHECKING(whether to turn on FreeBSD WARNS-like compiler warnings)
AC_ARG_WITH(warns,
[  --with-warns          You wish to use FreeBSD WARNS-like compiler warnings.],
[   case "$withval" in
   no)
        AC_MSG_RESULT(no);
        ;;
   *)
        if test "x$withval" != "xyes" ; then
                CFLAGS="$CFLAGS $withval"
        fi

        CFLAGS="$CFLAGS -W -Wall -Wstrict-prototypes -Wmissing-prototypes -Wuninitialized -Wpointer-arith -Wreturn-type -Wcast-qual -Wwrite-strings -Wswitch -Wshadow -Wformat-extra-args -Wno-unused -ansi -fno-builtin"
        AC_MSG_RESULT(yes)
        ;;
   esac ],
   AC_MSG_RESULT(no)
)

AC_SUBST(CFLAGS)
AC_SUBST(LDFLAGS)
AC_SUBST(PERLDOTOH)
AC_SUBST(TCLDOTOH)
AC_SUBST(bindir)
AC_SUBST(irclibdir)
AC_SUBST(libexecdir)
AC_SUBST(srcdir)
AC_SUBST(includedir)
AC_SUBST(epic)
AC_SUBST(program_transform_name)
AC_SUBST(program_prefix)
AC_SUBST(mandir)

AC_OUTPUT(Makefile source/Makefile source/info.c.sh)


dnl ----------------------------------------------------------
dnl
dnl Commencement
dnl

echo
echo "There you go.  Look at include/config.h for any options that "
echo "you might want to change before you 'make'.  Don't forget to "
echo "do a 'make install' before you're done."
echo