trsm_kernel_lt_8x4_sse.s

Optimized GotoBLAS libraries

/*********************************************************************/
/*                                                                   */
/*             Optimized BLAS libraries                              */
/*                     By Kazushige Goto <[e-mail]>     */
/*                                                                   */
/* Copyright (c) The University of Texas, 2005. All rights reserved. */
/* UNIVERSITY EXPRESSLY DISCLAIMS ANY AND ALL WARRANTIES CONCERNING  */
/* THIS SOFTWARE AND DOCUMENTATION, INCLUDING ANY WARRANTIES OF      */
/* MERCHANTABILITY, FITNESS FOR ANY PARTICULAR PURPOSE,              */
/* NON-INFRINGEMENT AND WARRANTIES OF PERFORMANCE, AND ANY WARRANTY  */
/* THAT MIGHT OTHERWISE ARISE FROM COURSE OF DEALING OR USAGE OF     */
/* TRADE. NO WARRANTY IS EITHER EXPRESS OR IMPLIED WITH RESPECT TO   */
/* THE USE OF THE SOFTWARE OR DOCUMENTATION.                         */
/* Under no circumstances shall University be liable for incidental, */
/* special, indirect, direct or consequential damages or loss of     */
/* profits, interruption of business, or related expenses which may  */
/* arise from use of Software or Documentation, including but not    */
/* limited to those resulting from defects in Software and/or        */
/* Documentation, or loss or inaccuracy of data of any kind.         */
/*********************************************************************/

#define ASSEMBLER
#include "common.h"
 
#define M	%rdi
#define N	%rsi
#define K	%rdx
#define A	%rcx
#define B	%r8
#define C	%r9
#define LDC	%r10

#define I	%r11
#define J	%r12
#define AO	%r13
#define BO	%r14
#define	CO1	%r15
#define CO2	%rbp
	
#ifndef WINDOWS_ABI

#define STACKSIZE 64

#define OLD_LDC		 8 + STACKSIZE(%rsp)
#define OLD_OFFSET	16 + STACKSIZE(%rsp)

#else

#define STACKSIZE 256

#define OLD_A		40 + STACKSIZE(%rsp)
#define OLD_B		48 + STACKSIZE(%rsp)
#define OLD_C		56 + STACKSIZE(%rsp)
#define OLD_LDC		64 + STACKSIZE(%rsp)
#define OLD_OFFSET	72 + STACKSIZE(%rsp)

#endif

#define ALPHA	  0(%rsp)
#define OFFSET	 16(%rsp)
#define KK	 24(%rsp)
#define KKK	 32(%rsp)
#define AORIG	 40(%rsp)
#define BORIG	 48(%rsp)
#define BUFFER	128(%rsp)

#ifdef PENTIUM4
#define PREFETCH     prefetcht0
#define PREFETCHW    prefetcht0
#endif

#ifdef OPTERON
#define PREFETCH     prefetch
#define PREFETCHW    prefetchw
#define movsd movlps
#endif

#ifdef GENERIC
#define PREFETCH     prefetcht0
#define PREFETCHW    prefetcht0
#endif

	PROLOGUE
	PROFCODE
	
	subq	$STACKSIZE, %rsp

	EMMS
	
	movq	%rbx,  0(%rsp)
	movq	%rbp,  8(%rsp)
	movq	%r12, 16(%rsp)
	movq	%r13, 24(%rsp)
	movq	%r14, 32(%rsp)
	movq	%r15, 40(%rsp)

