zgemm3m_kernel_8x4_core2.s

Optimized GotoBLAS libraries

/*********************************************************************/
/*                                                                   */
/*             Optimized BLAS libraries                              */
/*                     By Kazushige Goto <[e-mail]>     */
/*                                                                   */
/* Copyright (c) The University of Texas, 2005. All rights reserved. */
/* UNIVERSITY EXPRESSLY DISCLAIMS ANY AND ALL WARRANTIES CONCERNING  */
/* THIS SOFTWARE AND DOCUMENTATION, INCLUDING ANY WARRANTIES OF      */
/* MERCHANTABILITY, FITNESS FOR ANY PARTICULAR PURPOSE,              */
/* NON-INFRINGEMENT AND WARRANTIES OF PERFORMANCE, AND ANY WARRANTY  */
/* THAT MIGHT OTHERWISE ARISE FROM COURSE OF DEALING OR USAGE OF     */
/* TRADE. NO WARRANTY IS EITHER EXPRESS OR IMPLIED WITH RESPECT TO   */
/* THE USE OF THE SOFTWARE OR DOCUMENTATION.                         */
/* Under no circumstances shall University be liable for incidental, */
/* special, indirect, direct or consequential damages or loss of     */
/* profits, interruption of business, or related expenses which may  */
/* arise from use of Software or Documentation, including but not    */
/* limited to those resulting from defects in Software and/or        */
/* Documentation, or loss or inaccuracy of data of any kind.         */
/*********************************************************************/

#define ASSEMBLER
#include "common.h"
 
#define OLD_M	%rdi
#define OLD_N	%rsi
#define M	%r13
#define N	%r14
#define K	%rdx

#define A	%rcx
#define B	%r8
#define C	%r9
#define LDC	%r10
	
#define I	%r11
#define AO	%rdi
#define BO	%rsi
#define	CO1	%rbx
#define CO2	%rbp
#define BB	%r12

#ifndef WINDOWS_ABI

#define STACKSIZE 64

#define OLD_LDC		 8 + STACKSIZE(%rsp)
#define OLD_OFFSET	16 + STACKSIZE(%rsp)

#else

#define STACKSIZE 256

#define OLD_ALPHA_I	40 + STACKSIZE(%rsp)
#define OLD_A		48 + STACKSIZE(%rsp)
#define OLD_B		56 + STACKSIZE(%rsp)
#define OLD_C		64 + STACKSIZE(%rsp)
#define OLD_LDC		72 + STACKSIZE(%rsp)
#define OLD_OFFSET	80 + STACKSIZE(%rsp)

#endif

#define ALPHA	    0(%rsp)
#define J	   16(%rsp)
#define OFFSET	   24(%rsp)
#define KK	   32(%rsp)
#define KKK	   40(%rsp)
#define BUFFER	  128(%rsp)

#define PREFETCH_R    (16 * 16 + 0)
#define PREFETCH_W    (PREFETCH_R * 2)

#define PREFETCHSIZE  (16 * 21 + 8)
#define PREFETCH     prefetcht0

#define LOCAL_BUFFER_SIZE  GEMM_Q * GEMM_UNROLL_N * COMPSIZE * 16

	PROLOGUE
	PROFCODE
	
	subq	$STACKSIZE, %rsp
	movq	%rbx,  0(%rsp)
	movq	%rbp,  8(%rsp)
	movq	%r12, 16(%rsp)
	movq	%r13, 24(%rsp)
	movq	%r14, 32(%rsp)
	movq	%r15, 40(%rsp)

#ifdef WINDOWS_ABI
	movq	%rdi,    48(%rsp)
	movq	%rsi,    56(%rsp)
	movups	%xmm6,   64(%rsp)
	movups	%xmm7,   80(%rsp)
	movups	%xmm8,   96(%rsp)
	movups	%xmm9,  112(%rsp)
	movups	%xmm10, 128(%rsp)
	movups	%xmm11, 144(%rsp)
	movups	%xmm12, 160(%rsp)
	movups	%xmm13, 176(%rsp)
	movups	%xmm14, 192(%rsp)
	movups	%xmm15, 208(%rsp)

	movq	ARG1,      OLD_M
	movq	ARG2,      OLD_N
	movq	ARG3,      K
	movq	OLD_A,     A
	movq	OLD_B,     B
	movq	OLD_C,     C
	movq	OLD_LDC,   LDC
