zgemm_kernel_4x1_core2.s

Optimized GotoBLAS libraries

/*********************************************************************/
/*                                                                   */
/*             Optimized BLAS libraries                              */
/*                     By Kazushige Goto <[e-mail]>     */
/*                                                                   */
/* Copyright (c) The University of Texas, 2005. All rights reserved. */
/* UNIVERSITY EXPRESSLY DISCLAIMS ANY AND ALL WARRANTIES CONCERNING  */
/* THIS SOFTWARE AND DOCUMENTATION, INCLUDING ANY WARRANTIES OF      */
/* MERCHANTABILITY, FITNESS FOR ANY PARTICULAR PURPOSE,              */
/* NON-INFRINGEMENT AND WARRANTIES OF PERFORMANCE, AND ANY WARRANTY  */
/* THAT MIGHT OTHERWISE ARISE FROM COURSE OF DEALING OR USAGE OF     */
/* TRADE. NO WARRANTY IS EITHER EXPRESS OR IMPLIED WITH RESPECT TO   */
/* THE USE OF THE SOFTWARE OR DOCUMENTATION.                         */
/* Under no circumstances shall University be liable for incidental, */
/* special, indirect, direct or consequential damages or loss of     */
/* profits, interruption of business, or related expenses which may  */
/* arise from use of Software or Documentation, including but not    */
/* limited to those resulting from defects in Software and/or        */
/* Documentation, or loss or inaccuracy of data of any kind.         */
/*********************************************************************/

#define ASSEMBLER
#include "common.h"

#if !defined(HAVE_SSE) || !defined(HAVE_MMX)
#error  You have to check your configuration.
#endif

#define STACK	16
#define ARGS	 0
	
#define STACK_M	 4 + STACK + ARGS(%esi)
#define STACK_N	 8 + STACK + ARGS(%esi)
#define STACK_K	12 + STACK + ARGS(%esi)
#define STACK_ALPHA_R	16 + STACK + ARGS(%esi)
#define STACK_ALPHA_I	20 + STACK + ARGS(%esi)
#define STACK_A	24 + STACK + ARGS(%esi)
#define STACK_B	28 + STACK + ARGS(%esi)
#define STACK_C	32 + STACK + ARGS(%esi)
#define STACK_LDC	36 + STACK + ARGS(%esi)
#define STACK_OFFT	40 + STACK + ARGS(%esi)

#define ALPHA_R	16(%esp)
#define ALPHA_I	32(%esp)
#define K	48(%esp)
#define N	52(%esp)
#define M	56(%esp)
#define A	60(%esp)
#define C	64(%esp)
#define J	68(%esp)
#define OLD_STACK 72(%esp)
#define TEMP    76(%esp)
#define OFFSET  80(%esp)
#define KK	84(%esp)
#define KKK	88(%esp)
#define BUFFER 128(%esp)

#define B	%edi
#define LDC	%ebp
#define C1	%esi

#define STACK_ALIGN	4096
#define STACK_OFFSET	1024

#define PREFETCH_R    (8 * 16 + 0)
#define PREFETCH_W    (PREFETCH_R * 2)

#define PREFETCHSIZE  (8 * 16 + 4)
#define PREFETCH     prefetcht0
#define LOCAL_BUFFER_SIZE  GEMM_Q * GEMM_UNROLL_N * COMPSIZE * 16

#define AA	%edx
#define BB	%ecx

#if defined(NN) || defined(NT) || defined(TN) || defined(TT) || \
    defined(RN) || defined(RT) || defined(CN) || defined(CT)
#define ADDSUB	addps
#else
#define ADDSUB	subps
#endif

	PROLOGUE

	pushl	%ebp
	pushl	%edi
	pushl	%esi
	pushl	%ebx

	PROFCODE

	movl	%esp, %esi	# save old stack

	subl	$128 + LOCAL_BUFFER_SIZE + STACK_OFFSET, %esp
	andl	$-STACK_ALIGN, %esp	# align stack
	addl	$STACK_OFFSET, %esp

#ifdef WINDOWS_ABI
#if LOCAL_BUFFER_SIZE > 12288
	movl	$0,  4096 * 3(%esp)
#endif
#if LOCAL_BUFFER_SIZE >  8192
	movl	$0,  4096 * 2(%esp)
