trsm_kernel_lt_8x2_sse.s

Optimized GotoBLAS libraries

/*********************************************************************/
/*                                                                   */
/*             Optimized BLAS libraries                              */
/*                     By Kazushige Goto <[e-mail]>     */
/*                                                                   */
/* Copyright (c) The University of Texas, 2005. All rights reserved. */
/* UNIVERSITY EXPRESSLY DISCLAIMS ANY AND ALL WARRANTIES CONCERNING  */
/* THIS SOFTWARE AND DOCUMENTATION, INCLUDING ANY WARRANTIES OF      */
/* MERCHANTABILITY, FITNESS FOR ANY PARTICULAR PURPOSE,              */
/* NON-INFRINGEMENT AND WARRANTIES OF PERFORMANCE, AND ANY WARRANTY  */
/* THAT MIGHT OTHERWISE ARISE FROM COURSE OF DEALING OR USAGE OF     */
/* TRADE. NO WARRANTY IS EITHER EXPRESS OR IMPLIED WITH RESPECT TO   */
/* THE USE OF THE SOFTWARE OR DOCUMENTATION.                         */
/* Under no circumstances shall University be liable for incidental, */
/* special, indirect, direct or consequential damages or loss of     */
/* profits, interruption of business, or related expenses which may  */
/* arise from use of Software or Documentation, including but not    */
/* limited to those resulting from defects in Software and/or        */
/* Documentation, or loss or inaccuracy of data of any kind.         */
/*********************************************************************/

#define ASSEMBLER
#include "common.h"

#if !defined(HAVE_SSE) || !defined(HAVE_MMX)
#error  You have to check your configuration.
#endif

#define STACK	16
#define ARGS	 0
	
#define STACK_M	 4 + STACK + ARGS(%esi)
#define STACK_N	 8 + STACK + ARGS(%esi)
#define STACK_K	12 + STACK + ARGS(%esi)
#define STACK_A	20 + STACK + ARGS(%esi)
#define STACK_B	24 + STACK + ARGS(%esi)
#define STACK_C	28 + STACK + ARGS(%esi)
#define STACK_LDC	32 + STACK + ARGS(%esi)
#define STACK_OFFT	36 + STACK + ARGS(%esi)

#define MASK	 0(%esp)
#define K	16(%esp)
#define N	20(%esp)
#define M	24(%esp)
#define A	28(%esp)
#define C	32(%esp)
#define J	36(%esp)
#define OLD_STACK 40(%esp)
#define OFFSET  44(%esp)
#define KK	48(%esp)
#define KKK	52(%esp)
#define AORIG	56(%esp)
#define BORIG	60(%esp)
#define BUFFER 128(%esp)

#if defined(OPTERON) || defined(BARCELONA)
#define PREFETCH     prefetch
#define PREFETCHW    prefetchw
#define PREFETCHSIZE (16 * 10 + 8)
#endif

#ifdef PENTIUM4
#define PREFETCH     prefetcht0
#define PREFETCHW    prefetcht0
#define PREFETCHSIZE   96
#endif

#define B	%edi
#define AA	%edx
#define	BB	%ecx
#define LDC	%ebp
#define CO1	%esi

#define STACK_ALIGN	4096
#define STACK_OFFSET	1024

#define LOCAL_BUFFER_SIZE  GEMM_Q * GEMM_UNROLL_N * COMPSIZE * 16

	PROLOGUE

	pushl	%ebp
	pushl	%edi
	pushl	%esi
	pushl	%ebx

	PROFCODE

	movl	%esp, %esi	# save old stack

	subl	$128 + LOCAL_BUFFER_SIZE, %esp
	andl	$-STACK_ALIGN, %esp

	movss	STACK_M, %xmm0
	movl	STACK_N, %eax
	movss	STACK_K, %xmm1
	movss	STACK_A, %xmm2
	movl	STACK_B, B
	movss	STACK_C, %xmm3
	movl	STACK_LDC, LDC
	movss	STACK_OFFT, %xmm4

	movss	%xmm1, K
	movl	%eax,  N
	movss	%xmm0, M
	movss	%xmm2, A
	movss	%xmm3, C
	movl	%esi,  OLD_STACK
	movss	%xmm4, OFFSET
	movss	%xmm4, KK

	leal	(, LDC, SIZE), LDC

