d5.bat

Advanced.Export.Component.v4.01.rar,delphi 第三方控件

@echo off

rem ---------------
rem Local variables
rem ---------------

@set DCC=%1 
@set BPL=%2
@set DCP=%3

@if not defined DCC goto ParamsError
@if not defined BPL goto ParamsError
@if not defined DCP goto ParamsError

@if not exist %BPL% mkdir %BPL%
@if not exist %DCP% mkdir %DCP%

@if exist %BPL%\QExport4??_D5.bpl del %BPL%\QExport4??_D5.bpl /Q
@if exist %DCP%\QExport4??_D5.dcp del %DCP%\QExport4??_D5.dcp /Q

rem ------------------
rem Deleting old files
rem ------------------

@if exist error.log del error.log

@if exist *.~?? del *.~?? > nul
@if exist *.dcu del *.dcu > nul

rem --------------------------
rem Compiling run-time package
rem --------------------------

@%DCC% QExport4RT_D5.dpk -B -LN%DCP% -U%DCP% -DHTML;XMLDOC;XLSX;DOCX;ODS;ODT >> error.log
@if errorlevel=1 goto RTCommonError
@echo QExport4RT_D5.dpk was compiled successfully!

rem -----------------------------
rem Compiling design-time package
rem -----------------------------

@%DCC% QExport4DT_D5.dpk -B -LN%DCP% -U%DCP% -DHTML;XMLDOC;XLSX;DOCX;ODS;ODT >> error.log
@if errorlevel=1 goto DTCommonError
@echo QExport4DT_D5.dpk was compiled successfully!

rem --------------------
rem Copying bpl files
rem --------------------

@copy *D5.bpl %BPL% /Y > nul

rem -----------------------
rem Deleting needless files
rem -----------------------

@if exist *.bpl del *.bpl > nul
@if exist *.dcp del *.dcp > nul
@if exist *.dcu del *.dcu > nul

goto End

:RTCommonError
@echo QExport4RT_D5.dpk was compiled with errors!
@"error.log"
@pause
@exit

:DTCommonError
@echo QExport4DT_D5.dpk was compiled with errors!
@"error.log"
@pause
@exit

:ParamsError
@echo Empty params!
@pause
@exit

:End