program.txt

LED显示定义 定义164数据位 显示千位寄存器 发码次数寄存器

;--------------LED显示定义 
#DEFINE        DATE164       PORTB,3     ;定义164数据位
#DEFINE        CLK164        PORTB,2     ;定义164时钟位 
#DEFINE        ENABLE164     PORTB,1    ;定义164显示使能位

;－－－－－－－显示寄存器
DATE_ZJ        EQU           24H        ;显示数据寄存器
TEMP_JZ        EQU           25H        ;显示间址寄存器
BZ_TEMP        EQU           26H        ;刷新标志寄存器
COUNT_FMBCD    EQU           27H        ;发码次数寄存器
QIAN           EQU           28H        ;显示千位寄存器
BAI            EQU           29H        ;百
SHI            EQU           2AH        ;十
GE             EQU           2BH        ;个

;--------------显示代码表－－－－－－-------------------------
TB
               ADDWF       PCL,1
               RETLW       03H           ;0
               RETLW       9FH           ;1
               RETLW       25H           ;2
               RETLW       0DH           ;3
               RETLW       99H           ;4
               RETLW       49H           ;5
               RETLW       41H           ;6
               RETLW       1FH           ;7
               RETLW       01H           ;8
               RETLW       19H           ;9
               RETLW       11H           ;A
               RETLW       0C1H          ;B
               RETLW       63H           ;C
               RETLW       85H           ;D
               RETLW       61H           ;E
               RETLW       71H           ;F
               RETLW       0FFH          ;关显示
               RETURN

;==============显示子程序==================================
XIANSHI        BCF           BZ_TEMP,1    ;清刷新标志位
               MOVLW         28H
               MOVWF         TEMP_JZ
XIANSHI_1      BTFSC         TEMP_JZ,2
               GOTO          XIANSHI_WAN
               MOVF          TEMP_JZ,0
               MOVWF         FSR
               MOVF          00H,0
               CALL          TB
               MOVWF         DATE_ZJ
               CALL          FSBCD
               INCF          TEMP_JZ,1
               GOTO          XIANSHI_1          
XIANSHI_WAN    RETURN
;**************BCD码发送子程序****************************
FSBCD          MOVLW        08H           ;发送循环次数
               MOVWF        COUNT_FMBCD
               BCF          ENABLE164     ;关显示
               BCF          STATUS,0
FSBCD_1        BCF          CLK164
               RLF          DATE_ZJ,1
               BTFSS        STATUS,0
               GOTO         FSBCD_2
               BSF          DATE164
               GOTO         FSBCD_3
FSBCD_2        BCF          DATE164
               NOP
FSBCD_3        BSF          CLK164        ;产生时钟上升沿
               DECFSZ       COUNT_FMBCD,1 ;发送完毕否?   
               GOTO         FSBCD_1
               BSF          ENABLE164     ;开显示
               RETURN