counter.asp

嘉缘人才6.0精简 ,很好用的人才系统

<%
Option Explicit
Response.buffer=true
on error resume next

'---------------------------程序配置变量---------------------------
dim num_color,file_end,file_index
num_color="#ff0000"			'数字显示颜色
file_end=".inc"				'数据文件的文件名
file_index="index"&file_end		'总数据文件名：index.inc
'---------------------------配置变量结束---------------------------

dim visitors,count,visitor_s,sortfile,sortfiles,file_name,file_names,out
dim sort_name,sort_id,fs,thisfile,index_s,right_s,max_s,tim_s,html_temp
sort_name=request.querystring("action")
if sort_name="" or isnull(sort_name) then
  response.end
end if

Set fs = CreateObject("Scripting.FileSystemObject")

if sort_name<>"" then
  sort_name=sort_name&file_end
  sortfile=server.mappath(sort_name)
  Set file_name = fs.OpenTextFile(sortfile)
  visitors=file_name.readline
  file_name.close

  if request.querystring("refresh")<>"no" or request.cookies("yjysjob_online")("counter_name")<>sort_name then
    visitors=visitors+1
    Set out=fs.CreateTextFile(sortfile)
    out.WriteLine(visitors)
    out.close
    
    sortfiles=server.mappath(file_index)
    Set file_names = fs.OpenTextFile(sortfiles)
    index_s=file_names.readline
   
    visitor_s=int(left(index_s,(Instr(index_s,"|")-1)))
    right_s=right(index_s,(len(index_s)-len(visitor_s)-1))
    max_s=int(left(right_s,(Instr(right_s,"=")-1)))
    tim_s=right(right_s,(len(right_s)-len(max_s)-1))
    visitor_s=visitor_s+1
    if int(Application("OnLine"))>max_s then
      max_s=int(Application("OnLine"))
      tim_s=now
    end if
    index_s=visitor_s & "|" & max_s & "=" & tim_s
    file_names.close
    
    Set out=fs.CreateTextFile(sortfiles)
    out.WriteLine(index_s)
    out.close

    response.cookies("yjysjob_online")("counter_name") = sort_name
    response.cookies("yjysjob_online")("counter_visitor_s") = visitor_s
    response.cookies("yjysjob_online")("counter_max_s") = max_s
    visitor_s=request.cookies("yjysjob_online")("counter_visitor_s")
    max_s=request.cookies("yjysjob_online")("counter_max_s")
  else
    visitor_s=request.cookies("yjysjob_online")("counter_visitor_s")
    max_s=request.cookies("yjysjob_online")("counter_max_s")
  end if

  if request.querystring("main")="view" then
    if err then
      err.clear
      html_temp="参数有错误或程序运行出错!"
    else
      html_temp="&nbsp;&nbsp;&nbsp;&nbsp;本站总访问量:&nbsp;<font color=" & num_color & ">" & visitor_s & "</font>&nbsp;人次</td></tr><tr height=20><td>"
      html_temp=html_temp & "&nbsp;&nbsp;&nbsp;&nbsp;最高峰&nbsp;<font color=" & num_color & " title='最高峰发生在：" & tim_s & "'>" & max_s & "</font>&nbsp;人在线</td></tr><tr height=20><td>&nbsp;&nbsp;&nbsp;&nbsp;当前有&nbsp;<font color=" & num_color & ">" & Application("OnLine") & "</font>&nbsp;人在线"
    end if
    response.write( "document.write(""" & html_temp & """);" )
  end if
end if

set fs=nothing
%>