gemm_kernel_4x4_core2.s

Optimized GotoBLAS libraries

#ifndef TRMMKERNEL
	movsd	0 * SIZE(CO1), %xmm0
	movhpd	1 * SIZE(CO1), %xmm0
	movsd	0 * SIZE(CO2), %xmm2
	movhpd	1 * SIZE(CO2), %xmm2
#endif

	addpd	%xmm10, %xmm8
	addpd	%xmm11, %xmm9

	mulpd	%xmm7, %xmm8
	mulpd	%xmm7, %xmm9

#ifndef TRMMKERNEL
	addpd	%xmm0,  %xmm8
	addpd	%xmm2, %xmm9
#endif

	movsd	%xmm8, 0 * SIZE(CO1)
	movhpd	%xmm8, 1 * SIZE(CO1)
	movsd	%xmm9, 0 * SIZE(CO2)
	movhpd	%xmm9, 1 * SIZE(CO2)

#if (defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
    (defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))
	movq	K, %rax
	subq	KKK, %rax
	leaq	(,%rax, SIZE), %rax
	leaq	(AO, %rax, 2), AO
	leaq	(BO, %rax, 4), BO
#endif

#if defined(TRMMKERNEL) && defined(LEFT)
	addq	$2, KK
#endif

	addq	$2 * SIZE, CO1
	addq	$2 * SIZE, CO2
	ALIGN_4
	
.L70:
	testq	$1, M
	jle	.L79

#if !defined(TRMMKERNEL) || \
	(defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
	(defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))

	leaq	16 * SIZE + BUFFER, BO
#else
	leaq	16 * SIZE + BUFFER, BO
	movq	KK, %rax
	leaq	(, %rax, SIZE), %rax
	leaq	(AO, %rax, 1), AO
	leaq	(BO, %rax, 4), BO
#endif	

	movsd	-16 * SIZE(AO), %xmm0
	movsd	-15 * SIZE(AO), %xmm1
	pxor	%xmm8, %xmm8
	pxor	%xmm9, %xmm9
	pxor	%xmm10, %xmm10
	pxor	%xmm11, %xmm11

	movapd	%xmm8, %xmm2
	movapd	%xmm8, %xmm3
	movapd	%xmm8, %xmm4
	movapd	%xmm8, %xmm5

#ifndef TRMMKERNEL
	movq	K, %rax
#elif (defined(LEFT) && !defined(TRANSA)) || (!defined(LEFT) && defined(TRANSA))
	movq	K, %rax
	subq	KK, %rax
	movq	%rax, KKK	
#else
	movq	KK, %rax
#ifdef LEFT
	addq	$1, %rax
#else
	addq	$2, %rax
#endif
	movq	%rax, KKK
#endif
	sarq	$2, %rax
	jle	.L75
	ALIGN_4

.L71:	
	PREFETCH (PREFETCHSIZE +  0) * SIZE(AO)

	addsd	%xmm2, %xmm8
	movsd	-16 * SIZE(BO), %xmm2
	mulsd	%xmm0, %xmm2
	addsd	%xmm3, %xmm9
	movsd	-14 * SIZE(BO), %xmm3
	mulsd	%xmm0, %xmm3
	movsd	-14 * SIZE(AO), %xmm0
	addsd	%xmm4, %xmm10
	movsd	-12 * SIZE(BO), %xmm4
	mulsd	%xmm1, %xmm4
	addsd	%xmm5, %xmm11
	movsd	-10 * SIZE(BO), %xmm5
	mulsd	%xmm1, %xmm5
	movsd	-13 * SIZE(AO), %xmm1

	addsd	%xmm2, %xmm8
	movsd	 -8 * SIZE(BO), %xmm2
	mulsd	%xmm0, %xmm2
	addsd	%xmm3, %xmm9
	movsd	 -6 * SIZE(BO), %xmm3
	mulsd	%xmm0, %xmm3
	movsd	-12 * SIZE(AO), %xmm0
	addsd	%xmm4, %xmm10
	movsd	 -4 * SIZE(BO), %xmm4
	mulsd	%xmm1, %xmm4
	addsd	%xmm5, %xmm11
	movsd	 -2 * SIZE(BO), %xmm5
	mulsd	%xmm1, %xmm5
	movsd	-11 * SIZE(AO), %xmm1

	subq	$ -4 * SIZE, AO
	subq	$-16 * SIZE, BO
	subq	$1, %rax
	jg	.L71
	ALIGN_4