#ifdef LN
       movl	M, %eax
       leal	(, %eax, SIZE), %eax
       addl	%eax, C
       imull	K, %eax
       addl	%eax, A
#endif

#ifdef RT
       movl	N, %eax
       leal	(, %eax, SIZE), %eax
       imull	K, %eax
       addl	%eax, B
       movl	N, %eax
       imull	LDC, %eax
       addl	%eax, C
#endif

#ifdef RN
	negl	KK
#endif	

#ifdef RT
       movl	N, %eax
       subl	OFFSET, %eax
       movl	%eax, KK
#endif

#if defined(LN) || defined(LT)
	movl	  $0x3f800000,   0 + MASK	#  1.0
	movl	  $0x00000000,   4 + MASK	#  0.0
	movl	  $0x3f800000,   8 + MASK	#  1.0
	movl	  $0x00000000,  12 + MASK	#  0.0
#endif

	movl	N,  %eax
	sarl	$1, %eax	# j = (n >> 1)
	movl	%eax, J
	jle	.L100
	ALIGN_2
	
.L01:
#ifdef LN
	movl	OFFSET, %eax
	addl	M, %eax
	movl	%eax, KK
#endif	

	leal	BUFFER, BB

#ifdef RT
       movl	K, %eax
       sall	$1 + BASE_SHIFT, %eax
       subl	%eax, B
#endif

#if defined(LN) || defined(RT)
	movl	KK, %eax
	movl	B, BORIG
        sall	$1 + BASE_SHIFT, %eax
	leal	(B,  %eax, 1), B
	leal	(BB, %eax, 4), BB
#endif	

#ifdef LT
	movl	OFFSET, %eax
	movl	%eax, KK
#endif

#if defined(LT) || defined(RN)
	movl	KK, %eax
#else
	movl	K,  %eax
	subl	KK, %eax
#endif
	sarl	$2, %eax
	jle	.L03
	ALIGN_4
	
.L02:
	movaps	 0 * SIZE(B), %xmm3
	movaps	 4 * SIZE(B), %xmm7

	pshufd	 $0x00, %xmm3, %xmm0
	pshufd	 $0x55, %xmm3, %xmm1
	pshufd	 $0xaa, %xmm3, %xmm2
	pshufd	 $0xff, %xmm3, %xmm3

	pshufd	 $0x00, %xmm7, %xmm4
	pshufd	 $0x55, %xmm7, %xmm5
	pshufd	 $0xaa, %xmm7, %xmm6
	pshufd	 $0xff, %xmm7, %xmm7

	movaps	%xmm0,  0 * SIZE(BB)
	movaps	%xmm1,  4 * SIZE(BB)
	movaps	%xmm2,  8 * SIZE(BB)
	movaps	%xmm3, 12 * SIZE(BB)
	movaps	%xmm4, 16 * SIZE(BB)
	movaps	%xmm5, 20 * SIZE(BB)
	movaps	%xmm6, 24 * SIZE(BB)
	movaps	%xmm7, 28 * SIZE(BB)

	addl	$ 8 * SIZE, B
	addl	$32 * SIZE, BB
	decl	%eax
	BRANCH
	jne	.L02
	ALIGN_2

.L03:
#if defined(LT) || defined(RN)
	movl	KK, %eax
#else
	movl	K, %eax
	subl	KK, %eax
#endif
	andl	$3, %eax
	BRANCH
	jle	.L05
	ALIGN_2

