gemm_kernel_8x4_core2.s

Optimized GotoBLAS libraries

.L100:
	testq	$1, N
	jle	.L999
	ALIGN_4

.L101:
/* Copying to Sub Buffer */
	leaq	BUFFER, BO
	
#if defined(TRMMKERNEL) && defined(LEFT)
	movq	OFFSET, %rax
	movq	%rax, KK
#endif	

	movq	K, %rax
	sarq	$4, %rax
	jle	.L103

	addq	%rax, %rax
	ALIGN_4
	
.L102:
	movss	 -32 * SIZE(B), %xmm0
	movss	 -31 * SIZE(B), %xmm1
	movss	 -30 * SIZE(B), %xmm2
	movss	 -29 * SIZE(B), %xmm3
	movss	 -28 * SIZE(B), %xmm4
	movss	 -27 * SIZE(B), %xmm5
	movss	 -26 * SIZE(B), %xmm6
	movss	 -25 * SIZE(B), %xmm7

	shufps	$0, %xmm0,  %xmm0
	shufps	$0, %xmm1,  %xmm1
	shufps	$0, %xmm2,  %xmm2
	shufps	$0, %xmm3,  %xmm3
	shufps	$0, %xmm4,  %xmm4
	shufps	$0, %xmm5,  %xmm5
	shufps	$0, %xmm6,  %xmm6
	shufps	$0, %xmm7,  %xmm7

	movaps	%xmm0,   0 * SIZE(BO)
	movaps	%xmm1,   4 * SIZE(BO)
	movaps	%xmm2,   8 * SIZE(BO)
	movaps	%xmm3,  12 * SIZE(BO)
	movaps	%xmm4,  16 * SIZE(BO)
	movaps	%xmm5,  20 * SIZE(BO)
	movaps	%xmm6,  24 * SIZE(BO)
	movaps	%xmm7,  28 * SIZE(BO)

	addq	$  8 * SIZE, B
	subq	$-32 * SIZE, BO
	subq	$1, %rax
	jne	.L102
	ALIGN_4

.L103:
	movq	K, %rax
	andq	$15, %rax
	BRANCH
	jle	.L105
	ALIGN_4

.L104:
	movss	 -32 * SIZE(B), %xmm8

	shufps	$0, %xmm8,  %xmm8

	movaps	%xmm8,  0 * SIZE(BO)

	addq	$1 * SIZE, B
	addq	$4 * SIZE, BO
	subq	$1, %rax
	jne	.L104
	ALIGN_4
	
.L105:
	movq	C, CO1
	movq	A, AO

	movq	M,  I
	sarq	$3, I
	jle	.L120
	ALIGN_4

.L110:
#if !defined(TRMMKERNEL) || \
	(defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
	(defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))

	leaq	32 * SIZE + BUFFER, BO
#else
	leaq	32 * SIZE + BUFFER, BO
	movq	KK, %rax
	leaq	(, %rax,   8), %rax
	leaq	(AO, %rax, 4), AO
	leaq	(BO, %rax, 2), BO
#endif	

	pxor	%xmm8, %xmm8
	pxor	%xmm9, %xmm9

	prefetcht0     7 * SIZE(CO1)
	pxor	%xmm12, %xmm12
	pxor	%xmm13, %xmm13

#ifndef TRMMKERNEL
	movq	K, %rax
#elif (defined(LEFT) && !defined(TRANSA)) || (!defined(LEFT) && defined(TRANSA))
	movq	K, %rax
	subq	KK, %rax
	movq	%rax, KKK	
#else
	movq	KK, %rax
#ifdef LEFT
	addq	$8, %rax
#else
	addq	$1, %rax
#endif
	movq	%rax, KKK
#endif
	sarq	$2, %rax
	jle	.L115
	ALIGN_4

.L111:	
	PREFETCH (PREFETCHSIZE +  0) * SIZE(AO)

	movaps	-32 * SIZE(AO), %xmm0
	movaps	-28 * SIZE(AO), %xmm1
	movaps	-32 * SIZE(BO), %xmm2
	movaps	 %xmm2, %xmm3

	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3
	addps	%xmm2, %xmm8
	addps	%xmm3, %xmm12

	movaps	-24 * SIZE(AO), %xmm0
	movaps	-20 * SIZE(AO), %xmm1
	movaps	-28 * SIZE(BO), %xmm2
	movaps	 %xmm2, %xmm3

	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3
	addps	%xmm2, %xmm9
	addps	%xmm3, %xmm13

	movaps	-16 * SIZE(AO), %xmm0
	movaps	-12 * SIZE(AO), %xmm1
	movaps	-24 * SIZE(BO), %xmm2
	movaps	 %xmm2, %xmm3

	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3
	addps	%xmm2, %xmm8
	addps	%xmm3, %xmm12

	movaps	 -8 * SIZE(AO), %xmm0
	movaps	 -4 * SIZE(AO), %xmm1
	movaps	-20 * SIZE(BO), %xmm2
	movaps	 %xmm2, %xmm3

	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3
	addps	%xmm2, %xmm9
	addps	%xmm3, %xmm13

	subq	$-32 * SIZE, AO
	subq	$-16 * SIZE, BO
	subq	$1, %rax
	jg	.L111
	ALIGN_4