.L75:
	movsd	ALPHA, %xmm7

#ifndef TRMMKERNEL
	movq	K, %rax
#else
	movq	KKK, %rax
#endif
	andq	$3, %rax		# if (k & 1)
	je .L78
	ALIGN_4

.L76:
	addsd	%xmm2, %xmm8
	movsd	-16 * SIZE(BO), %xmm2
	mulsd	%xmm0, %xmm2
	addsd	%xmm3, %xmm9
	movsd	-14 * SIZE(BO), %xmm3
	mulsd	%xmm0, %xmm3
	movsd	-15 * SIZE(AO), %xmm0

	addq	$1 * SIZE, AO
	addq	$4 * SIZE, BO
	subq	$1, %rax
	jg	.L76
	ALIGN_4

.L78:
	addsd	%xmm2, %xmm8
	addsd	%xmm3, %xmm9
	addsd	%xmm4, %xmm10
	addsd	%xmm5, %xmm11

#ifndef TRMMKERNEL
	movsd	0 * SIZE(CO1), %xmm0
	movsd	0 * SIZE(CO2), %xmm2
#endif

	addsd	%xmm10, %xmm8
	addsd	%xmm11, %xmm9

	mulsd	%xmm7, %xmm8
	mulsd	%xmm7, %xmm9

#ifndef TRMMKERNEL
	addsd	%xmm0,  %xmm8
	addsd	%xmm2, %xmm9
#endif

#if (defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
    (defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))
	movq	K, %rax
	subq	KKK, %rax
	leaq	(,%rax, SIZE), %rax
	leaq	(AO, %rax, 1), AO
	leaq	(BO, %rax, 4), BO
#endif

#if defined(TRMMKERNEL) && defined(LEFT)
	addq	$1, KK
#endif

	movsd	%xmm8, 0 * SIZE(CO1)
	movsd	%xmm9, 0 * SIZE(CO2)
	ALIGN_4

.L79:
#if defined(TRMMKERNEL) && !defined(LEFT)
	addq	$2, KK
#endif

	leaq	(C, LDC, 2), C
	ALIGN_4

.L80:
	testq	$1, N
	jle,pt	.L999
	ALIGN_4

.L81:
/* Copying to Sub Buffer */
	leaq	BUFFER, BO
	
#if defined(TRMMKERNEL) && defined(LEFT)
	movq	OFFSET, %rax
	movq	%rax, KK
#endif	

	movq	K, %rax
	sarq	$4, %rax
	jle	.L83

	addq	%rax, %rax
	ALIGN_4
	
.L82:
	movddup	 -16 * SIZE(B), %xmm8
	movddup	 -15 * SIZE(B), %xmm9
	movddup	 -14 * SIZE(B), %xmm10
	movddup	 -13 * SIZE(B), %xmm11
	movddup	 -12 * SIZE(B), %xmm12
	movddup	 -11 * SIZE(B), %xmm13
	movddup	 -10 * SIZE(B), %xmm14
	movddup	  -9 * SIZE(B), %xmm15

	movapd	%xmm8,  0 * SIZE(BO)
	movapd	%xmm9,  2 * SIZE(BO)
	movapd	%xmm10,  4 * SIZE(BO)
	movapd	%xmm11,  6 * SIZE(BO)
	movapd	%xmm12,  8 * SIZE(BO)
	movapd	%xmm13, 10 * SIZE(BO)
	movapd	%xmm14, 12 * SIZE(BO)
	movapd	%xmm15, 14 * SIZE(BO)

	addq	$  8 * SIZE, B
	subq	$-16 * SIZE, BO
	subq	$1, %rax
	jne	.L82
	ALIGN_4

