ztrsm_kernel_rt_4x2_sse.s

Optimized GotoBLAS libraries

/*********************************************************************/
/*                                                                   */
/*             Optimized BLAS libraries                              */
/*                     By Kazushige Goto <[e-mail]>     */
/*                                                                   */
/* Copyright (c) The University of Texas, 2005. All rights reserved. */
/* UNIVERSITY EXPRESSLY DISCLAIMS ANY AND ALL WARRANTIES CONCERNING  */
/* THIS SOFTWARE AND DOCUMENTATION, INCLUDING ANY WARRANTIES OF      */
/* MERCHANTABILITY, FITNESS FOR ANY PARTICULAR PURPOSE,              */
/* NON-INFRINGEMENT AND WARRANTIES OF PERFORMANCE, AND ANY WARRANTY  */
/* THAT MIGHT OTHERWISE ARISE FROM COURSE OF DEALING OR USAGE OF     */
/* TRADE. NO WARRANTY IS EITHER EXPRESS OR IMPLIED WITH RESPECT TO   */
/* THE USE OF THE SOFTWARE OR DOCUMENTATION.                         */
/* Under no circumstances shall University be liable for incidental, */
/* special, indirect, direct or consequential damages or loss of     */
/* profits, interruption of business, or related expenses which may  */
/* arise from use of Software or Documentation, including but not    */
/* limited to those resulting from defects in Software and/or        */
/* Documentation, or loss or inaccuracy of data of any kind.         */
/*********************************************************************/

#define ASSEMBLER
#include "common.h"
 
#define OLD_M	%rdi
#define OLD_N	%rsi
#define M	%r13
#define N	%r14
#define K	%rdx
#define A	%rcx
#define B	%r8
#define C	%r9
#define LDC	%r10

#define I	%r11
#define J	%r12
#define AO	%rdi
#define BO	%rsi
#define	CO1	%r15
#define CO2	%rbp

#ifndef WINDOWS_ABI

#define STACKSIZE 64

#define OLD_LDC		 8 + STACKSIZE(%rsp)
#define OLD_OFFSET	16 + STACKSIZE(%rsp)

#else

#define STACKSIZE 256

#define OLD_ALPHA_I	40 + STACKSIZE(%rsp)
#define OLD_A		48 + STACKSIZE(%rsp)
#define OLD_B		56 + STACKSIZE(%rsp)
#define OLD_C		64 + STACKSIZE(%rsp)
#define OLD_LDC		72 + STACKSIZE(%rsp)
#define OLD_OFFSET	80 + STACKSIZE(%rsp)

#endif

#define POSINV	  0(%rsp)
#define OFFSET	 16(%rsp)
#define KK	 24(%rsp)
#define KKK	 32(%rsp)
#define AORIG    40(%rsp)
#define BORIG	 48(%rsp)
#define BUFFER  128(%rsp)

#ifdef OPTERON
#define movsd movlps
#endif

#if defined(PENTIUM4) || defined(CORE2) || defined(PENRYN)
#define PREFETCH     prefetcht0
#define PREFETCHW    prefetcht0
#define PREFETCHNTA  prefetchnta
#define PREFETCHSIZE (8 * 6 + 4)
#endif

#if defined(OPTERON) || defined(BARCELONA)
#define PREFETCH     prefetch
#define PREFETCHW    prefetchw
#define PREFETCHNTA  prefetchnta
#define PREFETCHSIZE (8 * 6 + 4)
#endif

#ifdef GENERIC
#define PREFETCH     prefetcht0
#define PREFETCHW    prefetcht0
#define PREFETCHNTA  prefetchnta
#define PREFETCHSIZE (8 * 6 + 4)
#endif