#ifdef TRMMKERNEL
	movsd	OLD_OFFSET, %xmm12
#endif
	movaps	%xmm3, %xmm0
	movss	OLD_ALPHA_I, %xmm1
#else
	movq	OLD_LDC,   LDC
#ifdef TRMMKERNEL
	movsd	OLD_OFFSET, %xmm12
#endif
#endif

	movq	%rsp, %r15	# save old stack
	subq	$256 + LOCAL_BUFFER_SIZE, %rsp
	andq	$-4096, %rsp	# align stack

	movss	%xmm0,  0 + ALPHA
	movss	%xmm1,  4 + ALPHA
	movss	%xmm0,  8 + ALPHA
	movss	%xmm1, 12 + ALPHA

	subq	$-32 * SIZE, A
	subq	$-32 * SIZE, B

#ifdef TRMMKERNEL
	movsd	%xmm12, OFFSET
	movsd	%xmm12, KK
#ifndef LEFT
	negq	KK
#endif	
#endif

	movq	OLD_M, M
	movq	OLD_N, N

	salq	$ZBASE_SHIFT, LDC

	movq	N,  J
	sarq	$2, J
	jle	.L50
	ALIGN_4

.L01:
#if defined(TRMMKERNEL) && defined(LEFT)
	movq	OFFSET, %rax
	movq	%rax, KK
#endif	

/* Copying to Sub Buffer */
	leaq	32 * SIZE + BUFFER, BO
	
	movq	K, %rax
	sarq	$2, %rax
	jle	.L05
	ALIGN_4
	
.L02:
	prefetcht0	(PREFETCH_R + 0) * SIZE(B)
	movaps	 -32 * SIZE(B), %xmm3
	movaps	 -28 * SIZE(B), %xmm7
	movaps	 -24 * SIZE(B), %xmm11
	movaps	 -20 * SIZE(B), %xmm15

	prefetcht0	(PREFETCH_W +  0) * SIZE(BO)
	pshufd	$0x00, %xmm3,  %xmm0
	pshufd	$0x55, %xmm3,  %xmm1
	pshufd	$0xaa, %xmm3,  %xmm2
	pshufd	$0xff, %xmm3,  %xmm3
	pshufd	$0x00, %xmm7,  %xmm4
	pshufd	$0x55, %xmm7,  %xmm5
	pshufd	$0xaa, %xmm7,  %xmm6
	pshufd	$0xff, %xmm7,  %xmm7

	prefetcht0	(PREFETCH_W + 16) * SIZE(BO)
	pshufd	$0x00, %xmm11, %xmm8
	pshufd	$0x55, %xmm11, %xmm9
	pshufd	$0xaa, %xmm11, %xmm10
	pshufd	$0xff, %xmm11, %xmm11
	pshufd	$0x00, %xmm15, %xmm12
	pshufd	$0x55, %xmm15, %xmm13
	pshufd	$0xaa, %xmm15, %xmm14
	pshufd	$0xff, %xmm15, %xmm15

	prefetcht0	(PREFETCH_W + 32) * SIZE(BO)
	movaps	%xmm0,  -32 * SIZE(BO)
	movaps	%xmm1,  -28 * SIZE(BO)
	movaps	%xmm2,  -24 * SIZE(BO)
	movaps	%xmm3,  -20 * SIZE(BO)
	movaps	%xmm4,  -16 * SIZE(BO)
	movaps	%xmm5,  -12 * SIZE(BO)
	movaps	%xmm6,   -8 * SIZE(BO)
	movaps	%xmm7,   -4 * SIZE(BO)

	prefetcht0	(PREFETCH_W + 48) * SIZE(BO)
	movaps	%xmm8,    0 * SIZE(BO)
	movaps	%xmm9,    4 * SIZE(BO)
	movaps	%xmm10,   8 * SIZE(BO)
	movaps	%xmm11,  12 * SIZE(BO)
	movaps	%xmm12,  16 * SIZE(BO)
	movaps	%xmm13,  20 * SIZE(BO)
	movaps	%xmm14,  24 * SIZE(BO)
	movaps	%xmm15,  28 * SIZE(BO)

	subq	$-16 * SIZE, B
	subq	$-64 * SIZE, BO
	subq	$1, %rax
	jne	.L02
	ALIGN_4

