company_update.asp

嘉缘人才6.0精简 ,很好用的人才系统

<!--#include file="../inc/sub.asp"-->
<!--#include file="../conn/conn.asp" -->
<%
link="company_modi.asp"
%>
<!--#include file="checkcmember.asp" -->
<!--#include file="../inc/replace.asp" -->
<%
company_name=CheckStr(trim(request("comname")))
set rs=server.createobject("ADODB.Recordset")
sql="select company_name from job_c_company where company_name='"&company_name&"' and company_cmember<>'"&cmember_login&"'"
rs.open sql,conn,1,1
if not rs.eof then
 rs.close
 set rs=nothing
 Response.Write ("<script language=JavaScript>{alert('错误：此公司名称已有人使用，请正确填写您的公司名称！');location.href = 'javascript:history.go(-1)';}</script>")
 Response.End
end if
rs.close
company_introduce=CheckStrbox(request("introduce"))
If lenmix(company_introduce)>=8000 Then 
response.write "<script language=javascript>alert('错误：公司简介太长了，要求不多于8000个字符!！');location.href='javascript:history.back()';</script>"
response.end 
end if
company_id=clng(trim(request("id")))
company_licence=CheckStr(trim(request("licence")))
company_trade=cint(trim(request("trade")))
company_provinceid=cint(trim(request("province")))
company_capitalid=cint(trim(request("capital")))
company_cityid=cint(trim(request("city")))
company_ecoclass=CheckStr(trim(request("ecoclass")))
founddate_year=trim(request("founddate_year"))
founddate_month=trim(request("founddate_month"))
founddate_day=trim(request("founddate_day"))
company_founddate=cdate(request("foundate"))
company_fund=clng(trim(request("fund")))
company_workers=CheckStr(trim(request("workers")))
company_address=CheckStr(trim(request("address")))
company_post=CheckStr(trim(request("post")))
company_contact=CheckStr(trim(Request("contact")))
company_tel=trim(Request("tel"))
if trim(request("telshowflag"))<>"" then
 company_telshowflag=cint(trim(request("telshowflag")))
else
 company_telshowflag=1
end if
company_fax=trim(Request("fax"))
company_email=CheckStr(trim(request("email")))
if trim(request("emailshowflag"))<>"" then
 company_emailshowflag=cint(trim(request("emailshowflag")))
else
 company_emailshowflag=1
end if
company_url=CheckStr(trim(request("url")))
if trim(request("resetcontactinfo"))<>"" then
 resetcontactinfo=cint(trim(request("resetcontactinfo")))
else
 resetcontactinfo=0
end if

'把修改后的企业资料存入company表，把相应基本资料存入cmember表
sql="select * from job_c_company where company_cmember='"&cmember_login&"'"
rs.open sql,conn,1,3

rs("company_name")=company_name
rs("company_provinceid")=company_provinceid
rs("company_capitalid")=company_capitalid
rs("company_cityid")=company_cityid
rs("company_licence")=company_licence
rs("company_trade")=company_trade
rs("company_ecoclass")=company_ecoclass
rs("company_founddate")=company_founddate
rs("company_fund")=company_fund
rs("company_workers")=company_workers
rs("company_introduce")=company_introduce
rs("company_address")=company_address
rs("company_post")=company_post
rs("company_contact")=company_contact
rs("company_tel")=company_tel
rs("company_telshowflag")=company_telshowflag
rs("company_fax")=company_fax
rs("company_email")=company_email
rs("company_emailshowflag")=company_emailshowflag
rs("company_url")=company_url
rs.update
rs.close
sql="select * from JOB_C_cmember where cmember_login='"&cmember_login&"'"
rs.open sql,conn,1,3

rs("cmember_comname")=company_name
rs("cmember_provinceid")=company_provinceid
rs("cmember_capitalid")=company_capitalid
rs("cmember_cityid")=company_cityid
rs("cmember_address")=company_address
rs("cmember_post")=company_post
rs("cmember_contact")=company_contact
rs("cmember_tel")=company_tel
rs("cmember_fax")=company_fax
rs("cmember_email")=company_email
rs("cmember_url")=company_url
rs.update
rs.close
set rs=nothing 
Response.Write ("<script language=JavaScript>{alert('资料更新成功！');location.href='company_modi.asp';}</script>")
response.End()
%>