znrm2.s

Optimized GotoBLAS libraries

/*********************************************************************/
/*                                                                   */
/*             Optimized BLAS libraries                              */
/*                     By Kazushige Goto <[e-mail]>     */
/*                                                                   */
/* Copyright (c) The University of Texas, 2005. All rights reserved. */
/* UNIVERSITY EXPRESSLY DISCLAIMS ANY AND ALL WARRANTIES CONCERNING  */
/* THIS SOFTWARE AND DOCUMENTATION, INCLUDING ANY WARRANTIES OF      */
/* MERCHANTABILITY, FITNESS FOR ANY PARTICULAR PURPOSE,              */
/* NON-INFRINGEMENT AND WARRANTIES OF PERFORMANCE, AND ANY WARRANTY  */
/* THAT MIGHT OTHERWISE ARISE FROM COURSE OF DEALING OR USAGE OF     */
/* TRADE. NO WARRANTY IS EITHER EXPRESS OR IMPLIED WITH RESPECT TO   */
/* THE USE OF THE SOFTWARE OR DOCUMENTATION.                         */
/* Under no circumstances shall University be liable for incidental, */
/* special, indirect, direct or consequential damages or loss of     */
/* profits, interruption of business, or related expenses which may  */
/* arise from use of Software or Documentation, including but not    */
/* limited to those resulting from defects in Software and/or        */
/* Documentation, or loss or inaccuracy of data of any kind.         */
/*********************************************************************/

#define ASSEMBLER
#include "common.h"
	
#define M	ARG1	/* rdi */
#define X	ARG2	/* rsi */
#define INCX	ARG3	/* rdx */

#define I	%rax

	PROLOGUE
	PROFCODE
	
#ifdef F_INTERFACE
#ifndef USE64BITINT
	movslq	(M),    M
	movslq	(INCX), INCX
#else
	movq	(M),    M
	movq	(INCX), INCX
#endif
#endif

	fldz
	testq	M, M
	jle	.L999
	testq	INCX, INCX
	jle	.L999

	salq	$ZBASE_SHIFT, INCX

	fldz
	fldz
	fldz
	cmpq	$SIZE * 2, INCX
	jne	.L40

	movq	M,  I
	sarq	$2, I
	jle	.L20
	ALIGN_4
	
.L10:
#if defined(HAVE_SSE) || defined(HAVE_SSE2)
        prefetcht0   80 * SIZE(X)
#endif

	FLD	0 * SIZE(X)
	fmul	%st, %st
	FLD	1 * SIZE(X)
	fmul	%st, %st
	FLD	2 * SIZE(X)
	fmul	%st, %st
	FLD	3 * SIZE(X)
	fmul	%st, %st

	faddp	%st, %st(7)
	faddp	%st, %st(5)
	faddp	%st, %st(3)
	faddp	%st, %st(1)

	FLD	4 * SIZE(X)
	fmul	%st, %st
	FLD	5 * SIZE(X)
	fmul	%st, %st
	FLD	6 * SIZE(X)
	fmul	%st, %st
	FLD	7 * SIZE(X)
	fmul	%st, %st

	addq	$8 * SIZE, X

	faddp	%st, %st(7)
	faddp	%st, %st(5)
	faddp	%st, %st(3)
	faddp	%st, %st(1)

	decq	I
	jg	.L10
	ALIGN_4

.L20:
	andq	$3,  M
	jle	.L998
	ALIGN_4


.L21:
	FLD	0 * SIZE(X)
	fmul	%st, %st
	FLD	1 * SIZE(X)
	fmul	%st, %st
	faddp	%st,%st(3)
	faddp	%st,%st(1)
	addq	$2 * SIZE, X
	decq	M
	jg	.L21
	jmp	.L998
	ALIGN_4

.L40:
	movq	M, I
	sarq	$2,   I
	jle	.L60
	ALIGN_4
	
.L50:
	FLD	0 * SIZE(X)
	fmul	%st, %st
	FLD	1 * SIZE(X)
	addq	INCX, X
	fmul	%st, %st
	FLD	0 * SIZE(X)
	fmul	%st, %st
	FLD	1 * SIZE(X)
	addq	INCX, X
	fmul	%st, %st

	faddp	%st, %st(7)
	faddp	%st, %st(5)
	faddp	%st, %st(3)
	faddp	%st, %st(1)

	FLD	0 * SIZE(X)
	fmul	%st, %st
	FLD	1 * SIZE(X)
	addq	INCX, X
	fmul	%st, %st
	FLD	0 * SIZE(X)
	fmul	%st, %st
	FLD	1 * SIZE(X)
	addq	INCX, X
	fmul	%st, %st

	faddp	%st, %st(7)
	faddp	%st, %st(5)
	faddp	%st, %st(3)
	faddp	%st, %st(1)

	decq	I
	jg	.L50
	ALIGN_4

.L60:
	andq	$3,  M
	jle	.L998
	ALIGN_4


.L61:
	FLD	0 * SIZE(X)
	fmul	%st, %st
	FLD	1 * SIZE(X)
	addq	INCX, X
	fmul	%st, %st
	faddp	%st,%st(3)
	faddp	%st,%st(1)
	decq	M
	jg	.L61
	ALIGN_4

.L998:
	faddp	%st,%st(2)
	faddp	%st,%st(1)
	faddp	%st,%st(1)
	ALIGN_4

.L999:
	fsqrt
#ifndef XDOUBLE
	subq	$2 * SIZE, %rsp
#if !defined(DOUBLE) && defined(F_INTERFACE) && \
     defined(F_INTERFACE_F2C) && defined (NEED_F2CCONV)
	fstpl	(%rsp)
	movsd	(%rsp), %xmm0
#else	
	FST	(%rsp)
	MOVSD	(%rsp), %xmm0
#endif
	add	$2 * SIZE, %rsp
#endif
	ret

	EPILOGUE