#ifdef WINDOWS_ABI
	movq	%rdi,    48(%rsp)
	movq	%rsi,    56(%rsp)
	movups	%xmm6,   64(%rsp)
	movups	%xmm7,   80(%rsp)
	movups	%xmm8,   96(%rsp)
	movups	%xmm9,  112(%rsp)
	movups	%xmm10, 128(%rsp)
	movups	%xmm11, 144(%rsp)
	movups	%xmm12, 160(%rsp)
	movups	%xmm13, 176(%rsp)
	movups	%xmm14, 192(%rsp)
	movups	%xmm15, 208(%rsp)

	movq	ARG1,      M
	movq	ARG2,      N
	movq	ARG3,      K
	movq	OLD_A,     A
	movq	OLD_B,     B
	movq	OLD_C,     C
	movq	OLD_LDC,   LDC
	movsd	OLD_OFFSET, %xmm4

	movaps	%xmm3, %xmm0

#else
	movq	OLD_LDC,   LDC
	movsd	OLD_OFFSET, %xmm4

#endif

	movq	%rsp, %rbx	# save old stack
	subq	$128 + GEMM_Q * 64, %rsp
	andq	$-4096, %rsp	# align stack

#ifdef WINDOWS_ABI
#if GEMM_Q > 192
	movq	$0,  4096 * 3(%rsp)
#endif
#if GEMM_Q > 128
	movq	$0,  4096 * 2(%rsp)
#endif
#if GEMM_Q >  64
	movq	$0,  4096 * 1(%rsp)
#endif
	movq	$0,  4096 * 0(%rsp)
#endif

	movsd	%xmm4, OFFSET
	movsd	%xmm4, KK

	leaq	(, LDC, SIZE), LDC

#ifdef LN
       leaq	(, M, SIZE), %rax
       addq	%rax, C
       imulq	K, %rax
       addq	%rax, A
#endif

#ifdef RT
       leaq	(, N, SIZE), %rax
       imulq	K, %rax
       addq	%rax, B
       movq	N, %rax
       imulq	LDC, %rax
       addq	%rax, C
#endif

#ifdef RN
	negq	KK
#endif	

#ifdef RT
       movq	N, %rax
       subq	OFFSET, %rax
       movq	%rax, KK
#endif

	movq	N,  J
	sarq	$2, J		# j = (n >> 2)
	jle	.L50

.L01:
/* Copying to Sub Buffer */

#ifdef LN
	movq	OFFSET, %rax
	addq	M, %rax
	movq	%rax, KK
#endif	

	leaq	BUFFER, BO
	
#ifdef RT
       movq	K, %rax
       salq	$2 + BASE_SHIFT, %rax
       subq	%rax, B
#endif

#if defined(LN) || defined(RT)
	movq	KK, %rax
	movq	B, BORIG
	salq	$2 + BASE_SHIFT, %rax
	leaq	(B,  %rax, 1), B
	leaq	(BO, %rax, 4), BO
#endif	

#ifdef LT
	movq	OFFSET, %rax
	movq	%rax, KK
#endif

#if defined(LT) || defined(RN)
	movq	KK, %rax
#else
	movq	K, %rax
	subq	KK, %rax
#endif
	sarq	$2, %rax
	jle	.L03
	ALIGN_4
	