.L04:
	movlps	 0 * SIZE(B), %xmm3

	pshufd	 $0x00, %xmm3, %xmm0
	pshufd	 $0x55, %xmm3, %xmm1

	movaps	%xmm0,  0 * SIZE(BB)
	movaps	%xmm1,  4 * SIZE(BB)

	addl	$2 * SIZE, B
	addl	$8 * SIZE, BB

	decl	%eax
	jne	.L04
	ALIGN_4

.L05:
#if defined(LT) || defined(RN)
	movl	A, AA
#else
	movl	A, %eax
	movl	%eax, AORIG
#endif

	leal	(, LDC, 2), %eax

#ifdef RT
	subl	%eax, C
#endif
	movl	C, CO1
#ifndef RT
	addl	%eax, C
#endif

	movl	M,  %ebx
	sarl	$3, %ebx
	jle	.L30
	ALIGN_4

.L10:
#ifdef LN
       movl	K, %eax
       sall	$3 + BASE_SHIFT, %eax
       subl	%eax, AORIG
#endif

#if defined(LN) || defined(RT)
	movl	KK, %eax
	movl	AORIG, AA
	sall	$3 + BASE_SHIFT, %eax
	addl	%eax, AA
#endif

	leal	BUFFER, BB

#if defined(LN) || defined(RT)
	movl	KK, %eax
	sall	$1 + BASE_SHIFT, %eax
	leal	(BB, %eax, 4), BB
#endif	

	movaps	 0 * SIZE(BB), %xmm2
	xorps	%xmm4, %xmm4
	movaps	 0 * SIZE(AA), %xmm0
	xorps	%xmm5, %xmm5
	movaps	 8 * SIZE(BB), %xmm3
	xorps	%xmm6, %xmm6
	movaps	 8 * SIZE(AA), %xmm1
	xorps	%xmm7, %xmm7

	PREFETCHW      7 * SIZE(CO1)
	PREFETCHW      7 * SIZE(CO1, LDC)

#if defined(LT) || defined(RN)
	movl	KK, %eax
#else
	movl	K, %eax
	subl	KK, %eax
#endif
	sarl	$3, %eax
	je	.L12
	ALIGN_2