#define KERNEL1(xx) \
	mulps	%xmm8, %xmm9 ;\
	addps	%xmm9, %xmm0 ;\
	movaps	 0 * SIZE + 2 * (xx) * SIZE(BO), %xmm9 ;\
	mulps	%xmm8, %xmm11 ;\
	PREFETCH	(PREFETCHSIZE     +  0) * SIZE + 1 * (xx) * SIZE(AO) ;\
	addps	%xmm11, %xmm1 ;\
	movaps	 4 * SIZE + 2 * (xx) * SIZE(BO), %xmm11 ;\
	mulps	%xmm8, %xmm13 ;\
	mulps	12 * SIZE + 2 * (xx) * SIZE(BO), %xmm8 ;\
	addps	%xmm13, %xmm2 ;\
	movaps	 8 * SIZE + 2 * (xx) * SIZE(BO), %xmm13 ;\
	addps	%xmm8, %xmm3 ;\
	movaps	16 * SIZE + 1 * (xx) * SIZE(AO), %xmm8

#define KERNEL2(xx) \
	mulps	%xmm10, %xmm9 ;\
	addps	%xmm9, %xmm4 ;\
	movaps	32 * SIZE + 2 * (xx) * SIZE(BO), %xmm9 ;\
	mulps	%xmm10, %xmm11 ;\
	addps	%xmm11, %xmm5 ;\
	movaps	20 * SIZE + 2 * (xx) * SIZE(BO), %xmm11 ;\
	mulps	%xmm10, %xmm13 ;\
	mulps	12 * SIZE + 2 * (xx) * SIZE(BO), %xmm10 ;\
	addps	%xmm13, %xmm6 ;\
	movaps	24 * SIZE + 2 * (xx) * SIZE(BO), %xmm13 ;\
	addps	%xmm10, %xmm7 ;\
	movaps	20 * SIZE + 1 * (xx) * SIZE(AO), %xmm10

#define KERNEL3(xx) \
	mulps	%xmm12, %xmm15 ;\
	addps	%xmm15, %xmm0 ;\
	movaps	16 * SIZE + 2 * (xx) * SIZE(BO), %xmm15 ;\
	mulps	%xmm12, %xmm11 ;\
	addps	%xmm11, %xmm1 ;\
	movaps	20 * SIZE + 2 * (xx) * SIZE(BO), %xmm11 ;\
	mulps	%xmm12, %xmm13 ;\
	mulps	28 * SIZE + 2 * (xx) * SIZE(BO), %xmm12 ;\
	addps	%xmm13, %xmm2 ;\
	movaps	24 * SIZE + 2 * (xx) * SIZE(BO), %xmm13 ;\
	addps	%xmm12, %xmm3 ;\
	movaps	24 * SIZE + 1 * (xx) * SIZE(AO), %xmm12

#define KERNEL4(xx) \
	mulps	%xmm14, %xmm15 ;\
	addps	%xmm15, %xmm4 ;\
	movaps	48 * SIZE + 2 * (xx) * SIZE(BO), %xmm15 ;\
	mulps	%xmm14, %xmm11 ;\
	addps	%xmm11, %xmm5 ;\
	movaps	36 * SIZE + 2 * (xx) * SIZE(BO), %xmm11 ;\
	mulps	%xmm14, %xmm13 ;\
	mulps	28 * SIZE + 2 * (xx) * SIZE(BO), %xmm14 ;\
	addps	%xmm13, %xmm6 ;\
	movaps	40 * SIZE + 2 * (xx) * SIZE(BO), %xmm13 ;\
	addps	%xmm14, %xmm7 ;\
	movaps	28 * SIZE + 1 * (xx) * SIZE(AO), %xmm14

#define KERNEL5(xx) \
	mulps	%xmm8, %xmm9 ;\
	addps	%xmm9, %xmm0 ;\
	movaps	32 * SIZE + 2 * (xx) * SIZE(BO), %xmm9 ;\
	mulps	%xmm8, %xmm11 ;\
	PREFETCH	(PREFETCHSIZE     +  8) * SIZE + 1 * (xx) * SIZE(AO) ;\
	addps	%xmm11, %xmm1 ;\
	movaps	36 * SIZE + 2 * (xx) * SIZE(BO), %xmm11 ;\
	mulps	%xmm8, %xmm13 ;\
	mulps	44 * SIZE + 2 * (xx) * SIZE(BO), %xmm8 ;\
	addps	%xmm13, %xmm2 ;\
	movaps	40 * SIZE + 2 * (xx) * SIZE(BO), %xmm13 ;\
	addps	%xmm8, %xmm3 ;\
	movaps	32 * SIZE + 1 * (xx) * SIZE(AO), %xmm8