.L02:
	movaps	 0 * SIZE(B), %xmm3
	movaps	 4 * SIZE(B), %xmm7
	movaps	 8 * SIZE(B), %xmm11
	movaps	12 * SIZE(B), %xmm15

	pshufd	 $0x00, %xmm3, %xmm0
	pshufd	 $0x55, %xmm3, %xmm1
	pshufd	 $0xaa, %xmm3, %xmm2
	pshufd	 $0xff, %xmm3, %xmm3

	pshufd	 $0x00, %xmm7, %xmm4
	pshufd	 $0x55, %xmm7, %xmm5
	pshufd	 $0xaa, %xmm7, %xmm6
	pshufd	 $0xff, %xmm7, %xmm7

	movaps	%xmm0,  0 * SIZE(BO)
	movaps	%xmm1,  4 * SIZE(BO)
	movaps	%xmm2,  8 * SIZE(BO)
	movaps	%xmm3, 12 * SIZE(BO)
	movaps	%xmm4, 16 * SIZE(BO)
	movaps	%xmm5, 20 * SIZE(BO)
	movaps	%xmm6, 24 * SIZE(BO)
	movaps	%xmm7, 28 * SIZE(BO)

	pshufd	 $0x00, %xmm11, %xmm8
	pshufd	 $0x55, %xmm11, %xmm9
	pshufd	 $0xaa, %xmm11, %xmm10
	pshufd	 $0xff, %xmm11, %xmm11

	pshufd	 $0x00, %xmm15, %xmm12
	pshufd	 $0x55, %xmm15, %xmm13
	pshufd	 $0xaa, %xmm15, %xmm14
	pshufd	 $0xff, %xmm15, %xmm15

	movaps	%xmm8,  32 * SIZE(BO)
	movaps	%xmm9,  36 * SIZE(BO)
	movaps	%xmm10, 40 * SIZE(BO)
	movaps	%xmm11, 44 * SIZE(BO)
	movaps	%xmm12, 48 * SIZE(BO)
	movaps	%xmm13, 52 * SIZE(BO)
	movaps	%xmm14, 56 * SIZE(BO)
	movaps	%xmm15, 60 * SIZE(BO)

	addq	$16 * SIZE, B
	addq	$64 * SIZE, BO

	decq	%rax
	jne	.L02
	ALIGN_4

.L03:
#if defined(LT) || defined(RN)
	movq	KK, %rax
#else
	movq	K, %rax
	subq	KK, %rax
#endif
	andq	$3, %rax
	BRANCH
	jle	.L10
	ALIGN_4

.L04:
	movaps	 0 * SIZE(B), %xmm3

	pshufd	 $0x00, %xmm3, %xmm0
	pshufd	 $0x55, %xmm3, %xmm1
	pshufd	 $0xaa, %xmm3, %xmm2
	pshufd	 $0xff, %xmm3, %xmm3

	movaps	%xmm0,  0 * SIZE(BO)
	movaps	%xmm1,  4 * SIZE(BO)
	movaps	%xmm2,  8 * SIZE(BO)
	movaps	%xmm3, 12 * SIZE(BO)

	addq	$ 4 * SIZE, B
	addq	$16 * SIZE, BO
	decq	%rax
	jne	.L04
	ALIGN_4
	
.L10:
#if defined(LT) || defined(RN)
	movq	A, AO
#else
	movq	A, AORIG
#endif

#ifdef RT
       leaq	(, LDC, 4), %rax
       subq	%rax, C
#endif

	movq	C, CO1			# coffset1 = c
	leaq	(C, LDC, 1), CO2	# coffset2 = c + ldc
#ifndef RT
	leaq	(C, LDC, 4), C
#endif

	movq	M,  I
	sarq	$3, I	# i = (m >> 3)
	jle	.L20
	ALIGN_4

.L11:
#ifdef LN
       movq	K, %rax
       salq	$3 + BASE_SHIFT, %rax
       subq	%rax, AORIG
#endif

#if defined(LN) || defined(RT)
	movq	KK, %rax
	movq	AORIG, AO
	leaq	(, %rax, SIZE), %rax
	leaq	(AO, %rax, 8), AO
#endif

	leaq	BUFFER, BO

#if defined(LN) || defined(RT)
	movq	KK, %rax
	salq	$2 + BASE_SHIFT, %rax
	leaq	(BO, %rax, 4), BO