.L83:
	movq	K, %rax
	andq	$15, %rax
	BRANCH
	jle	.L85
	ALIGN_4

.L84:
	movddup	 -16 * SIZE(B), %xmm8

	movapd	%xmm8,  0 * SIZE(BO)

	addq	$1 * SIZE, B
	addq	$2 * SIZE, BO
	subq	$1, %rax
	jne	.L84
	ALIGN_4
	
.L85:
	movq	C, CO1
	movq	A, AO

	movq	M,  I
	sarq	$2, I
	jle	.L100
	ALIGN_4

.L90:
#if !defined(TRMMKERNEL) || \
	(defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
	(defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))

	leaq	16 * SIZE + BUFFER, BO
#else
	leaq	16 * SIZE + BUFFER, BO
	movq	KK, %rax
	leaq	(, %rax, SIZE), %rax
	leaq	(AO, %rax, 4), AO
	leaq	(BO, %rax, 2), BO
#endif	

	pxor	%xmm8, %xmm8
	movapd	-16 * SIZE(BO), %xmm4
	pxor	%xmm9, %xmm9
	movapd	-14 * SIZE(BO), %xmm5
	pxor	%xmm12, %xmm12
	movapd	-12 * SIZE(BO), %xmm6
	pxor	%xmm13, %xmm13
	movapd	-10 * SIZE(BO), %xmm7

	movapd	%xmm8, %xmm0
	prefetcht0     3 * SIZE(CO1)
	movapd	%xmm8, %xmm1
	movapd	%xmm8, %xmm2
	movapd	%xmm8, %xmm3

#ifndef TRMMKERNEL
	movq	K, %rax
#elif (defined(LEFT) && !defined(TRANSA)) || (!defined(LEFT) && defined(TRANSA))
	movq	K, %rax
	subq	KK, %rax
	movq	%rax, KKK	
#else
	movq	KK, %rax
#ifdef LEFT
	addq	$4, %rax
#else
	addq	$1, %rax
#endif
	movq	%rax, KKK
#endif
	sarq	$2, %rax
	jle	.L95
	ALIGN_4

.L91:	
	PREFETCH (PREFETCHSIZE +  0) * SIZE(AO)

	addpd	%xmm0, %xmm8
	movapd	-16 * SIZE(AO), %xmm0
	mulpd	%xmm4, %xmm0
	addpd	%xmm1, %xmm12
	movapd	-14 * SIZE(AO), %xmm1
	mulpd	%xmm4, %xmm1
	movapd	 -8 * SIZE(BO), %xmm4
	addpd	%xmm2, %xmm9
	movapd	-12 * SIZE(AO), %xmm2
	mulpd	%xmm5, %xmm2
	addpd	%xmm3, %xmm13
	movapd	-10 * SIZE(AO), %xmm3
	mulpd	%xmm5, %xmm3
	movapd	 -6 * SIZE(BO), %xmm5

	PREFETCH (PREFETCHSIZE +  8) * SIZE(AO)
	addpd	%xmm0, %xmm8
	movapd	 -8 * SIZE(AO), %xmm0
	mulpd	%xmm6, %xmm0
	addpd	%xmm1, %xmm12
	movapd	 -6 * SIZE(AO), %xmm1
	mulpd	%xmm6, %xmm1
	movapd	 -4 * SIZE(BO), %xmm6
	addpd	%xmm2, %xmm9
	movapd	 -4 * SIZE(AO), %xmm2
	mulpd	%xmm7, %xmm2
	addpd	%xmm3, %xmm13
	movapd	 -2 * SIZE(AO), %xmm3
	mulpd	%xmm7, %xmm3
	movapd	 -2 * SIZE(BO), %xmm7

	subq	$-16 * SIZE, AO
	subq	$ -8 * SIZE, BO
	subq	$1, %rax
	jg	.L91
	ALIGN_4