#define KERNEL6(xx) \
	mulps	%xmm10, %xmm9 ;\
	addps	%xmm9, %xmm4 ;\
	movaps	64 * SIZE + 2 * (xx) * SIZE(BO), %xmm9 ;\
	mulps	%xmm10, %xmm11 ;\
	addps	%xmm11, %xmm5 ;\
	movaps	52 * SIZE + 2 * (xx) * SIZE(BO), %xmm11 ;\
	mulps	%xmm10, %xmm13 ;\
	mulps	44 * SIZE + 2 * (xx) * SIZE(BO), %xmm10 ;\
	addps	%xmm13, %xmm6 ;\
	movaps	56 * SIZE + 2 * (xx) * SIZE(BO), %xmm13 ;\
	addps	%xmm10, %xmm7 ;\
	movaps	36 * SIZE + 1 * (xx) * SIZE(AO), %xmm10

#define KERNEL7(xx) \
	mulps	%xmm12, %xmm15 ;\
	addps	%xmm15, %xmm0 ;\
	movaps	48 * SIZE + 2 * (xx) * SIZE(BO), %xmm15 ;\
	mulps	%xmm12, %xmm11 ;\
	addps	%xmm11, %xmm1 ;\
	movaps	52 * SIZE + 2 * (xx) * SIZE(BO), %xmm11 ;\
	mulps	%xmm12, %xmm13 ;\
	mulps	60 * SIZE + 2 * (xx) * SIZE(BO), %xmm12 ;\
	addps	%xmm13, %xmm2 ;\
	movaps	56 * SIZE + 2 * (xx) * SIZE(BO), %xmm13 ;\
	addps	%xmm12, %xmm3 ;\
	movaps	40 * SIZE + 1 * (xx) * SIZE(AO), %xmm12

#define KERNEL8(xx) \
	mulps	%xmm14, %xmm15 ;\
	addps	%xmm15, %xmm4 ;\
	movaps	80 * SIZE + 2 * (xx) * SIZE(BO), %xmm15 ;\
	mulps	%xmm14, %xmm11 ;\
	addps	%xmm11, %xmm5 ;\
	movaps	68 * SIZE + 2 * (xx) * SIZE(BO), %xmm11 ;\
	mulps	%xmm14, %xmm13 ;\
	mulps	60 * SIZE + 2 * (xx) * SIZE(BO), %xmm14 ;\
	addps	%xmm13, %xmm6 ;\
	movaps	72 * SIZE + 2 * (xx) * SIZE(BO), %xmm13 ;\
	addps	%xmm14, %xmm7 ;\
	movaps	44 * SIZE + 1 * (xx) * SIZE(AO), %xmm14

	PROLOGUE
	PROFCODE
	
	subq	$STACKSIZE, %rsp
	
	movq	%rbx,  0(%rsp)
	movq	%rbp,  8(%rsp)
	movq	%r12, 16(%rsp)
	movq	%r13, 24(%rsp)
	movq	%r14, 32(%rsp)
	movq	%r15, 40(%rsp)


#ifdef WINDOWS_ABI
	movq	%rdi,    48(%rsp)
	movq	%rsi,    56(%rsp)
	movups	%xmm6,   64(%rsp)
	movups	%xmm7,   80(%rsp)
	movups	%xmm8,   96(%rsp)
	movups	%xmm9,  112(%rsp)
	movups	%xmm10, 128(%rsp)
	movups	%xmm11, 144(%rsp)
	movups	%xmm12, 160(%rsp)
	movups	%xmm13, 176(%rsp)
	movups	%xmm14, 192(%rsp)
	movups	%xmm15, 208(%rsp)

	movq	ARG1,      OLD_M
	movq	ARG2,      OLD_N
	movq	ARG3,      K
	movq	OLD_A,     A
	movq	OLD_B,     B
	movq	OLD_C,     C
	movq	OLD_LDC,   LDC
	movsd	OLD_OFFSET, %xmm4