#endif
#if LOCAL_BUFFER_SIZE >  4096
	movl	$0,  4096 * 1(%esp)
#endif
	movl	$0,  4096 * 0(%esp)
#endif

	movd	STACK_M, %mm0
	movl	STACK_N, %eax
	movd	STACK_K, %mm1
	movd	STACK_A, %mm2
	movl	STACK_B, B
	movd	STACK_C, %mm3
	movl	STACK_LDC, LDC
#ifdef TRMMKERNEL
	movd	STACK_OFFT, %mm4
#endif

	movd	%mm1, K
	movd	%mm0, M
	movl	%eax, N
	movd	%mm2, A
	movd	%mm3, C
	movl	%esi, OLD_STACK
#ifdef TRMMKERNEL
	movd	%mm4, OFFSET
	movd	%mm4, KK
#ifndef LEFT
	negl	KK
#endif	
#endif

	subl	$-32 * SIZE, A
	subl	$-32 * SIZE, B

	leal	(, LDC, SIZE * 2), LDC

	movss	STACK_ALPHA_R, %xmm0
	movss	STACK_ALPHA_I, %xmm1

	pcmpeqb	%xmm7, %xmm7
	pslld	$31, %xmm7	# Generate mask
	shufps	$0, %xmm0, %xmm0

	movaps	 %xmm0,  0 + ALPHA_R
	movss	 %xmm1,  4 + ALPHA_I
	movss	 %xmm1, 12 + ALPHA_I
	xorps	 %xmm7, %xmm1
	movss	 %xmm1,  0 + ALPHA_I
	movss	 %xmm1,  8 + ALPHA_I

	movl	%eax, J			# j = n
	testl	%eax, %eax
	jle	.L999

.L01:
 	leal	32 * SIZE + BUFFER, BB

#if defined(TRMMKERNEL) && defined(LEFT)
	movl	OFFSET, %eax
	movl	%eax, KK
#endif	

	movl	K, %eax
	sarl	$2, %eax
	jle	.L03

.L02:
	prefetcht0	(PREFETCH_R + 0) * SIZE(B)

	movss	-32 * SIZE(B), %xmm0
	movss	-31 * SIZE(B), %xmm1
	movss	-30 * SIZE(B), %xmm2
	movss	-29 * SIZE(B), %xmm3
	movss	-28 * SIZE(B), %xmm4
	movss	-27 * SIZE(B), %xmm5
	movss	-26 * SIZE(B), %xmm6
	movss	-25 * SIZE(B), %xmm7

	prefetcht0	(PREFETCH_W +  0) * SIZE(BB)
	shufps	$0, %xmm0, %xmm0
	shufps	$0, %xmm1, %xmm1
	shufps	$0, %xmm2, %xmm2
	shufps	$0, %xmm3, %xmm3
	shufps	$0, %xmm4, %xmm4
	shufps	$0, %xmm5, %xmm5
	shufps	$0, %xmm6, %xmm6
	shufps	$0, %xmm7, %xmm7

	prefetcht0	(PREFETCH_W + 16) * SIZE(BB)
	movaps	%xmm0,  -32 * SIZE(BB)
	movaps	%xmm1,  -28 * SIZE(BB)
	movaps	%xmm2,  -24 * SIZE(BB)
	movaps	%xmm3,  -20 * SIZE(BB)
	movaps	%xmm4,  -16 * SIZE(BB)
	movaps	%xmm5,  -12 * SIZE(BB)
	movaps	%xmm6,   -8 * SIZE(BB)
	movaps	%xmm7,   -4 * SIZE(BB)

	addl	$  8 * SIZE, B
	subl	$-32 * SIZE, BB
	decl	%eax
	jne	.L02

.L03:
	movl	K, %eax
	andl	$3, %eax
	BRANCH
	jle	.L05

.L04:
	movss	-32 * SIZE(B), %xmm0
	movss	-31 * SIZE(B), %xmm1

	shufps	$0, %xmm0, %xmm0
	shufps	$0, %xmm1, %xmm1

	movaps	%xmm0,  -32 * SIZE(BB)
	movaps	%xmm1,  -28 * SIZE(BB)
	addl	$2 * SIZE, B
	addl	$8 * SIZE, BB
	decl	%eax
	jne	.L04
	ALIGN_4