#endif	

	movaps	 0 * SIZE(BO), %xmm9
	movaps	 4 * SIZE(BO), %xmm11
	movaps	 8 * SIZE(BO), %xmm13
	movaps	16 * SIZE(BO), %xmm15

	movaps	 0 * SIZE(AO), %xmm8
	pxor	%xmm0, %xmm0
	movaps	 4 * SIZE(AO), %xmm10
	pxor	%xmm1, %xmm1
	movaps	 8 * SIZE(AO), %xmm12
	pxor	%xmm2, %xmm2
	movaps	12 * SIZE(AO), %xmm14
	pxor	%xmm3, %xmm3

	PREFETCHW      7 * SIZE(CO1)
	pxor	%xmm4, %xmm4
	PREFETCHW      7 * SIZE(CO2)
	pxor	%xmm5, %xmm5
	PREFETCHW      7 * SIZE(CO1, LDC, 2)
	pxor	%xmm6, %xmm6
	PREFETCHW      7 * SIZE(CO2, LDC, 2)
	pxor	%xmm7, %xmm7

#if defined(LT) || defined(RN)
	movq	KK, %rax
#else
	movq	K, %rax
	subq	KK, %rax
#endif
	sarq	$2, %rax
	je	.L15
	ALIGN_4
	
.L12:
	mulps	%xmm8, %xmm9
	addps	%xmm9, %xmm0
	movaps	 0 * SIZE(BO), %xmm9
	mulps	%xmm8, %xmm11
	addps	%xmm11, %xmm1
	movaps	 4 * SIZE(BO), %xmm11
	mulps	%xmm8, %xmm13
	mulps	12 * SIZE(BO), %xmm8
	addps	%xmm13, %xmm2
	movaps	 8 * SIZE(BO), %xmm13
	addps	%xmm8, %xmm3
	movaps	16 * SIZE(AO), %xmm8
	mulps	%xmm10, %xmm9
	addps	%xmm9, %xmm4
	movaps	32 * SIZE(BO), %xmm9
	mulps	%xmm10, %xmm11
	addps	%xmm11, %xmm5
	movaps	20 * SIZE(BO), %xmm11
	mulps	%xmm10, %xmm13
	mulps	12 * SIZE(BO), %xmm10
	addps	%xmm13, %xmm6
	movaps	24 * SIZE(BO), %xmm13
	addps	%xmm10, %xmm7
	movaps	20 * SIZE(AO), %xmm10
	mulps	%xmm12, %xmm15
	addps	%xmm15, %xmm0
	movaps	16 * SIZE(BO), %xmm15
	mulps	%xmm12, %xmm11
	addps	%xmm11, %xmm1
	movaps	20 * SIZE(BO), %xmm11
	mulps	%xmm12, %xmm13
	mulps	28 * SIZE(BO), %xmm12
	addps	%xmm13, %xmm2
	movaps	24 * SIZE(BO), %xmm13
	addps	%xmm12, %xmm3
	movaps	24 * SIZE(AO), %xmm12
	mulps	%xmm14, %xmm15
	addps	%xmm15, %xmm4
	movaps	48 * SIZE(BO), %xmm15
	mulps	%xmm14, %xmm11
	addps	%xmm11, %xmm5
	movaps	36 * SIZE(BO), %xmm11
	mulps	%xmm14, %xmm13
	mulps	28 * SIZE(BO), %xmm14
	addps	%xmm13, %xmm6
	movaps	40 * SIZE(BO), %xmm13
	addps	%xmm14, %xmm7
	movaps	28 * SIZE(AO), %xmm14
	mulps	%xmm8, %xmm9
	addps	%xmm9, %xmm0
	movaps	32 * SIZE(BO), %xmm9
	mulps	%xmm8, %xmm11
	addps	%xmm11, %xmm1
	movaps	36 * SIZE(BO), %xmm11
	mulps	%xmm8, %xmm13
	mulps	44 * SIZE(BO), %xmm8
	addps	%xmm13, %xmm2
	movaps	40 * SIZE(BO), %xmm13
	addps	%xmm8, %xmm3
	movaps	32 * SIZE(AO), %xmm8
	mulps	%xmm10, %xmm9
	addps	%xmm9, %xmm4
	movaps	64 * SIZE(BO), %xmm9
	mulps	%xmm10, %xmm11
	addps	%xmm11, %xmm5
	movaps	52 * SIZE(BO), %xmm11
	mulps	%xmm10, %xmm13
	mulps	44 * SIZE(BO), %xmm10
	addps	%xmm13, %xmm6
	movaps	56 * SIZE(BO), %xmm13
	addps	%xmm10, %xmm7
	movaps	36 * SIZE(AO), %xmm10
	mulps	%xmm12, %xmm15
	addps	%xmm15, %xmm0
	movaps	48 * SIZE(BO), %xmm15
	mulps	%xmm12, %xmm11
	addps	%xmm11, %xmm1
	movaps	52 * SIZE(BO), %xmm11
	mulps	%xmm12, %xmm13
	mulps	60 * SIZE(BO), %xmm12
	addps	%xmm13, %xmm2
	movaps	56 * SIZE(BO), %xmm13
	addps	%xmm12, %xmm3
	movaps	40 * SIZE(AO), %xmm12
	mulps	%xmm14, %xmm15
	addps	%xmm15, %xmm4
	movaps	80 * SIZE(BO), %xmm15
	mulps	%xmm14, %xmm11
	addps	%xmm11, %xmm5
	movaps	68 * SIZE(BO), %xmm11
	mulps	%xmm14, %xmm13
	mulps	60 * SIZE(BO), %xmm14
	addps	%xmm13, %xmm6
	movaps	72 * SIZE(BO), %xmm13
	addps	%xmm14, %xmm7
	movaps	44 * SIZE(AO), %xmm14

	addq	$32 * SIZE, AO
	addq	$64 * SIZE, BO
	decq	%rax
	jg	.L12
	ALIGN_4