.L05:
	movq	K, %rax
	andq	$3, %rax
	BRANCH
	jle	.L10
	ALIGN_4

.L06:
	movaps	 -32 * SIZE(B), %xmm3

	pshufd	$0x00, %xmm3,  %xmm0
	pshufd	$0x55, %xmm3,  %xmm1
	pshufd	$0xaa, %xmm3,  %xmm2
	pshufd	$0xff, %xmm3,  %xmm3

	movaps	%xmm0,  -32 * SIZE(BO)
	movaps	%xmm1,  -28 * SIZE(BO)
	movaps	%xmm2,  -24 * SIZE(BO)
	movaps	%xmm3,  -20 * SIZE(BO)

	addq	$ 4 * SIZE, B
	addq	$16 * SIZE, BO
	subq	$1, %rax
	jne	.L06
	ALIGN_4
	
.L10:
	movq	B, BB

	movq	C, CO1			# coffset1 = c
	leaq	(C, LDC, 1), CO2	# coffset2 = c + ldc
	movq	A, AO		# aoffset = a

	movq	M,  I
	sarq	$3, I
	jle	.L20
	ALIGN_4

.L11:
#if !defined(TRMMKERNEL) || \
	(defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
	(defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))

	leaq	40 * SIZE + BUFFER, BO
#else
	leaq	40 * SIZE + BUFFER, BO
	movq	KK, %rax
	leaq	(, %rax,   8), %rax
	leaq	(AO, %rax, 4), AO
	leaq	(BO, %rax, 8), BO
#endif	

	pxor	%xmm8, %xmm8
	movaps	-32 * SIZE(AO), %xmm0
	pxor	%xmm9, %xmm9
	movaps	-28 * SIZE(AO), %xmm1
	pxor	%xmm10, %xmm10
	movaps	-40 * SIZE(BO), %xmm6
	pxor	%xmm11, %xmm11
	movaps	-36 * SIZE(BO), %xmm7

	prefetcht0	(PREFETCH_R +  0) * SIZE(BB)

	prefetcht0    15 * SIZE(CO1)
	pxor	%xmm12, %xmm12
	pxor	%xmm13, %xmm13
	prefetcht0    15 * SIZE(CO2)
	pxor	%xmm14, %xmm14
	pxor	%xmm15, %xmm15

	prefetcht0    15 * SIZE(CO1, LDC, 2)
	pxor	%xmm2, %xmm2
	pxor	%xmm3, %xmm3
	prefetcht0    15 * SIZE(CO2, LDC, 2)
	pxor	%xmm4, %xmm4
	pxor	%xmm5, %xmm5

	subq		$-8 * SIZE, BB

#ifndef TRMMKERNEL
	movq	K, %rax
#elif (defined(LEFT) && !defined(TRANSA)) || (!defined(LEFT) && defined(TRANSA))
	movq	K, %rax
	subq	KK, %rax
	movq	%rax, KKK	
#else
	movq	KK, %rax
#ifdef LEFT
	addq	$8, %rax
#else
	addq	$4, %rax
#endif
	movq	%rax, KKK
#endif
	sarq	$2, %rax
	jle	.L15
	ALIGN_4