#else
	movq	OLD_LDC,   LDC
	movsd	OLD_OFFSET, %xmm4
#endif

	EMMS

	movq	%rsp, %rbx	# save old stack
	subq	$128 + GEMM_Q * 64, %rsp
	andq	$-4096, %rsp	# align stack

#ifdef WINDOWS_ABI
#if GEMM_Q > 192
	movq	$0,  4096 * 3(%rsp)
#endif
#if GEMM_Q > 128
	movq	$0,  4096 * 2(%rsp)
#endif
#if GEMM_Q >  64
	movq	$0,  4096 * 1(%rsp)
#endif
	movq	$0,  4096 * 0(%rsp)
#endif

	movq	OLD_M, M
	movq	OLD_N, N

	pxor	%xmm15, %xmm15
	cmpeqps	%xmm15, %xmm15
	pslld	$31, %xmm15	# Generate mask
	pxor	%xmm2, %xmm2

#ifndef CONJ
	movss	  %xmm15,  0 + POSINV
	movss	  %xmm2,   4 + POSINV
	movss	  %xmm15,  8 + POSINV
	movss	  %xmm2,  12 + POSINV
#else
	movss	  %xmm2,   0 + POSINV
	movss	  %xmm15,  4 + POSINV
	movss	  %xmm2,   8 + POSINV
	movss	  %xmm15, 12 + POSINV
#endif

	movlpd	%xmm4, OFFSET
	movlpd	%xmm4, KK

	salq	$ZBASE_SHIFT, LDC

#ifdef LN
       movq	M, %rax
       salq	$ZBASE_SHIFT, %rax
       addq	%rax, C
       imulq	K, %rax
       addq	%rax, A
#endif

#ifdef RT
       movq	N, %rax
       salq	$ZBASE_SHIFT, %rax
       imulq	K, %rax
       addq	%rax, B

       movq	N, %rax
       imulq	LDC, %rax
       addq	%rax, C
#endif

#ifdef RN
	negq	KK
#endif	

#ifdef RT
       movq	N, %rax
       subq	OFFSET, %rax
       movq	%rax, KK
#endif

	testq	$1, N
	je	.L40
	ALIGN_4

#ifdef LN
	movq	OFFSET, %rax
	addq	M, %rax
	movq	%rax, KK
#endif	

	leaq	BUFFER, BO

#ifdef RT
       movq	K, %rax
       salq	$ZBASE_SHIFT, %rax
       subq	%rax, B
#endif

#if defined(LN) || defined(RT)
	movq	KK, %rax
	movq	B, BORIG
	salq	$ZBASE_SHIFT, %rax
	leaq	(B,  %rax, 1), B
	leaq	(BO, %rax, 4), BO
#endif	

#if defined(LT)
	movq	OFFSET, %rax
	movq	%rax, KK
#endif

#if defined(LT) || defined(RN)
	movq	KK, %rax
#else
	movq	K, %rax
	subq	KK, %rax
#endif
	sarq	$2, %rax
	jle	.L43
	ALIGN_4
	
.L42:
	movaps	 0 * SIZE(B), %xmm3
	movaps	 4 * SIZE(B), %xmm7

	pshufd	 $0x00, %xmm3, %xmm0
	pshufd	 $0x55, %xmm3, %xmm1
	pshufd	 $0xaa, %xmm3, %xmm2
	pshufd	 $0xff, %xmm3, %xmm3

	movaps	%xmm0,  0 * SIZE(BO)
	movaps	%xmm1,  4 * SIZE(BO)
	movaps	%xmm2,  8 * SIZE(BO)
	movaps	%xmm3, 12 * SIZE(BO)

	pshufd	 $0x00, %xmm7, %xmm4
	pshufd	 $0x55, %xmm7, %xmm5
	pshufd	 $0xaa, %xmm7, %xmm6
	pshufd	 $0xff, %xmm7, %xmm7

	movaps	%xmm4, 16 * SIZE(BO)
	movaps	%xmm5, 20 * SIZE(BO)
	movaps	%xmm6, 24 * SIZE(BO)
	movaps	%xmm7, 28 * SIZE(BO)

	addq	$ 8 * SIZE, B
	addq	$32 * SIZE, BO
	decq	%rax
	jne	.L42
	ALIGN_4