.L05:
	movl	C, C1		# coffset = c
	movl	A, AA		# aoffset = a
	movl	M,  %ebx
	sarl	$2, %ebx	# i = (m >> 2)
	jle	.L20
	ALIGN_4

.L10:
#if !defined(TRMMKERNEL) || \
	(defined(TRMMKERNEL) &&  defined(LEFT) &&  defined(TRANSA)) || \
	(defined(TRMMKERNEL) && !defined(LEFT) && !defined(TRANSA))

	leal	32 * SIZE + BUFFER, BB
#else
	leal	32 * SIZE + BUFFER, BB
	movl	KK, %eax
	leal	(, %eax,   8), %eax
	leal	(AA, %eax, 4), AA
	leal	(BB, %eax, 4), BB /* because it's doubled */
#endif	

	movaps	-32 * SIZE(AA), %xmm0
	pxor	%xmm4, %xmm4
	movaps	-32 * SIZE(BB), %xmm1
	pxor	%xmm5, %xmm5
	movapd	-16 * SIZE(AA), %xmm3
	pxor	%xmm6, %xmm6
	prefetcht0	7 * SIZE(C1)
	pxor	%xmm7, %xmm7

#ifndef TRMMKERNEL
	movl	K, %eax
#elif (defined(LEFT) && !defined(TRANSA)) || (!defined(LEFT) && defined(TRANSA))
	movl	K, %eax
	subl	KK, %eax
	movl	%eax, KKK	
#else
	movl	KK, %eax
#ifdef LEFT
	addl	$4, %eax
#else
	addl	$1, %eax
#endif
	movl	%eax, KKK
#endif
	sarl	$3, %eax
	je	.L15
	ALIGN_4