.L11:
	mulps	%xmm0, %xmm2
	mulps	 4 * SIZE(BB), %xmm0
	addps	%xmm2, %xmm4
	movaps	 0 * SIZE(BB), %xmm2

	addps	%xmm0, %xmm5
	movaps	 4 * SIZE(AA), %xmm0
	mulps	%xmm0, %xmm2
	mulps	 4 * SIZE(BB), %xmm0

	addps	%xmm2, %xmm6
	movaps	16 * SIZE(BB), %xmm2
	addps	%xmm0, %xmm7
	movaps	16 * SIZE(AA), %xmm0

	mulps	%xmm1, %xmm3
	mulps	12 * SIZE(BB), %xmm1
	addps	%xmm3, %xmm4
	movaps	 8 * SIZE(BB), %xmm3

	addps	%xmm1, %xmm5
	movaps	12 * SIZE(AA), %xmm1
	mulps	%xmm1, %xmm3
	mulps	12 * SIZE(BB), %xmm1

	addps	%xmm3, %xmm6
	movaps	24 * SIZE(BB), %xmm3
	addps	%xmm1, %xmm7
	movaps	24 * SIZE(AA), %xmm1

	mulps	%xmm0, %xmm2
	mulps	20 * SIZE(BB), %xmm0
	addps	%xmm2, %xmm4
	movaps	16 * SIZE(BB), %xmm2

	addps	%xmm0, %xmm5
	movaps	20 * SIZE(AA), %xmm0
	mulps	%xmm0, %xmm2
	mulps	20 * SIZE(BB), %xmm0

	addps	%xmm2, %xmm6
	movaps	32 * SIZE(BB), %xmm2
	addps	%xmm0, %xmm7
	movaps	32 * SIZE(AA), %xmm0

	mulps	%xmm1, %xmm3
	mulps	28 * SIZE(BB), %xmm1
	addps	%xmm3, %xmm4
	movaps	24 * SIZE(BB), %xmm3

	addps	%xmm1, %xmm5
	movaps	28 * SIZE(AA), %xmm1
	mulps	%xmm1, %xmm3
	mulps	28 * SIZE(BB), %xmm1

	addps	%xmm3, %xmm6
	movaps	40 * SIZE(BB), %xmm3
	addps	%xmm1, %xmm7
	movaps	40 * SIZE(AA), %xmm1

	mulps	%xmm0, %xmm2
	mulps	36 * SIZE(BB), %xmm0
	addps	%xmm2, %xmm4
	movaps	32 * SIZE(BB), %xmm2

	addps	%xmm0, %xmm5
	movaps	36 * SIZE(AA), %xmm0
	mulps	%xmm0, %xmm2
	mulps	36 * SIZE(BB), %xmm0

	addps	%xmm2, %xmm6
	movaps	48 * SIZE(BB), %xmm2
	addps	%xmm0, %xmm7
	movaps	48 * SIZE(AA), %xmm0

	mulps	%xmm1, %xmm3
	mulps	44 * SIZE(BB), %xmm1
	addps	%xmm3, %xmm4
	movaps	40 * SIZE(BB), %xmm3

	addps	%xmm1, %xmm5
	movaps	44 * SIZE(AA), %xmm1
	mulps	%xmm1, %xmm3
	mulps	44 * SIZE(BB), %xmm1

	addps	%xmm3, %xmm6
	movaps	56 * SIZE(BB), %xmm3
	addps	%xmm1, %xmm7
	movaps	56 * SIZE(AA), %xmm1

	mulps	%xmm0, %xmm2
	mulps	52 * SIZE(BB), %xmm0
	addps	%xmm2, %xmm4
	movaps	48 * SIZE(BB), %xmm2

	addps	%xmm0, %xmm5
	movaps	52 * SIZE(AA), %xmm0
	mulps	%xmm0, %xmm2
	mulps	52 * SIZE(BB), %xmm0

	addps	%xmm2, %xmm6
	movaps	64 * SIZE(BB), %xmm2
	addps	%xmm0, %xmm7
	movaps	64 * SIZE(AA), %xmm0

	mulps	%xmm1, %xmm3
	mulps	60 * SIZE(BB), %xmm1
	addps	%xmm3, %xmm4
	movaps	56 * SIZE(BB), %xmm3

	addps	%xmm1, %xmm5
	movaps	60 * SIZE(AA), %xmm1
	mulps	%xmm1, %xmm3
	mulps	60 * SIZE(BB), %xmm1

	addps	%xmm3, %xmm6
	movaps	72 * SIZE(BB), %xmm3
	addps	%xmm1, %xmm7
	movaps	72 * SIZE(AA), %xmm1

	addl   $64 * SIZE, BB
	addl   $64 * SIZE, AA
	decl   %eax
	jne    .L11
	ALIGN_2

.L12:
#if defined(LT) || defined(RN)
	movl	KK, %eax
#else
	movl	K, %eax
	subl	KK, %eax
#endif
	andl	$7, %eax		# if (k & 1)
	BRANCH
	je .L14

.L13:
	movaps	 4 * SIZE(BB), %xmm1
	mulps	%xmm0, %xmm2
	addps	%xmm2, %xmm4
	movaps	 0 * SIZE(BB), %xmm2
	mulps	%xmm0, %xmm1
	movaps	 4 * SIZE(AA), %xmm0
	addps	%xmm1, %xmm5
	movaps	 4 * SIZE(BB), %xmm1
	mulps	%xmm0, %xmm2
	addps	%xmm2, %xmm6
	movaps	 8 * SIZE(BB), %xmm2
	mulps	%xmm0, %xmm1
	movaps	 8 * SIZE(AA), %xmm0
	addps	%xmm1, %xmm7

	addl	$8 * SIZE, AA
	addl	$8 * SIZE, BB
	subl	$1, %eax
	jg	.L13
	ALIGN_4