.L43:
#if defined(LT) || defined(RN)
	movq	KK, %rax
#else
	movq	K, %rax
	subq	KK, %rax
#endif
	andq	$3, %rax
	BRANCH
	jle	.L50
	ALIGN_4

.L44:
	movlps	 0 * SIZE(B), %xmm3

	pshufd	 $0x00, %xmm3, %xmm0
	pshufd	 $0x55, %xmm3, %xmm1

	movaps	%xmm0,  0 * SIZE(BO)
	movaps	%xmm1,  4 * SIZE(BO)

	addq	$2 * SIZE, B
	addq	$8 * SIZE, BO
	decq	%rax
	jne	.L44
	ALIGN_4
	
.L50:
#if defined(LT) || defined(RN)
	movq	A, AO
#else
	movq	A, AORIG
#endif

#ifdef RT
       subq	LDC, C
#endif

	movq	C, CO1			# coffset1 = c

#ifndef RT
	addq	LDC, C
#endif

	movq	M,  I
	sarq	$2, I		# i = (m >> 2)
	jle	.L60
	ALIGN_4

.L51:
#ifdef LN
       movq	K, %rax
       salq	$2 + ZBASE_SHIFT, %rax
       subq	%rax, AORIG
#endif

#if defined(LN) || defined(RT)
	movq	KK, %rax
	movq	AORIG, AO
	salq	$ZBASE_SHIFT, %rax
	leaq	(AO, %rax, 4), AO
#endif

	leaq	BUFFER, BO

#if defined(LN) || defined(RT)
	movq	KK, %rax
	salq	$ZBASE_SHIFT, %rax
	leaq	(BO, %rax, 4), BO
#endif	

	movaps	 0 * SIZE(AO), %xmm8
	movaps	16 * SIZE(AO), %xmm10
	movaps	32 * SIZE(AO), %xmm12
	movaps	48 * SIZE(AO), %xmm14

	movaps	 0 * SIZE(BO), %xmm9
	movaps	16 * SIZE(BO), %xmm11
	movaps	32 * SIZE(BO), %xmm13
	movaps	48 * SIZE(BO), %xmm15

	pxor	%xmm0, %xmm0
	pxor	%xmm1, %xmm1
	pxor	%xmm2, %xmm2
	pxor	%xmm3, %xmm3

	pxor	%xmm4, %xmm4
	pxor	%xmm5, %xmm5
	pxor	%xmm6, %xmm6
	pxor	%xmm7, %xmm7

	PREFETCHW      4 * SIZE(CO1)

#if defined(LT) || defined(RN)
	movq	KK, %rax
#else
	movq	K, %rax
	subq	KK, %rax
#endif
	sarq	$3, %rax
	je	.L55
	ALIGN_4

.L52:
	mulps	%xmm8, %xmm9
#if defined(OPTERON) && defined(HAVE_PREFETCH)
	PREFETCH	(PREFETCHSIZE +  0) * SIZE(AO)
#endif
	mulps	 4 * SIZE(BO), %xmm8
	addps	%xmm9, %xmm0
	movaps	 0 * SIZE(BO), %xmm9
	addps	%xmm8, %xmm1
	movaps	 4 * SIZE(AO), %xmm8
	mulps	%xmm8, %xmm9
	mulps	 4 * SIZE(BO), %xmm8
	addps	%xmm9, %xmm4
	movaps	 8 * SIZE(BO), %xmm9
	addps	%xmm8, %xmm5
	movaps	 8 * SIZE(AO), %xmm8

	mulps	%xmm8, %xmm9
	mulps	12 * SIZE(BO), %xmm8
	addps	%xmm9, %xmm0
	movaps	 8 * SIZE(BO), %xmm9
	addps	%xmm8, %xmm1
	movaps	12 * SIZE(AO), %xmm8
	mulps	%xmm8, %xmm9
	mulps	12 * SIZE(BO), %xmm8
	addps	%xmm9, %xmm4
	movaps	64 * SIZE(BO), %xmm9
	addps	%xmm8, %xmm5
	movaps	64 * SIZE(AO), %xmm8