.L15:
#if defined(LT) || defined(RN)
	movq	KK, %rax
#else
	movq	K, %rax
	subq	KK, %rax
#endif
	andq	$3, %rax		# if (k & 1)
	BRANCH
	je .L18
	ALIGN_4
.L16:
	mulps	%xmm8, %xmm9
	addps	%xmm9, %xmm0
	movaps	 4 * SIZE(BO), %xmm9
	mulps	%xmm8, %xmm9
	addps	%xmm9, %xmm1
	movaps	 8 * SIZE(BO), %xmm9
	mulps	%xmm8, %xmm9
	mulps	12 * SIZE(BO), %xmm8
	addps	%xmm9, %xmm2
	movaps	 0 * SIZE(BO), %xmm9
	addps	%xmm8, %xmm3
	movaps	 8 * SIZE(AO), %xmm8
	mulps	%xmm10, %xmm9
	addps	%xmm9, %xmm4
	movaps	 4 * SIZE(BO), %xmm9
	mulps	%xmm10, %xmm9
	addps	%xmm9, %xmm5
	movaps	 8 * SIZE(BO), %xmm9
	mulps	%xmm10, %xmm9
	mulps	12 * SIZE(BO), %xmm10
	addps	%xmm9, %xmm6
	movaps	16 * SIZE(BO), %xmm9
	addps	%xmm10, %xmm7
	movaps	12 * SIZE(AO), %xmm10

	addq	$8  * SIZE, AO
	addq	$16 * SIZE, BO
	decq	%rax
	jg	.L16
	ALIGN_4

.L18:
#if defined(LN) || defined(RT)
	movq	KK, %rax
#ifdef LN
	subq	$8, %rax
#else
	subq	$4, %rax
#endif

	movq	AORIG, AO
	movq	BORIG, B
	leaq	BUFFER, BO

	salq	$2 + BASE_SHIFT, %rax
	leaq	(AO, %rax, 2), AO
	leaq	(B,  %rax, 1), B
	leaq	(BO, %rax, 4), BO
#endif

