frmjpg.frm

一个功能比较完善的远程抄表软件

VERSION 5.00
Begin VB.Form frmJPG 
   BorderStyle     =   4  'Fixed ToolWindow
   Caption         =   "用户数据图像"
   ClientHeight    =   3570
   ClientLeft      =   45
   ClientTop       =   285
   ClientWidth     =   4125
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   3570
   ScaleWidth      =   4125
   ShowInTaskbar   =   0   'False
   StartUpPosition =   3  '窗口缺省
   Begin VB.TextBox txtVal 
      Height          =   270
      Left            =   480
      TabIndex        =   3
      Top             =   3240
      Width           =   1095
   End
   Begin VB.CommandButton cmdTranslate 
      Caption         =   "识别"
      Height          =   255
      Left            =   1680
      TabIndex        =   2
      Top             =   3240
      Width           =   855
   End
   Begin VB.CommandButton cmdFeedback 
      Caption         =   "修正"
      Height          =   255
      Left            =   2520
      TabIndex        =   1
      Top             =   3240
      Width           =   855
   End
   Begin VB.HScrollBar srbJPG 
      Height          =   255
      Left            =   3600
      Max             =   15
      TabIndex        =   0
      Top             =   3240
      Width           =   480
   End
   Begin VB.Image imgJPG 
      Height          =   3135
      Left            =   0
      Stretch         =   -1  'True
      Top             =   0
      Width           =   4095
   End
   Begin VB.Label lblVal 
      Caption         =   "值:"
      Height          =   255
      Left            =   120
      TabIndex        =   4
      Top             =   3240
      Width           =   495
   End
End
Attribute VB_Name = "frmJPG"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'****************************************************************************
'人人为我，我为人人
'枕善居收藏整理
'发布日期：2007/07/09
'描    述：CBB三表户外计量系统 Ver 5.2
'网    站：http://www.Mndsoft.com/  (VB6源码博客)
'网    站：http://www.VbDnet.com/   (VB.NET源码博客,主要基于.NET2005)
'e-mail  ：[e-mail]
'e-mail  ：[e-mail]
'OICQ    ：88382850
'          如果您有新的好的代码别忘记给枕善居哦!
'****************************************************************************
Dim curDevSum As Integer
Dim curShowUserID As Long
Dim curUserID As Integer
Dim curDate As Date
Dim curJPGDir As String
Dim curJPGFile As String
Dim curDevType As Integer
Dim curDevID As Integer
Dim rcJPGUser As Recordset
Dim curColumnID As Integer