#if defined(OPTERON) && defined(HAVE_PREFETCH)
	PREFETCH	(PREFETCHSIZE + 16) * SIZE(AO)
#endif
	mulps	%xmm10, %xmm11
	mulps	20 * SIZE(BO), %xmm10
	addps	%xmm11, %xmm0
	movaps	16 * SIZE(BO), %xmm11
	addps	%xmm10, %xmm1
	movaps	20 * SIZE(AO), %xmm10
	mulps	%xmm10, %xmm11
	mulps	20 * SIZE(BO), %xmm10
	addps	%xmm11, %xmm4
	movaps	24 * SIZE(BO), %xmm11
	addps	%xmm10, %xmm5
	movaps	24 * SIZE(AO), %xmm10

	mulps	%xmm10, %xmm11
	mulps	28 * SIZE(BO), %xmm10
	addps	%xmm11, %xmm0
	movaps	24 * SIZE(BO), %xmm11
	addps	%xmm10, %xmm1
	movaps	28 * SIZE(AO), %xmm10
	mulps	%xmm10, %xmm11
	mulps	28 * SIZE(BO), %xmm10
	addps	%xmm11, %xmm4
	movaps	 80 * SIZE(BO), %xmm11
	addps	%xmm10, %xmm5
	movaps	 80 * SIZE(AO), %xmm10

#if defined(OPTERON) && defined(HAVE_PREFETCH)
	PREFETCH	(PREFETCHSIZE + 32) * SIZE(AO)
#endif
	mulps	%xmm12, %xmm13
	mulps	36 * SIZE(BO), %xmm12
	addps	%xmm13, %xmm0
	movaps	32 * SIZE(BO), %xmm13
	addps	%xmm12, %xmm1
	movaps	36 * SIZE(AO), %xmm12
	mulps	%xmm12, %xmm13
	mulps	36 * SIZE(BO), %xmm12
	addps	%xmm13, %xmm4
	movaps	40 * SIZE(BO), %xmm13
	addps	%xmm12, %xmm5
	movaps	40 * SIZE(AO), %xmm12

	mulps	%xmm12, %xmm13
	mulps	44 * SIZE(BO), %xmm12
	addps	%xmm13, %xmm0
	movaps	40 * SIZE(BO), %xmm13
	addps	%xmm12, %xmm1
	movaps	44 * SIZE(AO), %xmm12
	mulps	%xmm12, %xmm13
	mulps	44 * SIZE(BO), %xmm12
	addps	%xmm13, %xmm4
	movaps	 96 * SIZE(BO), %xmm13
	addps	%xmm12, %xmm5
	movaps	 96 * SIZE(AO), %xmm12

#if defined(OPTERON) && defined(HAVE_PREFETCH)
	PREFETCH	(PREFETCHSIZE + 48) * SIZE(AO)
#endif
	mulps	%xmm14, %xmm15
	mulps	52 * SIZE(BO), %xmm14
	addps	%xmm15, %xmm0
	movaps	48 * SIZE(BO), %xmm15
	addps	%xmm14, %xmm1
	movaps	52 * SIZE(AO), %xmm14
	mulps	%xmm14, %xmm15
	mulps	52 * SIZE(BO), %xmm14
	addps	%xmm15, %xmm4
	movaps	56 * SIZE(BO), %xmm15
	addps	%xmm14, %xmm5
	movaps	56 * SIZE(AO), %xmm14

	mulps	%xmm14, %xmm15
	mulps	60 * SIZE(BO), %xmm14
	addps	%xmm15, %xmm0
	movaps	56 * SIZE(BO), %xmm15
	addps	%xmm14, %xmm1
	movaps	60 * SIZE(AO), %xmm14
	mulps	%xmm14, %xmm15
	mulps	60 * SIZE(BO), %xmm14
	addps	%xmm15, %xmm4
	movaps	112 * SIZE(BO), %xmm15
	addps	%xmm14, %xmm5
	movaps	112 * SIZE(AO), %xmm14

	addq   $64 * SIZE, AO
	addq   $64 * SIZE, BO


	decq   %rax
	jne    .L52
	ALIGN_4

