sandpoint.ld

来自「一个开放源码」· LD 代码 · 共 40 行

run_base =  0x00800000;
load_base = 0x00900100;
text_base = 0x80000100;
ENTRY(text_base);
. = text_base;
SECTIONS
{
    /* The section .text has special meaning to some linker variants. We
       use .text0 to avoid triggering them. */
    .text0 text_base :  AT(load_base) 
    {
        *(.text) *(.rodata) *(.init) *(.fini) *(.ctors) *(.dtors)
        *(.gcc_except_table)
        *(.got)
        *(.got1)
        _GOT2_TABLE_ = .;
        *(.got2)
        _FIXUP_TABLE_ = .;
        *(.fixup)
    }
    PROVIDE(__end_text = .);
    . = (text_base == run_base) ? run_base + __end_text - text_base : run_base;
    .data   ALIGN(0x8000)  : AT ( load_base + SIZEOF(.text0)) 
    {
        PROVIDE(__start_data = .);
        *(.data) *(.data1) *(.sdata2)
        *(.sbss2)
        *(.sdata)  
    }
    PROVIDE(__end_data = .);
    PROVIDE(__bss_start = ALIGN(16));
    .bss  ALIGN (16): { *(.sbss) *(.bss) *(COMMON)
        PROVIDE(__bss_end = .);
        . = . + 0x2000;
        __stack_end = ALIGN(0x4000);
        __heap_end = ALIGN(0x8000);
    }
}
ENTRY(load_base );