.L115:
	movaps	ALPHA, %xmm7

#ifndef TRMMKERNEL
	movq	K, %rax
#else
	movq	KKK, %rax
#endif
	andq	$3, %rax		# if (k & 1)
	je .L118
	ALIGN_4

.L116:
	movaps	-32 * SIZE(AO), %xmm0
	movaps	-28 * SIZE(AO), %xmm1

	movaps	-32 * SIZE(BO), %xmm2
	movaps	 %xmm2, %xmm3

	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3
	addps	%xmm2, %xmm8
	addps	%xmm3, %xmm12

	addq	$8 * SIZE, AO
	addq	$4 * SIZE, BO
	subq	$1, %rax
	jg	.L116
	ALIGN_4

.L118:
	addps	%xmm9, %xmm8
	addps	%xmm13, %xmm12

#ifndef TRMMKERNEL
	movsd	0 * SIZE(CO1), %xmm0
	movhps	2 * SIZE(CO1), %xmm0
	movsd	4 * SIZE(CO1), %xmm1
	movhps	6 * SIZE(CO1), %xmm1
#endif

	mulps	%xmm7, %xmm8
	mulps	%xmm7, %xmm12

#ifndef TRMMKERNEL
	addps	%xmm0,  %xmm8
	addps	%xmm1,  %xmm12
#endif

	movlps	%xmm8, 0 * SIZE(CO1)
	movhps	%xmm8, 2 * SIZE(CO1)
	movlps	%xmm12, 4 * SIZE(CO1)
	movhps	%xmm12, 6 * SIZE(CO1)

#if (defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
    (defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))
	movq	K, %rax
	subq	KKK, %rax
	leaq	(,%rax,    8), %rax
	leaq	(AO, %rax, 4), AO
	leaq	(BO, %rax, 2), BO
#endif

#if defined(TRMMKERNEL) && defined(LEFT)
	addq	$8, KK
#endif

	addq	$8 * SIZE, CO1
	subq	$1, I
	jg	.L110
	ALIGN_4	

.L120:
	testq	$4, M
	jle	.L130

#if !defined(TRMMKERNEL) || \
	(defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
	(defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))

	leaq	32 * SIZE + BUFFER, BO
#else
	leaq	32 * SIZE + BUFFER, BO
	movq	KK, %rax
	leaq	(, %rax,   8), %rax
	leaq	(AO, %rax, 2), AO
	leaq	(BO, %rax, 2), BO
#endif	

	pxor	%xmm8, %xmm8
	pxor	%xmm9, %xmm9
	pxor	%xmm10, %xmm10
	pxor	%xmm11, %xmm11

#ifndef TRMMKERNEL
	movq	K, %rax
#elif (defined(LEFT) && !defined(TRANSA)) || (!defined(LEFT) && defined(TRANSA))
	movq	K, %rax
	subq	KK, %rax
	movq	%rax, KKK	
#else
	movq	KK, %rax
#ifdef LEFT
	addq	$4, %rax
#else
	addq	$1, %rax
#endif
	movq	%rax, KKK
#endif
	sarq	$2, %rax
	jle	.L125
	ALIGN_4

.L121:	
	PREFETCH (PREFETCHSIZE +  0) * SIZE(AO)

	movaps	-32 * SIZE(AO), %xmm0
	movaps	-28 * SIZE(AO), %xmm1
	movaps	-32 * SIZE(BO), %xmm2
	movaps	-28 * SIZE(BO), %xmm3

	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3

	addps	%xmm2, %xmm8
	addps	%xmm3, %xmm9

	movaps	-24 * SIZE(AO), %xmm0
	movaps	-20 * SIZE(AO), %xmm1
	movaps	-24 * SIZE(BO), %xmm2
	movaps	-20 * SIZE(BO), %xmm3

	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3

	addps	%xmm2, %xmm10
	addps	%xmm3, %xmm11

	subq	$-16 * SIZE, AO
	subq	$-16 * SIZE, BO
	subq	$1, %rax
	jg	.L121
	ALIGN_4