.L55:
#if defined(LT) || defined(RN)
	movq	KK, %rax
#else
	movq	K, %rax
	subq	KK, %rax
#endif
	movaps	POSINV,  %xmm15
	andq	$7, %rax		# if (k & 1)
	BRANCH
	je .L58
	ALIGN_4

.L56:
	mulps	%xmm8, %xmm9
	mulps	 4 * SIZE(BO), %xmm8
	addps	%xmm9, %xmm0
	movaps	 0 * SIZE(BO), %xmm9
	addps	%xmm8, %xmm1
	movaps	 4 * SIZE(AO), %xmm8
	mulps	%xmm8, %xmm9
	mulps	 4 * SIZE(BO), %xmm8
	addps	%xmm9, %xmm4
	movaps	 8 * SIZE(BO), %xmm9
	addps	%xmm8, %xmm5
	movaps	 8 * SIZE(AO), %xmm8

	addq	$ 8 * SIZE, AO		# aoffset  += 4
	addq	$ 8 * SIZE, BO		# boffset1 += 8
	decq	%rax
	jg	.L56
	ALIGN_4

.L58:
	shufps	$0xb1, %xmm1, %xmm1
	shufps	$0xb1, %xmm5, %xmm5

#if defined(LN) || defined(LT)
#ifndef CONJ
	xorps	 %xmm15, %xmm1
	xorps	 %xmm15, %xmm5
#else
	xorps	 %xmm15, %xmm0
	xorps	 %xmm15, %xmm4
#endif
#else
	xorps	 %xmm15, %xmm1
	xorps	 %xmm15, %xmm5
#endif

	addps	%xmm1, %xmm0
	addps	%xmm5, %xmm4

#if defined(LN) || defined(RT)
	movq	KK, %rax
#ifdef LN
	subq	$4, %rax
#else
	subq	$1, %rax
#endif

	movq	AORIG, AO
	movq	BORIG, B
	leaq	BUFFER, BO

	salq	$ZBASE_SHIFT, %rax
	leaq	(AO, %rax, 4), AO
	leaq	(B,  %rax, 1), B
	leaq	(BO, %rax, 4), BO
#endif

#if defined(LN) || defined(LT)
	movaps	%xmm0, %xmm1
	unpcklpd %xmm2, %xmm0
	unpckhpd %xmm2, %xmm1

	movaps	%xmm4, %xmm5
	unpcklpd %xmm6, %xmm4
	unpckhpd %xmm6, %xmm5

	movlps	 0 * SIZE(B), %xmm2
	movlps	 2 * SIZE(B), %xmm3
	movlps	 4 * SIZE(B), %xmm6
	movlps	 6 * SIZE(B), %xmm7

	subps	%xmm0,  %xmm2
	subps	%xmm1,  %xmm3
	subps	%xmm4,  %xmm6
	subps	%xmm5,  %xmm7
#else
	movaps	 0 * SIZE(AO), %xmm1
	movaps	 4 * SIZE(AO), %xmm3

	subps	%xmm0,  %xmm1
	subps	%xmm4,  %xmm3
#endif

#ifdef LN
	movaps	28 * SIZE(AO), %xmm8

	pshufd	 $0xee, %xmm8, %xmm9
	pshufd	 $0xbb, %xmm8, %xmm10

	pshufd	 $0xa0, %xmm7, %xmm0
	pshufd	 $0xf5, %xmm7, %xmm7

#ifndef CONJ
	xorps	 %xmm15, %xmm7
#else
	xorps	 %xmm15, %xmm0
#endif

	mulps	%xmm9,  %xmm0
	mulps	%xmm10, %xmm7