.L95:
	movapd	ALPHA, %xmm7

#ifndef TRMMKERNEL
	movq	K, %rax
#else
	movq	KKK, %rax
#endif
	andq	$3, %rax		# if (k & 1)
	je .L98
	ALIGN_4

.L96:
	addpd	%xmm0, %xmm8
	movapd	-16 * SIZE(AO), %xmm0
	mulpd	%xmm4, %xmm0
	addpd	%xmm1, %xmm12
	movapd	-14 * SIZE(AO), %xmm1
	mulpd	%xmm4, %xmm1
	movapd	-14 * SIZE(BO), %xmm4

	addq	$4 * SIZE, AO
	addq	$2 * SIZE, BO
	subq	$1, %rax
	jg	.L96
	ALIGN_4

.L98:
	addpd	%xmm0, %xmm8
	addpd	%xmm1, %xmm12
	addpd	%xmm2, %xmm9
	addpd	%xmm3, %xmm13

	addpd	%xmm9, %xmm8
	addpd	%xmm13, %xmm12

#ifndef TRMMKERNEL
	movsd	0 * SIZE(CO1), %xmm0
	movhpd	1 * SIZE(CO1), %xmm0
	movsd	2 * SIZE(CO1), %xmm1
	movhpd	3 * SIZE(CO1), %xmm1
#endif

	mulpd	%xmm7, %xmm8
	mulpd	%xmm7, %xmm12

#ifndef TRMMKERNEL
	addpd	%xmm0,  %xmm8
	addpd	%xmm1,  %xmm12
#endif

	movsd	%xmm8, 0 * SIZE(CO1)
	movhpd	%xmm8, 1 * SIZE(CO1)
	movsd	%xmm12, 2 * SIZE(CO1)
	movhpd	%xmm12, 3 * SIZE(CO1)

#if (defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
    (defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))
	movq	K, %rax
	subq	KKK, %rax
	leaq	(,%rax, SIZE), %rax
	leaq	(AO, %rax, 4), AO
	leaq	(BO, %rax, 2), BO
#endif

#if defined(TRMMKERNEL) && defined(LEFT)
	addq	$4, KK
#endif

	addq	$4 * SIZE, CO1
	subq	$1, I
	jg	.L90
	ALIGN_4	

.L100:
	testq	$2, M
	jle	.L110

#if !defined(TRMMKERNEL) || \
	(defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
	(defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))

	leaq	16 * SIZE + BUFFER, BO
#else
	leaq	16 * SIZE + BUFFER, BO
	movq	KK, %rax
	leaq	(, %rax, SIZE), %rax
	leaq	(AO, %rax, 2), AO
	leaq	(BO, %rax, 2), BO
#endif	

	pxor	%xmm8, %xmm8
	movapd	-16 * SIZE(BO), %xmm4
	pxor	%xmm9, %xmm9
	movapd	-14 * SIZE(BO), %xmm5
	pxor	%xmm10, %xmm10
	movapd	-12 * SIZE(BO), %xmm6
	pxor	%xmm11, %xmm11
	movapd	-10 * SIZE(BO), %xmm7

	movapd	%xmm8, %xmm0
	movapd	%xmm8, %xmm1
	movapd	%xmm8, %xmm2
	movapd	%xmm8, %xmm3

#ifndef TRMMKERNEL
	movq	K, %rax
#elif (defined(LEFT) && !defined(TRANSA)) || (!defined(LEFT) && defined(TRANSA))
	movq	K, %rax
	subq	KK, %rax
	movq	%rax, KKK	
#else
	movq	KK, %rax
#ifdef LEFT
	addq	$2, %rax
#else
	addq	$1, %rax