.L125:
	movaps	ALPHA, %xmm7

#ifndef TRMMKERNEL
	movq	K, %rax
#else
	movq	KKK, %rax
#endif
	andq	$3, %rax		# if (k & 1)
	je .L128
	ALIGN_4

.L126:
	movaps	-32 * SIZE(AO), %xmm0
	movaps	-32 * SIZE(BO), %xmm2

	mulps	%xmm0, %xmm2
	addps	%xmm2, %xmm8

	addq	$4 * SIZE, AO
	addq	$4 * SIZE, BO
	subq	$1, %rax
	jg	.L126
	ALIGN_4

.L128:
	addps	%xmm10, %xmm8
	addps	%xmm11, %xmm9

	addps	%xmm9, %xmm8

#ifndef TRMMKERNEL
	movsd	0 * SIZE(CO1), %xmm0
	movhps	2 * SIZE(CO1), %xmm0
#endif

	mulps	%xmm7, %xmm8
#ifndef TRMMKERNEL
	addps	%xmm0,  %xmm8
#endif

	movlps	%xmm8, 0 * SIZE(CO1)
	movhps	%xmm8, 2 * SIZE(CO1)

#if (defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
    (defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))
	movq	K, %rax
	subq	KKK, %rax
	leaq	(,%rax,    8), %rax
	leaq	(AO, %rax, 2), AO
	leaq	(BO, %rax, 2), BO
#endif

#if defined(TRMMKERNEL) && defined(LEFT)
	addq	$4, KK
#endif

	addq	$4 * SIZE, CO1
	addq	$4 * SIZE, CO2
	ALIGN_4
	
.L130:
	testq	$2, M
	jle	.L140

#if !defined(TRMMKERNEL) || \
	(defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
	(defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))

	leaq	32 * SIZE + BUFFER, BO
#else
	leaq	32 * SIZE + BUFFER, BO
	movq	KK, %rax
	leaq	(, %rax,   8), %rax
	leaq	(AO, %rax, 1), AO
	leaq	(BO, %rax, 2), BO
#endif	

	pxor	%xmm8, %xmm8
	pxor	%xmm9, %xmm9
	pxor	%xmm10, %xmm10
	pxor	%xmm11, %xmm11

#ifndef TRMMKERNEL
	movq	K, %rax
#elif (defined(LEFT) && !defined(TRANSA)) || (!defined(LEFT) && defined(TRANSA))
	movq	K, %rax
	subq	KK, %rax
	movq	%rax, KKK	
#else
	movq	KK, %rax
#ifdef LEFT
	addq	$2, %rax
#else
	addq	$1, %rax
#endif
	movq	%rax, KKK
#endif
	sarq	$2, %rax
	jle	.L135
	ALIGN_4

.L131:	
	PREFETCH (PREFETCHSIZE +  0) * SIZE(AO)

	movsd	-32 * SIZE(AO), %xmm0
	movsd	-30 * SIZE(AO), %xmm1
	movsd	-32 * SIZE(BO), %xmm2
	movsd	-28 * SIZE(BO), %xmm3

	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3
	addps	%xmm2, %xmm8
	addps	%xmm3, %xmm9

	movsd	-28 * SIZE(AO), %xmm0
	movsd	-26 * SIZE(AO), %xmm1
	movsd	-24 * SIZE(BO), %xmm2
	movsd	-20 * SIZE(BO), %xmm3

	mulps	%xmm0, %xmm2
	mulps	%xmm1, %xmm3
	addps	%xmm2, %xmm10
	addps	%xmm3, %xmm11

	subq	$ -8 * SIZE, AO
	subq	$-16 * SIZE, BO
	subq	$1, %rax
	jg	.L131
	ALIGN_4

.L135:
	movsd	ALPHA, %xmm7

#ifndef TRMMKERNEL
	movq	K, %rax
#else
	movq	KKK, %rax
#endif
	andq	$3, %rax		# if (k & 1)
	je .L138
	ALIGN_4

.L136:
	movsd	-32 * SIZE(AO), %xmm0
	movsd	-32 * SIZE(BO), %xmm2

	mulps	%xmm0, %xmm2
	addps	%xmm2, %xmm8

	addq	$2 * SIZE, AO
	addq	$4 * SIZE, BO
	subq	$1, %rax
	jg	.L136
	ALIGN_4

.L138:
#ifndef TRMMKERNEL
	movsd	0 * SIZE(CO1), %xmm0
#endif

	addps	%xmm10, %xmm8
	addps	%xmm11, %xmm9

	addps	%xmm9, %xmm8

	mulps	%xmm7, %xmm8

#ifndef TRMMKERNEL
	addps	%xmm0,  %xmm8