#if defined(LN) || defined(LT)
	movaps	 %xmm0,  %xmm8
	unpcklps %xmm2,  %xmm0
	unpckhps %xmm2,  %xmm8

	movaps	 %xmm1,  %xmm14
	unpcklps %xmm3,  %xmm1
	unpckhps %xmm3,  %xmm14

	movaps	 %xmm0,  %xmm2
	unpcklps %xmm1,  %xmm0
	unpckhps %xmm1,  %xmm2

	movaps	 %xmm8,  %xmm3
	unpcklps %xmm14, %xmm8
	unpckhps %xmm14, %xmm3

	movaps	 %xmm4,  %xmm9
	unpcklps %xmm6,  %xmm4
	unpckhps %xmm6,  %xmm9

	movaps	 %xmm5,  %xmm14
	unpcklps %xmm7,  %xmm5
	unpckhps %xmm7,  %xmm14

	movaps	 %xmm4,  %xmm6
	unpcklps %xmm5,  %xmm4
	unpckhps %xmm5,  %xmm6

	movaps	 %xmm9,  %xmm7
	unpcklps %xmm14, %xmm9
	unpckhps %xmm14, %xmm7

	movaps	 0 * SIZE(B), %xmm1
	movaps	 4 * SIZE(B), %xmm5
	movaps	 8 * SIZE(B), %xmm10
	movaps	12 * SIZE(B), %xmm11
	movaps	16 * SIZE(B), %xmm12
	movaps	20 * SIZE(B), %xmm13
	movaps	24 * SIZE(B), %xmm14
	movaps	28 * SIZE(B), %xmm15

	subps	%xmm0,  %xmm1
	subps	%xmm2,  %xmm5
	subps	%xmm8,  %xmm10
	subps	%xmm3,  %xmm11
	subps	%xmm4,  %xmm12
	subps	%xmm6,  %xmm13
	subps	%xmm9,  %xmm14
	subps	%xmm7,  %xmm15
#else
	movaps	 0 * SIZE(AO), %xmm8
	movaps	 4 * SIZE(AO), %xmm9
	movaps	 8 * SIZE(AO), %xmm10
	movaps	12 * SIZE(AO), %xmm11

	movaps	16 * SIZE(AO), %xmm12
	movaps	20 * SIZE(AO), %xmm13
	movaps	24 * SIZE(AO), %xmm14
	movaps	28 * SIZE(AO), %xmm15

	subps	%xmm0, %xmm8
	subps	%xmm4, %xmm9
	subps	%xmm1, %xmm10
	subps	%xmm5, %xmm11
	subps	%xmm2, %xmm12
	subps	%xmm6, %xmm13
	subps	%xmm3, %xmm14
	subps	%xmm7, %xmm15
#endif

#ifdef LN
	movaps	 60 * SIZE(AO), %xmm6
	pshufd	 $0xff, %xmm6, %xmm8
	mulps	 %xmm8, %xmm15
	pshufd	 $0xaa, %xmm6, %xmm8
	mulps	 %xmm15, %xmm8
	subps	 %xmm8, %xmm14
	pshufd	 $0x55, %xmm6, %xmm8
	mulps	 %xmm15, %xmm8
	subps	 %xmm8, %xmm13
	pshufd	 $0x00, %xmm6, %xmm8
	mulps	 %xmm15, %xmm8
	subps	 %xmm8, %xmm12

	movaps	 56 * SIZE(AO), %xmm6
	pshufd	 $0xff, %xmm6, %xmm8
	mulps	 %xmm15, %xmm8
	subps	 %xmm8, %xmm11
	pshufd	 $0xaa, %xmm6, %xmm8
	mulps	 %xmm15, %xmm8
	subps	 %xmm8, %xmm10
	pshufd	 $0x55, %xmm6, %xmm8
	mulps	 %xmm15, %xmm8
	subps	 %xmm8, %xmm5
	pshufd	 $0x00, %xmm6, %xmm8
	mulps	 %xmm15, %xmm8
	subps	 %xmm8, %xmm1

	movaps	 52 * SIZE(AO), %xmm6
	pshufd	 $0xaa, %xmm6, %xmm8