.L14:
#if defined(LN) || defined(RT)
	movl	KK, %eax
#ifdef LN
	subl	$8, %eax
#else
	subl	$2, %eax
#endif

	movl	AORIG, AA
	movl	BORIG, B
	leal	BUFFER, BB

	sall	$BASE_SHIFT, %eax
	leal	(AA, %eax, 8), AA
	leal	(B,  %eax, 2), B
	leal	(BB, %eax, 8), BB
#endif

#if defined(LN) || defined(LT)
	movaps	 %xmm4, %xmm0
	unpcklps %xmm5, %xmm4
	unpckhps %xmm5, %xmm0

	movaps	 %xmm6, %xmm1
	unpcklps %xmm7, %xmm6
	unpckhps %xmm7, %xmm1

	movaps	 0 * SIZE(B), %xmm2
	movaps	 4 * SIZE(B), %xmm3
	movaps	 8 * SIZE(B), %xmm5
	movaps	12 * SIZE(B), %xmm7

	subps	%xmm4,  %xmm2
	subps	%xmm0,  %xmm3
	subps	%xmm6,  %xmm5
	subps	%xmm1,  %xmm7
#else
	movaps	 0 * SIZE(AA), %xmm0
	movaps	 4 * SIZE(AA), %xmm1
	movaps	 8 * SIZE(AA), %xmm2
	movaps	12 * SIZE(AA), %xmm3

	subps	%xmm4, %xmm0
	subps	%xmm6, %xmm1
	subps	%xmm5, %xmm2
	subps	%xmm7, %xmm3
#endif

#if defined(LN) || defined(LT)
	movaps	MASK, %xmm6
#endif

#ifdef LN
	movss	63 * SIZE(AA), %xmm0
	movaps	 %xmm6, %xmm1
	shufps	$0x00, %xmm0,  %xmm1
	mulps	%xmm1, %xmm7

	pshufd	$0xee, %xmm7, %xmm1

	movss	62 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm7

	movsd	60 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm5

	movsd	58 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm3

	movsd	56 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm2

	movss	54 * SIZE(AA), %xmm0
	shufps	$0x00, %xmm6,  %xmm0
	mulps	%xmm0, %xmm7

	pshufd	$0x44, %xmm7, %xmm1

	movsd	52 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm5

	movsd	50 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm3

	movsd	48 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm2


	movss	45 * SIZE(AA), %xmm0
	movaps	 %xmm6, %xmm1
	shufps	$0x00, %xmm0,  %xmm1
	mulps	%xmm1, %xmm5

	pshufd	$0xee, %xmm5, %xmm1

	movss	44 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm5

	movsd	42 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm3

	movsd	40 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm2

	movss	36 * SIZE(AA), %xmm0
	shufps	$0x00, %xmm6,  %xmm0
	mulps	%xmm0, %xmm5

	pshufd	$0x44, %xmm5, %xmm1

	movsd	34 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm3

	movsd	32 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm2

	movss	27 * SIZE(AA), %xmm0
	movaps	 %xmm6, %xmm1
	shufps	$0x00, %xmm0,  %xmm1
	mulps	%xmm1, %xmm3

	pshufd	$0xee, %xmm3, %xmm1

	movss	26 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm3

	movsd	24 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm2

	movss	18 * SIZE(AA), %xmm0
	shufps	$0x00, %xmm6,  %xmm0
	mulps	%xmm0, %xmm3

	pshufd	$0x44, %xmm3, %xmm1

	movsd	16 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm2

	movss	 9 * SIZE(AA), %xmm0
	movaps	 %xmm6, %xmm1
	shufps	$0x00, %xmm0,  %xmm1
	mulps	%xmm1, %xmm2

	pshufd	$0xee, %xmm2, %xmm1

	movss	 8 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm2

	movss	 0 * SIZE(AA), %xmm0
	shufps	$0x00, %xmm6,  %xmm0
	mulps	%xmm0, %xmm2