#endif
	movq	%rax, KKK
#endif
	sarq	$2, %rax
	jle	.L105
	ALIGN_4

.L101:	
	PREFETCH (PREFETCHSIZE +  0) * SIZE(AO)

	addpd	%xmm0, %xmm8
	movapd	-16 * SIZE(AO), %xmm0
	mulpd	%xmm4, %xmm0
	movapd	 -8 * SIZE(BO), %xmm4
	addpd	%xmm1, %xmm9
	movapd	-14 * SIZE(AO), %xmm1
	mulpd	%xmm5, %xmm1
	movapd	 -6 * SIZE(BO), %xmm5
	addpd	%xmm2, %xmm10
	movapd	-12 * SIZE(AO), %xmm2
	mulpd	%xmm6, %xmm2
	movapd	 -4 * SIZE(BO), %xmm6
	addpd	%xmm3, %xmm11
	movapd	-10 * SIZE(AO), %xmm3
	mulpd	%xmm7, %xmm3
	movapd	 -2 * SIZE(BO), %xmm7

	subq	$-8 * SIZE, AO
	subq	$-8 * SIZE, BO
	subq	$1, %rax
	jg	.L101
	ALIGN_4

.L105:
	movapd	ALPHA, %xmm7

#ifndef TRMMKERNEL
	movq	K, %rax
#else
	movq	KKK, %rax
#endif
	andq	$3, %rax		# if (k & 1)
	je .L108
	ALIGN_4

.L106:
	addpd	%xmm0, %xmm8
	movapd	-16 * SIZE(AO), %xmm0
	mulpd	%xmm4, %xmm0
	movapd	-14 * SIZE(BO), %xmm4

	addq	$2 * SIZE, AO
	addq	$2 * SIZE, BO
	subq	$1, %rax
	jg	.L106
	ALIGN_4

.L108:
	addpd	%xmm0, %xmm8
	addpd	%xmm1, %xmm9
	addpd	%xmm2, %xmm10
	addpd	%xmm3, %xmm11

	addpd	%xmm10, %xmm8
	addpd	%xmm11, %xmm9

	addpd	%xmm9, %xmm8

#ifndef TRMMKERNEL
	movsd	0 * SIZE(CO1), %xmm0
	movhpd	1 * SIZE(CO1), %xmm0
#endif

	mulpd	%xmm7, %xmm8
#ifndef TRMMKERNEL
	addpd	%xmm0,  %xmm8
#endif

	movsd	%xmm8, 0 * SIZE(CO1)
	movhpd	%xmm8, 1 * SIZE(CO1)

#if (defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
    (defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))
	movq	K, %rax
	subq	KKK, %rax
	leaq	(,%rax, SIZE), %rax
	leaq	(AO, %rax, 2), AO
	leaq	(BO, %rax, 2), BO
#endif

#if defined(TRMMKERNEL) && defined(LEFT)
	addq	$2, KK
#endif
	addq	$2 * SIZE, CO1
	addq	$2 * SIZE, CO2
	ALIGN_4
	
.L110:
	testq	$1, M
	jle	.L999

#if !defined(TRMMKERNEL) || \
	(defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
	(defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))

	leaq	16 * SIZE + BUFFER, BO
#else
	leaq	16 * SIZE + BUFFER, BO
	movq	KK, %rax
	leaq	(, %rax, SIZE), %rax
	leaq	(AO, %rax, 1), AO
	leaq	(BO, %rax, 2), BO
#endif	

	pxor	%xmm8, %xmm8
	movsd	-16 * SIZE(BO), %xmm4
	pxor	%xmm9, %xmm9
	movsd	-14 * SIZE(BO), %xmm5
	pxor	%xmm10, %xmm10
	movsd	-12 * SIZE(BO), %xmm6
	pxor	%xmm11, %xmm11
	movsd	-10 * SIZE(BO), %xmm7

	movapd	%xmm8, %xmm0
	movapd	%xmm8, %xmm1
	movapd	%xmm8, %xmm2
	movapd	%xmm8, %xmm3