.L12:	
	addps	%xmm2, %xmm10
	movaps	-32 * SIZE(BO), %xmm2
	addps	%xmm3, %xmm14
	PADDING;
	movaps	%xmm6, %xmm3
	PREFETCH (PREFETCHSIZE +  0) * SIZE(AO)
	mulps	%xmm0, %xmm6
	mulps	%xmm1, %xmm3

	addps	%xmm4, %xmm11
	movaps	-28 * SIZE(BO), %xmm4
	addps	%xmm5, %xmm15
	movaps	%xmm7, %xmm5
	mulps	%xmm0, %xmm7
	mulps	%xmm1, %xmm5

	addps	%xmm6, %xmm8
	movaps	-24 * SIZE(BO), %xmm6
	addps	%xmm3, %xmm12
	movaps	%xmm2, %xmm3
	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3

	addps	%xmm7, %xmm9
	movaps	-20 * SIZE(BO), %xmm7
	addps	%xmm5, %xmm13
	movaps	 %xmm4, %xmm5
	mulps	%xmm0, %xmm4
	movaps	-24 * SIZE(AO), %xmm0
	mulps	%xmm1, %xmm5
	movaps	-20 * SIZE(AO), %xmm1

	addps	%xmm2, %xmm10
	movaps	-16 * SIZE(BO), %xmm2
	addps	%xmm3, %xmm14
	movaps	%xmm6, %xmm3
	mulps	%xmm0, %xmm6
	mulps	%xmm1, %xmm3

	addps	%xmm4, %xmm11
	movaps  -12 * SIZE(BO), %xmm4
	addps	%xmm5, %xmm15
	movaps	%xmm7, %xmm5
	mulps	%xmm0, %xmm7
	mulps	%xmm1, %xmm5

	addps	%xmm6, %xmm8
	movaps	 -8 * SIZE(BO), %xmm6
	addps	%xmm3, %xmm12
	movaps	%xmm2, %xmm3
	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3

	addps	%xmm7, %xmm9
	movaps	 -4 * SIZE(BO), %xmm7
	addps	%xmm5, %xmm13
	movaps	 %xmm4, %xmm5
	mulps	%xmm0, %xmm4
	movaps	-16 * SIZE(AO), %xmm0
	mulps	%xmm1, %xmm5
	movaps	-12 * SIZE(AO), %xmm1

	addps	%xmm2, %xmm10
	movaps	  0 * SIZE(BO), %xmm2
	addps	%xmm3, %xmm14
	PADDING;
	movaps	%xmm6, %xmm3
	PREFETCH (PREFETCHSIZE + 16) * SIZE(AO)
	mulps	%xmm0, %xmm6
	mulps	%xmm1, %xmm3

	addps	%xmm4, %xmm11
	movaps	  4 * SIZE(BO), %xmm4
	addps	%xmm5, %xmm15
	movaps	%xmm7, %xmm5
	mulps	%xmm0, %xmm7
	mulps	%xmm1, %xmm5

	addps	%xmm6, %xmm8
	movaps	  8 * SIZE(BO), %xmm6
	addps	%xmm3, %xmm12
	movaps	%xmm2, %xmm3
	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3

	addps	%xmm7, %xmm9
	movaps	 12 * SIZE(BO), %xmm7
	addps	%xmm5, %xmm13
	movaps	 %xmm4, %xmm5
	mulps	%xmm0, %xmm4
	movaps	 -8 * SIZE(AO), %xmm0
	mulps	%xmm1, %xmm5
	movaps	 -4 * SIZE(AO), %xmm1

	addps	%xmm2, %xmm10
	movaps	 16 * SIZE(BO), %xmm2
	addps	%xmm3, %xmm14
	movaps	%xmm6, %xmm3
	mulps	%xmm0, %xmm6
	mulps	%xmm1, %xmm3

	addps	%xmm4, %xmm11
	movaps	 20 * SIZE(BO), %xmm4
	addps	%xmm5, %xmm15
	movaps	%xmm7, %xmm5
	mulps	%xmm0, %xmm7
	mulps	%xmm1, %xmm5

	addps	%xmm6, %xmm8
	movaps	 24 * SIZE(BO), %xmm6
	addps	%xmm3, %xmm12
	movaps	%xmm2, %xmm3
	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3
	subq	$-32 * SIZE, AO

	addps	%xmm7, %xmm9
	movaps	 28 * SIZE(BO), %xmm7
	addps	%xmm5, %xmm13
	movaps	 %xmm4, %xmm5
	mulps	%xmm0, %xmm4
	movaps	-32 * SIZE(AO), %xmm0
	mulps	%xmm1, %xmm5
	movaps	-28 * SIZE(AO), %xmm1

	subq	$-64 * SIZE, BO
	subq	$1, %rax
	jg,pt	.L12
	ALIGN_4

.L15:
#ifndef TRMMKERNEL
	movq	K, %rax
#else
	movq	KKK, %rax
#endif
	andq	$3, %rax		# if (k & 1)
	je,pt .L18
	ALIGN_4