Private Sub cmdFeedback_Click()
Dim rcData As Recordset
Dim rcData2 As Recordset

    If Trim(txtVal.Text) = "" Then Exit Sub
    If MsgBox("确定要以输入框中的值进行修正吗？", vbQuestion + vbYesNo, "修正") = vbYes Then
        Feedback Val(txtVal.Text)
    End If
    
    Set rcData = dbCbb.OpenRecordset(QData, dbOpenDynaset)
    Set rcData2 = dbCbb.OpenRecordset("UserData2", dbOpenDynaset)
    With rcData
    .FindFirst "DevID=" + Format(curDevID) _
        & " and UserID=" + Format(curUserID) _
        & " and format(Date,""yyyy-mm-dd"")=""" _
        & Format(curDate, "yyyy-mm-dd") + """"
    If Not .NoMatch Then
        .Edit
        !Value = Val(txtVal.Text)
        .Update
    End If
    .Close
    End With
    With rcData2
    .FindFirst "DevID=" + Format(curDevID) _
        & " and UserID=" + Format(curUserID) _
        & " and format(Date,""yyyy-mm-dd"")=""" _
        & Format(curDate, "yyyy-mm-dd") + """"
    If Not .NoMatch Then
        .Edit
        !Value = Val(txtVal.Text)
        .Update
    End If
    .Close
    End With
    
    With frmQuery
    Select Case gShowJPGFrom
        Case 1  'from frmQuery.QData1
            .lvwData1.SelectedItem.SubItems(curColumnID - 1) = Val(txtVal)
        Case 2  'from frmShowAll.QData2
            .lvwData2.SelectedItem.SubItems(curColumnID - 1) = Val(txtVal)
        Case Else
    End Select
    End With
End Sub

Private Sub cmdTranslate_Click()
Dim temVal As Long
Dim sDevaddr As String
Dim nStart As Integer

    nStart = InStr(1, curJPGFile, "_")
    sDevaddr = Mid(curJPGFile, nStart + 1, 10)
    'temVal = Translate(curJPGFile)
    temVal = Recognize(curJPGFile, sDevaddr)
    txtVal = temVal
End Sub

Private Sub Form_Load()
    Set rcJPGUser = dbCbb.OpenRecordset("UserDev", dbOpenSnapshot)
    gJPGShow = True
    SetOnTop Me.hwnd
    showJPG
    initVal
End Sub

Private Sub Form_Unload(Cancel As Integer)
    gJPGShow = False
End Sub

Sub initVal()
    With srbJPG
    .Max = frmQuery.lvwData1.ColumnHeaders.Count - 3
    .Min = 1
    .Value = .Min
    .LargeChange = 1
    .SmallChange = 1
    curDevType = .Value
    .Refresh
    End With
    
End Sub
Sub showJPG()
Dim nCardAddr As Long
Dim nDevAddr As Long
Dim sDevaddr As String

    curDevType = srbJPG.Value
    With frmQuery
    Select Case gShowJPGFrom
        Case 1  'from frmQuery.QData1
            curUserID = .lvwData1.SelectedItem.Text
            If Not IsDate(.cmbDate1.List(.cmbDate1.ListIndex)) And Not IsDate(.cmbDate2.List(.cmbDate2.ListIndex)) Then
                Exit Sub
            End If
            If Not IsDate(.cmbDate1.List(.cmbDate1.ListIndex)) Then
                curDate = .cmbDate2.List(.cmbDate2.ListIndex)
            ElseIf Not IsDate(.cmbDate2.List(.cmbDate2.ListIndex)) Then
                curDate = .cmbDate1.List(.cmbDate1.ListIndex)
            Else
                If CDate(.cmbDate1.List(.cmbDate1.ListIndex)) > CDate(.cmbDate2.List(.cmbDate2.ListIndex)) Then
                    curDate = .cmbDate1.List(.cmbDate1.ListIndex)
                Else
                    curDate = .cmbDate2.List(.cmbDate2.ListIndex)
                End If
            End If
            curJPGDir = Format(curDate, "yyyymmdd")
            rcJPGUser.FindFirst "UserID=" & curUserID & " and devType=" & curDevType
            sDevaddr = "0000000000"
            If Not rcJPGUser.NoMatch Then
                sDevaddr = Format(rcJPGUser!CardTermID, "00000000") & Format(rcJPGUser!CardUserID, "00")
                curDevID = rcJPGUser!devID
            End If
            curJPGFile = App.Path & "\data\" & curJPGDir & "\" & curUserID & "-" & curDevType & "_" & sDevaddr & ".jpg"
            curColumnID = 3 + curDevType
            curDevName = .lvwData1.ColumnHeaders.Item(curColumnID).Text
        Case 2  'from frmQuery.QData2
            curUserID = .lvwData2.SelectedItem.Text
            If Not IsDate(.cmbDate1.List(.cmbDate1.ListIndex)) Or Not IsDate(.cmbDate2.List(.cmbDate2.ListIndex)) Then
                Exit Sub
            End If
            If CDate(.cmbDate1.List(.cmbDate1.ListIndex)) > CDate(.cmbDate2.List(.cmbDate2.ListIndex)) Then
                curDate = .cmbDate2.List(.cmbDate2.ListIndex)
            Else
                curDate = .cmbDate1.List(.cmbDate1.ListIndex)
            End If
            curJPGDir = Format(curDate, "yyyymmdd")
            sDevaddr = "0000000000"
            If Not rcJPGUser.NoMatch Then
                sDevaddr = Format(rcJPGUser!CardTermID, "00000000") & Format(rcJPGUser!CardUserID, "00")
                curDevID = rcJPGUser!devID
            End If
            curJPGFile = App.Path & "\data\" & curJPGDir & "\" & curUserID & "-" & curDevType & "_" & sDevaddr & ".jpg"
            curColumnID = 3 + curDevType
            curDevName = .lvwData2.ColumnHeaders.Item(curColumnID).Text
    End Select
    End With
    
    If curUserID >= 0 Then
        Me.Caption = "用户[" & curUserID & "-" & curDevType & "  " & IIf(curDevName = "", "", curDevName) & "]数据图像"
    Else
        Me.Caption = "用户数据图像"
    End If
    If Dir(curJPGFile, vbNormal) <> "" Then
        imgJPG.Picture = LoadPicture(curJPGFile)
        cmdTranslate.Enabled = True
        cmdFeedback.Enabled = True
    Else
        imgJPG.Picture = LoadPicture()
        cmdTranslate.Enabled = False
        cmdFeedback.Enabled = False
    End If
End Sub

Private Sub srbJPG_Change()
    showJPG
End Sub