#ifndef TRMMKERNEL
	movq	K, %rax
#elif (defined(LEFT) && !defined(TRANSA)) || (!defined(LEFT) && defined(TRANSA))
	movq	K, %rax
	subq	KK, %rax
	movq	%rax, KKK	
#else
	movq	KK, %rax
#ifdef LEFT
	addq	$1, %rax
#else
	addq	$1, %rax
#endif
	movq	%rax, KKK
#endif
	sarq	$2, %rax
	jle	.L115
	ALIGN_4

.L111:	
	PREFETCH (PREFETCHSIZE +  0) * SIZE(AO)

	addpd	%xmm0, %xmm8
	movsd	-16 * SIZE(AO), %xmm0
	mulpd	%xmm4, %xmm0
	movsd	 -8 * SIZE(BO), %xmm4
	addpd	%xmm1, %xmm9
	movsd	-15 * SIZE(AO), %xmm1
	mulpd	%xmm5, %xmm1
	movsd	 -6 * SIZE(BO), %xmm5
	addpd	%xmm2, %xmm10
	movsd	-14 * SIZE(AO), %xmm2
	mulpd	%xmm6, %xmm2
	movsd	 -4 * SIZE(BO), %xmm6
	addpd	%xmm3, %xmm11
	movsd	-13 * SIZE(AO), %xmm3
	mulpd	%xmm7, %xmm3
	movsd	 -2 * SIZE(BO), %xmm7

	subq	$-4 * SIZE, AO
	subq	$-8 * SIZE, BO
	subq	$1, %rax
	jg	.L111
	ALIGN_4

.L115:
	movsd	ALPHA, %xmm7

#ifndef TRMMKERNEL
	movq	K, %rax
#else
	movq	KKK, %rax
#endif
	andq	$3, %rax		# if (k & 1)
	je .L118
	ALIGN_4

.L116:
	addsd	%xmm0, %xmm8
	movsd	-16 * SIZE(AO), %xmm0
	mulsd	%xmm4, %xmm0
	movsd	-14 * SIZE(BO), %xmm4

	addq	$1 * SIZE, AO
	addq	$2 * SIZE, BO
	subq	$1, %rax
	jg	.L116
	ALIGN_4

.L118:
	addsd	%xmm0, %xmm8
	addsd	%xmm1, %xmm9
	addsd	%xmm2, %xmm10
	addsd	%xmm3, %xmm11

#ifndef TRMMKERNEL
	movsd	0 * SIZE(CO1), %xmm0
#endif
	addsd	%xmm10, %xmm8
	addsd	%xmm11, %xmm9

	addsd	%xmm9, %xmm8

	mulsd	%xmm7, %xmm8
#ifndef TRMMKERNEL
	addsd	%xmm0,  %xmm8
#endif
	movsd	%xmm8, 0 * SIZE(CO1)
	ALIGN_4

.L999:
	movq	%r15, %rsp

	movq	  0(%rsp), %rbx
	movq	  8(%rsp), %rbp
	movq	 16(%rsp), %r12
	movq	 24(%rsp), %r13
	movq	 32(%rsp), %r14
	movq	 40(%rsp), %r15

#ifdef WINDOWS_ABI
	movq	 48(%rsp), %rdi
	movq	 56(%rsp), %rsi
	movups	 64(%rsp), %xmm6
	movups	 80(%rsp), %xmm7
	movups	 96(%rsp), %xmm8
	movups	112(%rsp), %xmm9
	movups	128(%rsp), %xmm10
	movups	144(%rsp), %xmm11
	movups	160(%rsp), %xmm12
	movups	176(%rsp), %xmm13
	movups	192(%rsp), %xmm14
	movups	208(%rsp), %xmm15
#endif

	addq	$STACKSIZE, %rsp
	ret

	EPILOGUE