.L12:
	movaps	%xmm1,  %xmm2
	mulps	%xmm0,  %xmm1
	addps	%xmm1,  %xmm4
	movaps	-28 * SIZE(BB), %xmm1
	mulps	%xmm1,  %xmm0
	ADDSUB	%xmm0,  %xmm5
	movaps	-28 * SIZE(AA), %xmm0
	mulps	%xmm0,  %xmm2
	mulps	%xmm0,  %xmm1
	movaps	-24 * SIZE(AA), %xmm0
	addps	%xmm2,  %xmm6
	ADDSUB	%xmm1,  %xmm7

	movaps	-24 * SIZE(BB), %xmm1
	movaps	%xmm1,  %xmm2
	mulps	%xmm0,  %xmm1
	addps	%xmm1,  %xmm4
	movaps	-20 * SIZE(BB), %xmm1
	mulps	%xmm1,  %xmm0
	ADDSUB	%xmm0,  %xmm5
	movaps	-20 * SIZE(AA), %xmm0
	mulps	%xmm0,  %xmm2
	mulps	%xmm0,  %xmm1
	movaps	  0 * SIZE(AA), %xmm0
	addps	%xmm2,  %xmm6
	ADDSUB	%xmm1,  %xmm7

	movaps	-16 * SIZE(BB), %xmm1
	movaps	%xmm1,  %xmm2
	mulps	%xmm3,  %xmm1
	addps	%xmm1,  %xmm4
	movaps	-12 * SIZE(BB), %xmm1
	mulps	%xmm1,  %xmm3
	ADDSUB	%xmm3,  %xmm5
	movaps	-12 * SIZE(AA), %xmm3
	mulps	%xmm3,  %xmm2
	mulps	%xmm3,  %xmm1
	movaps	 -8 * SIZE(AA), %xmm3
	addps	%xmm2,  %xmm6
	ADDSUB	%xmm1,  %xmm7

	movaps	 -8 * SIZE(BB), %xmm1
	movaps	%xmm1,  %xmm2
	mulps	%xmm3,  %xmm1
	addps	%xmm1,  %xmm4
	movaps	 -4 * SIZE(BB), %xmm1
	mulps	%xmm1,  %xmm3
	ADDSUB	%xmm3,  %xmm5
	movaps	 -4 * SIZE(AA), %xmm3
	mulps	%xmm3,  %xmm2
	mulps	%xmm3,  %xmm1
	movaps	 16 * SIZE(AA), %xmm3
	addps	%xmm2,  %xmm6
	ADDSUB	%xmm1,  %xmm7
	movaps	  0 * SIZE(BB), %xmm1

	movaps	%xmm1,  %xmm2
	mulps	%xmm0,  %xmm1
	addps	%xmm1,  %xmm4
	movaps	  4 * SIZE(BB), %xmm1
	mulps	%xmm1,  %xmm0
	ADDSUB	%xmm0,  %xmm5
	movaps	  4 * SIZE(AA), %xmm0
	mulps	%xmm0,  %xmm2
	mulps	%xmm0,  %xmm1
	movaps	  8 * SIZE(AA), %xmm0
	addps	%xmm2,  %xmm6
	ADDSUB	%xmm1,  %xmm7

	movaps	  8 * SIZE(BB), %xmm1
	movaps	%xmm1,  %xmm2
	mulps	%xmm0,  %xmm1
	addps	%xmm1,  %xmm4
	movaps	 12 * SIZE(BB), %xmm1
	mulps	%xmm1,  %xmm0
	ADDSUB	%xmm0,  %xmm5
	movaps	 12 * SIZE(AA), %xmm0
	mulps	%xmm0,  %xmm2
	mulps	%xmm0,  %xmm1
	movaps	 32 * SIZE(AA), %xmm0
	addps	%xmm2,  %xmm6
	ADDSUB	%xmm1,  %xmm7

	movaps	 16 * SIZE(BB), %xmm1
	movaps	%xmm1,  %xmm2
	mulps	%xmm3,  %xmm1
	addps	%xmm1,  %xmm4
	movaps	 20 * SIZE(BB), %xmm1
	mulps	%xmm1,  %xmm3
	ADDSUB	%xmm3,  %xmm5
	movaps	 20 * SIZE(AA), %xmm3
	mulps	%xmm3,  %xmm2
	mulps	%xmm3,  %xmm1
	addps	%xmm2,  %xmm6
	movaps	 24 * SIZE(AA), %xmm3
	ADDSUB	%xmm1,  %xmm7

	movaps	 24 * SIZE(BB), %xmm1
	movaps	%xmm1,  %xmm2
	mulps	%xmm3,  %xmm1
	addps	%xmm1,  %xmm4
	movaps	 28 * SIZE(BB), %xmm1
	mulps	%xmm1,  %xmm3
	ADDSUB	%xmm3,  %xmm5
	movaps	 28 * SIZE(AA), %xmm3
	mulps	%xmm3,  %xmm2
	mulps	%xmm3,  %xmm1
	subl   $-64 * SIZE, BB
	movaps	 48 * SIZE(AA), %xmm3
	subl   $-64 * SIZE, AA
	addps	%xmm2,  %xmm6
	ADDSUB	%xmm1,  %xmm7
	movaps	-32 * SIZE(BB), %xmm1

	
	decl   %eax
	jne    .L12
	ALIGN_4
	
.L15:
#ifndef TRMMKERNEL
	movl	K, %eax
#else
	movl	KKK, %eax
#endif
	andl	$7, %eax		# if (k & 1)
	BRANCH
	je .L18

.L16:
	movaps	%xmm1,  %xmm2
	mulps	%xmm0,  %xmm1
	addps	%xmm1,  %xmm4
	movaps	-28 * SIZE(BB), %xmm1
	mulps	%xmm1,  %xmm0
	ADDSUB	%xmm0,  %xmm5
	movaps	-28 * SIZE(AA), %xmm0
	mulps	%xmm0,  %xmm2
	mulps	%xmm0,  %xmm1
	movaps	-24 * SIZE(AA), %xmm0
	addps	%xmm2,  %xmm6
	ADDSUB	%xmm1,  %xmm7
	movaps	-24 * SIZE(BB), %xmm1

	addl	$8 * SIZE, AA
	addl	$8 * SIZE, BB
	decl	%eax
	jg	.L16

.L18:
	movaps	ALPHA_R, %xmm0
	movaps	ALPHA_I, %xmm1

#if defined(NN) || defined(NT) || defined(TN) || defined(TT) || \
    defined(NR) || defined(NC) || defined(TR) || defined(TC)
	shufps	$0xb1, %xmm5, %xmm5