.L16:
	addps	%xmm2, %xmm10
	movaps	-32 * SIZE(BO), %xmm2
	addps	%xmm3, %xmm14
	movaps	%xmm6, %xmm3
	mulps	%xmm0, %xmm6
	mulps	%xmm1, %xmm3

	addps	%xmm4, %xmm11
	movaps	-28 * SIZE(BO), %xmm4
	addps	%xmm5, %xmm15
	movaps	%xmm7, %xmm5
	mulps	%xmm0, %xmm7
	mulps	%xmm1, %xmm5

	addps	%xmm6, %xmm8
	movaps	-24 * SIZE(BO), %xmm6
	addps	%xmm3, %xmm12
	addq	$8  * SIZE, AO
	movaps	%xmm2, %xmm3
	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3

	addps	%xmm7, %xmm9
	movaps	-20 * SIZE(BO), %xmm7
	addps	%xmm5, %xmm13
	addq	$16 * SIZE, BO
	movaps	 %xmm4, %xmm5
	mulps	%xmm0, %xmm4
	movaps	-32 * SIZE(AO), %xmm0
	mulps	%xmm1, %xmm5
	movaps	-28 * SIZE(AO), %xmm1

	subq	$1, %rax
	jg,pt	.L16
	ALIGN_4

.L18:
	movaps	ALPHA, %xmm7

	addps	%xmm2, %xmm10
	addps	%xmm3, %xmm14
	addps	%xmm4, %xmm11
	addps	%xmm5, %xmm15

	movsd	 0 * SIZE(CO1), %xmm0
	movhps	 2 * SIZE(CO1), %xmm0
	movsd	 4 * SIZE(CO1), %xmm1
	movhps	 6 * SIZE(CO1), %xmm1
	movsd	 8 * SIZE(CO1), %xmm2
	movhps	10 * SIZE(CO1), %xmm2
	movsd	12 * SIZE(CO1), %xmm3
	movhps	14 * SIZE(CO1), %xmm3

	pshufd	$0x50, %xmm8,  %xmm4
	pshufd	$0xfa, %xmm8,  %xmm8
	pshufd	$0x50, %xmm12, %xmm5
	pshufd	$0xfa, %xmm12, %xmm12

	mulps	%xmm7, %xmm4
	mulps	%xmm7, %xmm8
	mulps	%xmm7, %xmm5
	mulps	%xmm7, %xmm12

	addps	%xmm0, %xmm4
	addps	%xmm1, %xmm8
	addps	%xmm2, %xmm5
	addps	%xmm3, %xmm12

	movlps	%xmm4,   0 * SIZE(CO1)
	movhps	%xmm4,   2 * SIZE(CO1)
	movlps	%xmm8,   4 * SIZE(CO1)
	movhps	%xmm8,   6 * SIZE(CO1)
	movlps	%xmm5,   8 * SIZE(CO1)
	movhps	%xmm5,  10 * SIZE(CO1)
	movlps	%xmm12, 12 * SIZE(CO1)
	movhps	%xmm12, 14 * SIZE(CO1)

	movsd	 0 * SIZE(CO2), %xmm0
	movhps	 2 * SIZE(CO2), %xmm0
	movsd	 4 * SIZE(CO2), %xmm1
	movhps	 6 * SIZE(CO2), %xmm1
	movsd	 8 * SIZE(CO2), %xmm2
	movhps	10 * SIZE(CO2), %xmm2
	movsd	12 * SIZE(CO2), %xmm3
	movhps	14 * SIZE(CO2), %xmm3

	pshufd	$0x50, %xmm9,  %xmm4
	pshufd	$0xfa, %xmm9,  %xmm9
	pshufd	$0x50, %xmm13, %xmm5
	pshufd	$0xfa, %xmm13, %xmm13

	mulps	%xmm7, %xmm4
	mulps	%xmm7, %xmm9
	mulps	%xmm7, %xmm5
	mulps	%xmm7, %xmm13

	addps	%xmm0, %xmm4
	addps	%xmm1, %xmm9
	addps	%xmm2, %xmm5
	addps	%xmm3, %xmm13

	movlps	%xmm4,   0 * SIZE(CO2)
	movhps	%xmm4,   2 * SIZE(CO2)
	movlps	%xmm9,   4 * SIZE(CO2)
	movhps	%xmm9,   6 * SIZE(CO2)
	movlps	%xmm5,   8 * SIZE(CO2)
	movhps	%xmm5,  10 * SIZE(CO2)
	movlps	%xmm13, 12 * SIZE(CO2)
	movhps	%xmm13, 14 * SIZE(CO2)
	
	movsd	 0 * SIZE(CO1, LDC, 2), %xmm0
	movhps	 2 * SIZE(CO1, LDC, 2), %xmm0
	movsd	 4 * SIZE(CO1, LDC, 2), %xmm1
	movhps	 6 * SIZE(CO1, LDC, 2), %xmm1
	movsd	 8 * SIZE(CO1, LDC, 2), %xmm2
	movhps	10 * SIZE(CO1, LDC, 2), %xmm2
	movsd	12 * SIZE(CO1, LDC, 2), %xmm3
	movhps	14 * SIZE(CO1, LDC, 2), %xmm3

	pshufd	$0x50, %xmm10,  %xmm4
	pshufd	$0xfa, %xmm10,  %xmm10
	pshufd	$0x50, %xmm14, %xmm5
	pshufd	$0xfa, %xmm14, %xmm14

	mulps	%xmm7, %xmm4
	mulps	%xmm7, %xmm10
	mulps	%xmm7, %xmm5
	mulps	%xmm7, %xmm14

	addps	%xmm0, %xmm4
	addps	%xmm1, %xmm10
	addps	%xmm2, %xmm5
	addps	%xmm3, %xmm14

	movlps	%xmm4,   0 * SIZE(CO1, LDC, 2)
	movhps	%xmm4,   2 * SIZE(CO1, LDC, 2)
	movlps	%xmm10,  4 * SIZE(CO1, LDC, 2)
	movhps	%xmm10,  6 * SIZE(CO1, LDC, 2)
	movlps	%xmm5,   8 * SIZE(CO1, LDC, 2)
	movhps	%xmm5,  10 * SIZE(CO1, LDC, 2)
	movlps	%xmm14, 12 * SIZE(CO1, LDC, 2)
	movhps	%xmm14, 14 * SIZE(CO1, LDC, 2)

	movsd	 0 * SIZE(CO2, LDC, 2), %xmm0
	movhps	 2 * SIZE(CO2, LDC, 2), %xmm0
	movsd	 4 * SIZE(CO2, LDC, 2), %xmm1
	movhps	 6 * SIZE(CO2, LDC, 2), %xmm1
	movsd	 8 * SIZE(CO2, LDC, 2), %xmm2
	movhps	10 * SIZE(CO2, LDC, 2), %xmm2
	movsd	12 * SIZE(CO2, LDC, 2), %xmm3
	movhps	14 * SIZE(CO2, LDC, 2), %xmm3

	pshufd	$0x50, %xmm11, %xmm4
	pshufd	$0xfa, %xmm11, %xmm11
	pshufd	$0x50, %xmm15, %xmm5
	pshufd	$0xfa, %xmm15, %xmm15

	mulps	%xmm7, %xmm4
	mulps	%xmm7, %xmm11
	mulps	%xmm7, %xmm5
	mulps	%xmm7, %xmm15

	addps	%xmm0, %xmm4
	addps	%xmm1, %xmm11
	addps	%xmm2, %xmm5
	addps	%xmm3, %xmm15

	movlps	%xmm4,   0 * SIZE(CO2, LDC, 2)
	movhps	%xmm4,   2 * SIZE(CO2, LDC, 2)
	movlps	%xmm11,  4 * SIZE(CO2, LDC, 2)
	movhps	%xmm11,  6 * SIZE(CO2, LDC, 2)
	movlps	%xmm5,   8 * SIZE(CO2, LDC, 2)
	movhps	%xmm5,  10 * SIZE(CO2, LDC, 2)
	movlps	%xmm15, 12 * SIZE(CO2, LDC, 2)
	movhps	%xmm15, 14 * SIZE(CO2, LDC, 2)
	
	addq	$16 * SIZE, CO1
	addq	$16 * SIZE, CO2
	subq	$1, I
	jg	.L11
	ALIGN_4	

.L20:
	testq	$4, M
	jle	.L30

#if !defined(TRMMKERNEL) || \
	(defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
	(defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))

	leaq	32 * SIZE + BUFFER, BO
#else
	leaq	32 * SIZE + BUFFER, BO
	movq	KK, %rax
	leaq	(, %rax,   8), %rax
	leaq	(AO, %rax, 2), AO
	leaq	(BO, %rax, 8), BO
#endif	

	pxor	%xmm8, %xmm8
	pxor	%xmm9, %xmm9
	pxor	%xmm10, %xmm10
	pxor	%xmm11, %xmm11

#ifndef TRMMKERNEL
	movq	K, %rax