#endif

#ifdef LT
	movss	 0 * SIZE(AA), %xmm0
	shufps	$0x00, %xmm6,  %xmm0
	mulps	%xmm0, %xmm2

	pshufd	$0x44, %xmm2, %xmm1

	movss	 1 * SIZE(AA), %xmm0
	pshufd	$0x05, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm2

	movsd	 2 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm3

	movsd	 4 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm5

	movsd	 6 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm7

	movss	 9 * SIZE(AA), %xmm0
	movaps	 %xmm6, %xmm1
	shufps	$0x00, %xmm0,  %xmm1
	mulps	%xmm1, %xmm2

	pshufd	$0xee, %xmm2, %xmm1

	movsd	10 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm3

	movsd	12 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm5

	movsd	14 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm7

	movss	18 * SIZE(AA), %xmm0
	shufps	$0x00, %xmm6,  %xmm0
	mulps	%xmm0, %xmm3

	pshufd	$0x44, %xmm3, %xmm1

	movss	19 * SIZE(AA), %xmm0
	pshufd	$0x05, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm3

	movsd	20 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm5

	movsd	22 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm7

	movss	27 * SIZE(AA), %xmm0
	movaps	 %xmm6, %xmm1
	shufps	$0x00, %xmm0,  %xmm1
	mulps	%xmm1, %xmm3

	pshufd	$0xee, %xmm3, %xmm1

	movsd	28 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm5

	movsd	30 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm7

	movss	36 * SIZE(AA), %xmm0
	shufps	$0x00, %xmm6,  %xmm0
	mulps	%xmm0, %xmm5

	pshufd	$0x44, %xmm5, %xmm1

	movss	37 * SIZE(AA), %xmm0
	pshufd	$0x05, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm5

	movsd	38 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm7

	movss	45 * SIZE(AA), %xmm0
	movaps	 %xmm6, %xmm1
	shufps	$0x00, %xmm0,  %xmm1
	mulps	%xmm1, %xmm5

	pshufd	$0xee, %xmm5, %xmm1

	movsd	46 * SIZE(AA), %xmm0
	pshufd	$0x50, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm7

	movss	54 * SIZE(AA), %xmm0
	shufps	$0x00, %xmm6,  %xmm0
	mulps	%xmm0, %xmm7

	pshufd	$0x44, %xmm7, %xmm1

	movss	55 * SIZE(AA), %xmm0
	pshufd	$0x05, %xmm0, %xmm0
	mulps	%xmm1, %xmm0
	subps	%xmm0, %xmm7

	movss	63 * SIZE(AA), %xmm0
	movaps	 %xmm6, %xmm1
	shufps	$0x00, %xmm0,  %xmm1
	mulps	%xmm1, %xmm7
#endif

#ifdef RN
	movss	 0 * SIZE(B), %xmm6
	shufps	$0x00, %xmm6, %xmm6
	
	mulps	%xmm6, %xmm0
	mulps	%xmm6, %xmm1

	movss	 1 * SIZE(B), %xmm6
	shufps	$0x00, %xmm6, %xmm6
	movaps	%xmm6, %xmm5

	mulps	%xmm0, %xmm5
	mulps	%xmm1, %xmm6

	subps	%xmm5, %xmm2
	subps	%xmm6, %xmm3

	movss	 3 * SIZE(B), %xmm6
	shufps	$0x00, %xmm6, %xmm6
	
	mulps	%xmm6, %xmm2
	mulps	%xmm6, %xmm3
#endif

#ifdef RT
	movss	 3 * SIZE(B), %xmm6