#endif
	movlps	%xmm8, 0 * SIZE(CO1)

#if (defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
    (defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))
	movq	K, %rax
	subq	KKK, %rax
	leaq	(,%rax,    8), %rax
	leaq	(AO, %rax, 1), AO
	leaq	(BO, %rax, 2), BO
#endif

#if defined(TRMMKERNEL) && defined(LEFT)
	addq	$2, KK
#endif
	addq	$2 * SIZE, CO1
	ALIGN_4

.L140:
	testq	$1, M
	jle	.L999

#if !defined(TRMMKERNEL) || \
	(defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
	(defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))

	leaq	32 * SIZE + BUFFER, BO
#else
	leaq	32 * SIZE + BUFFER, BO
	movq	KK, %rax
	leaq	(, %rax,   4), %rax
	leaq	(AO, %rax, 1), AO
	leaq	(BO, %rax, 4), BO
#endif	

	pxor	%xmm8, %xmm8
	pxor	%xmm9, %xmm9
	pxor	%xmm10, %xmm10
	pxor	%xmm11, %xmm11

#ifndef TRMMKERNEL
	movq	K, %rax
#elif (defined(LEFT) && !defined(TRANSA)) || (!defined(LEFT) && defined(TRANSA))
	movq	K, %rax
	subq	KK, %rax
	movq	%rax, KKK	
#else
	movq	KK, %rax
#ifdef LEFT
	addq	$1, %rax
#else
	addq	$1, %rax
#endif
	movq	%rax, KKK
#endif
	sarq	$2, %rax
	jle	.L145
	ALIGN_4

.L141:	
	PREFETCH (PREFETCHSIZE +  0) * SIZE(AO)

	movss	-32 * SIZE(AO), %xmm0
	movss	-31 * SIZE(AO), %xmm1
	movss	-32 * SIZE(BO), %xmm2
	movss	-28 * SIZE(BO), %xmm3

	mulss	%xmm0, %xmm2
	mulss	%xmm1, %xmm3
	addss	%xmm2, %xmm8
	addss	%xmm3, %xmm9

	movss	-30 * SIZE(AO), %xmm0
	movss	-29 * SIZE(AO), %xmm1
	movss	-24 * SIZE(BO), %xmm2
	movss	-20 * SIZE(BO), %xmm3

	mulss	%xmm0, %xmm2
	mulss	%xmm1, %xmm3
	addss	%xmm2, %xmm10
	addss	%xmm3, %xmm11

	subq	$ -4 * SIZE, AO
	subq	$-16 * SIZE, BO
	subq	$1, %rax
	jg	.L141
	ALIGN_4

.L145:
	movss	ALPHA, %xmm7

#ifndef TRMMKERNEL
	movq	K, %rax
#else
	movq	KKK, %rax
#endif
	andq	$3, %rax		# if (k & 1)
	je .L148
	ALIGN_4

.L146:
	movss	-32 * SIZE(AO), %xmm0
	movss	-32 * SIZE(BO), %xmm2

	mulss	%xmm0, %xmm2
	addss	%xmm2, %xmm8

	addq	$1 * SIZE, AO
	addq	$4 * SIZE, BO
	subq	$1, %rax
	jg	.L146
	ALIGN_4

.L148:
#ifndef TRMMKERNEL
	movss	0 * SIZE(CO1), %xmm0
#endif

	addss	%xmm10, %xmm8
	addss	%xmm11, %xmm9
	addss	%xmm9, %xmm8
	mulss	%xmm7, %xmm8

#ifndef TRMMKERNEL
	addss	%xmm0,  %xmm8
#endif

	movss	%xmm8, 0 * SIZE(CO1)
	ALIGN_4

.L999:
	movq	%r15, %rsp

	movq	  0(%rsp), %rbx
	movq	  8(%rsp), %rbp
	movq	 16(%rsp), %r12
	movq	 24(%rsp), %r13
	movq	 32(%rsp), %r14
	movq	 40(%rsp), %r15

#ifdef WINDOWS_ABI
	movq	 48(%rsp), %rdi
	movq	 56(%rsp), %rsi
	movups	 64(%rsp), %xmm6
	movups	 80(%rsp), %xmm7
	movups	 96(%rsp), %xmm8
	movups	112(%rsp), %xmm9
	movups	128(%rsp), %xmm10
	movups	144(%rsp), %xmm11
	movups	160(%rsp), %xmm12
	movups	176(%rsp), %xmm13
	movups	192(%rsp), %xmm14
	movups	208(%rsp), %xmm15
#endif

	addq	$STACKSIZE, %rsp
	ret

	EPILOGUE