gemv_n_sse2_opteron.s

Optimized GotoBLAS libraries

/*********************************************************************/
/*                                                                   */
/*             Optimized BLAS libraries                              */
/*                     By Kazushige Goto <[e-mail]>     */
/*                                                                   */
/* Copyright (c) The University of Texas, 2005. All rights reserved. */
/* UNIVERSITY EXPRESSLY DISCLAIMS ANY AND ALL WARRANTIES CONCERNING  */
/* THIS SOFTWARE AND DOCUMENTATION, INCLUDING ANY WARRANTIES OF      */
/* MERCHANTABILITY, FITNESS FOR ANY PARTICULAR PURPOSE,              */
/* NON-INFRINGEMENT AND WARRANTIES OF PERFORMANCE, AND ANY WARRANTY  */
/* THAT MIGHT OTHERWISE ARISE FROM COURSE OF DEALING OR USAGE OF     */
/* TRADE. NO WARRANTY IS EITHER EXPRESS OR IMPLIED WITH RESPECT TO   */
/* THE USE OF THE SOFTWARE OR DOCUMENTATION.                         */
/* Under no circumstances shall University be liable for incidental, */
/* special, indirect, direct or consequential damages or loss of     */
/* profits, interruption of business, or related expenses which may  */
/* arise from use of Software or Documentation, including but not    */
/* limited to those resulting from defects in Software and/or        */
/* Documentation, or loss or inaccuracy of data of any kind.         */
/*********************************************************************/

#define ASSEMBLER
#include "common.h"

#define PREFETCH	prefetch
#define PREFETCHW	prefetchw
#define PREFETCHSIZE	16

#ifndef WINDOWS_ABI

#define STACKSIZE	64
	
#define OLD_INCX	 8 + STACKSIZE(%rsp)
#define OLD_Y		16 + STACKSIZE(%rsp)
#define OLD_INCY	24 + STACKSIZE(%rsp)
#define BUFFER		32 + STACKSIZE(%rsp)
#define STACK_ALPHA	48	      (%rsp)

#define M	  %rdi
#define N	  %rsi
#define A	  %rcx
#define LDA	  %r8
#define X	  %r9
#define INCX	  %rdx
#define Y	  %rbp
#define INCY	  %r10

#else

#define STACKSIZE	256
	
#define OLD_A		 40 + STACKSIZE(%rsp)
#define OLD_LDA		 48 + STACKSIZE(%rsp)
#define OLD_X		 56 + STACKSIZE(%rsp)
#define OLD_INCX	 64 + STACKSIZE(%rsp)
#define OLD_Y		 72 + STACKSIZE(%rsp)
#define OLD_INCY	 80 + STACKSIZE(%rsp)
#define BUFFER		 88 + STACKSIZE(%rsp)

#define STACK_ALPHA	224	       (%rsp)

#define M	  %rcx
#define N	  %rdx
#define A	  %r8
#define LDA	  %r9
#define X	  %rdi
#define INCX	  %rsi
#define Y	  %rbp
#define INCY	  %r10

#endif

#define TEMP	%rax
#define I	%rax
#define J	%r11
#define A1	%r12
#define A2	%r13
#define Y1	%r14
#define YY	%r15

	PROLOGUE
	PROFCODE

	subq	$STACKSIZE, %rsp
	movq	%rbx,  0(%rsp)
	movq	%rbp,  8(%rsp)
	movq	%r12, 16(%rsp)
	movq	%r13, 24(%rsp)
	movq	%r14, 32(%rsp)
	movq	%r15, 40(%rsp)

#ifdef WINDOWS_ABI
	movq	%rdi,    48(%rsp)
	movq	%rsi,    56(%rsp)
	movups	%xmm6,   64(%rsp)
	movups	%xmm7,   80(%rsp)
	movups	%xmm8,   96(%rsp)
	movups	%xmm9,  112(%rsp)
	movups	%xmm10, 128(%rsp)
	movups	%xmm11, 144(%rsp)
	movups	%xmm12, 160(%rsp)
	movups	%xmm13, 176(%rsp)
	movups	%xmm14, 192(%rsp)
	movups	%xmm15, 208(%rsp)

	movq	OLD_A,     A
	movq	OLD_LDA,   LDA
	movq	OLD_X,     X
#endif

	movq	OLD_INCX,  INCX
	movq	OLD_Y,     Y
	movq	OLD_INCY,  INCY

#ifndef WINDOWS_ABI
	movsd	 %xmm0, STACK_ALPHA
#else
	movsd	 %xmm3, STACK_ALPHA
#endif

	leaq	(,INCX, SIZE), INCX
	leaq	(,INCY, SIZE), INCY
	leaq	(,LDA,  SIZE), LDA

	testq	N, N		# if n <= 0 goto END
	jle	.L999
	testq	M, M		# if n <= 0 goto END
	jle	.L999

	pxor	%xmm4, %xmm4
	movq	Y, YY
	cmpq	$SIZE, INCY
	je	.L10

	movq	BUFFER, YY
	movq	BUFFER, Y1
	movq	M,  %rax
	addq	$7, %rax
	sarq	$3, %rax
	ALIGN_3

.L01:
	movapd	%xmm4, 0 * SIZE(Y1)
	movapd	%xmm4, 2 * SIZE(Y1)
	movapd	%xmm4, 4 * SIZE(Y1)
	movapd	%xmm4, 6 * SIZE(Y1)
	addq	$8 * SIZE, Y1
	decq	%rax
	jg	.L01
	ALIGN_3
	
.L10:
	movq	N,  J
	sarq	$2, J
	jle	.L20
	ALIGN_3

.L11:
	movq	YY, Y1
	movq	A,  A1
	leaq	(A, LDA, 1), A2
	leaq	(A, LDA, 4), A

	movlpd	(X), %xmm0
	addq	INCX, X
	movlpd	(X), %xmm1
	addq	INCX, X
	movlpd	(X), %xmm2
	addq	INCX, X
	movlpd	(X), %xmm3
	addq	INCX, X

	mulsd	STACK_ALPHA, %xmm0
	mulsd	STACK_ALPHA, %xmm1
	mulsd	STACK_ALPHA, %xmm2
	mulsd	STACK_ALPHA, %xmm3

	unpcklpd %xmm0, %xmm0
	unpcklpd %xmm1, %xmm1
	unpcklpd %xmm2, %xmm2
	unpcklpd %xmm3, %xmm3

	movq	M,  I
	sarq	$4, I
	jle	.L14

	movlpd	 0 * SIZE(A1), %xmm8
	movhpd	 1 * SIZE(A1), %xmm8
	movlpd	 2 * SIZE(A1), %xmm9
	movhpd	 3 * SIZE(A1), %xmm9
	movlpd	 4 * SIZE(A1), %xmm10
	movhpd	 5 * SIZE(A1), %xmm10
	movlpd	 6 * SIZE(A1), %xmm11
	movhpd	 7 * SIZE(A1), %xmm11

	movlpd	 0 * SIZE(A2), %xmm12
	movhpd	 1 * SIZE(A2), %xmm12
	movlpd	 2 * SIZE(A2), %xmm13
	movhpd	 3 * SIZE(A2), %xmm13
	movlpd	 4 * SIZE(A2), %xmm14
	movhpd	 5 * SIZE(A2), %xmm14
	movlpd	 6 * SIZE(A2), %xmm15
	movhpd	 7 * SIZE(A2), %xmm15

	movlpd	 0 * SIZE(Y1), %xmm4
	movhpd	 1 * SIZE(Y1), %xmm4
	movlpd	 2 * SIZE(Y1), %xmm5
	movhpd	 3 * SIZE(Y1), %xmm5
	movlpd	 4 * SIZE(Y1), %xmm6
	movhpd	 5 * SIZE(Y1), %xmm6
	movlpd	 6 * SIZE(Y1), %xmm7
	movhpd	 7 * SIZE(Y1), %xmm7

	mulpd	 %xmm0, %xmm8
	mulpd	 %xmm0, %xmm9
	mulpd	 %xmm0, %xmm10
	mulpd	 %xmm0, %xmm11

	decq	 I
	jle	 .L13
	ALIGN_3

.L12:
	PREFETCH	PREFETCHSIZE * SIZE(A1)
	addpd	 %xmm8,  %xmm4
	movlpd	 0 * SIZE(A1, LDA, 2), %xmm8
	movhpd	 1 * SIZE(A1, LDA, 2), %xmm8
	mulpd	 %xmm1, %xmm12
	addpd	 %xmm9,  %xmm5
	movlpd	 2 * SIZE(A1, LDA, 2), %xmm9
	movhpd	 3 * SIZE(A1, LDA, 2), %xmm9
	mulpd	 %xmm1, %xmm13

	PREFETCHW	PREFETCHSIZE * SIZE(Y1)
	addpd	 %xmm10, %xmm6
	movlpd	 4 * SIZE(A1, LDA, 2), %xmm10
	movhpd	 5 * SIZE(A1, LDA, 2), %xmm10
	mulpd	 %xmm1, %xmm14
	addpd	 %xmm11, %xmm7
	movlpd	 6 * SIZE(A1, LDA, 2), %xmm11
	movhpd	 7 * SIZE(A1, LDA, 2), %xmm11
	mulpd	 %xmm1, %xmm15

	PREFETCH	PREFETCHSIZE * SIZE(A2)
	addpd	 %xmm12, %xmm4
	movlpd	 0 * SIZE(A2, LDA, 2), %xmm12
	movhpd	 1 * SIZE(A2, LDA, 2), %xmm12
	mulpd	 %xmm2, %xmm8
	addpd	 %xmm13, %xmm5
	movlpd	 2 * SIZE(A2, LDA, 2), %xmm13
	movhpd	 3 * SIZE(A2, LDA, 2), %xmm13
	mulpd	 %xmm2, %xmm9

	addpd	 %xmm14, %xmm6
	movlpd	 4 * SIZE(A2, LDA, 2), %xmm14
	movhpd	 5 * SIZE(A2, LDA, 2), %xmm14
	mulpd	 %xmm2, %xmm10
	addpd	 %xmm15, %xmm7
	movlpd	 6 * SIZE(A2, LDA, 2), %xmm15
	movhpd	 7 * SIZE(A2, LDA, 2), %xmm15
	mulpd	 %xmm2, %xmm11

	PREFETCH	PREFETCHSIZE * SIZE(A1, LDA, 2)
	addpd	 %xmm8,  %xmm4
	movlpd	 8 * SIZE(A1), %xmm8
	movhpd	 9 * SIZE(A1), %xmm8
	mulpd	 %xmm3, %xmm12
	addpd	 %xmm9,  %xmm5
	movlpd	10 * SIZE(A1), %xmm9
	movhpd	11 * SIZE(A1), %xmm9
	mulpd	 %xmm3, %xmm13

	addpd	 %xmm10, %xmm6
	movlpd	12 * SIZE(A1), %xmm10
	movhpd	13 * SIZE(A1), %xmm10
	mulpd	 %xmm3, %xmm14
	addpd	 %xmm11, %xmm7
	movlpd	14 * SIZE(A1), %xmm11
	movhpd	15 * SIZE(A1), %xmm11
	mulpd	 %xmm3, %xmm15

	PREFETCH	PREFETCHSIZE * SIZE(A2, LDA, 2)
	addpd	 %xmm12, %xmm4
	movlpd	 8 * SIZE(A2), %xmm12
	movhpd	 9 * SIZE(A2), %xmm12
	mulpd	 %xmm0, %xmm8
	addpd	 %xmm13, %xmm5
	movlpd	10 * SIZE(A2), %xmm13
	movhpd	11 * SIZE(A2), %xmm13
	mulpd	 %xmm0, %xmm9

	addpd	 %xmm14, %xmm6
	movlpd	12 * SIZE(A2), %xmm14
	movhpd	13 * SIZE(A2), %xmm14
	mulpd	 %xmm0, %xmm10
	addpd	 %xmm15, %xmm7
	movlpd	14 * SIZE(A2), %xmm15
	movhpd	15 * SIZE(A2), %xmm15
	mulpd	 %xmm0, %xmm11

	movlpd	 %xmm4, 0 * SIZE(Y1)
	movlpd	 8 * SIZE(Y1), %xmm4
	movhpd	 %xmm4, 1 * SIZE(Y1)
	movhpd	 9 * SIZE(Y1), %xmm4
	movlpd	 %xmm5, 2 * SIZE(Y1)
	movlpd	10 * SIZE(Y1), %xmm5
	movhpd	 %xmm5, 3 * SIZE(Y1)
	movhpd	11 * SIZE(Y1), %xmm5

	movlpd	 %xmm6, 4 * SIZE(Y1)
	movlpd	12 * SIZE(Y1), %xmm6
	movhpd	 %xmm6, 5 * SIZE(Y1)
 	movhpd	13 * SIZE(Y1), %xmm6
	movlpd	 %xmm7, 6 * SIZE(Y1)
	movlpd	14 * SIZE(Y1), %xmm7
	movhpd	 %xmm7, 7 * SIZE(Y1)
	movhpd	15 * SIZE(Y1), %xmm7

	PREFETCH	(PREFETCHSIZE + 8) * SIZE(A1)
	addpd	 %xmm8,  %xmm4
	movlpd	 8 * SIZE(A1, LDA, 2), %xmm8
	movhpd	 9 * SIZE(A1, LDA, 2), %xmm8
	mulpd	 %xmm1, %xmm12
	addpd	 %xmm9,  %xmm5
	movlpd	10 * SIZE(A1, LDA, 2), %xmm9
	movhpd	11 * SIZE(A1, LDA, 2), %xmm9
	mulpd	 %xmm1, %xmm13

	PREFETCHW	(PREFETCHSIZE + 8) * SIZE(Y1)
	addpd	 %xmm10, %xmm6
	movlpd	12 * SIZE(A1, LDA, 2), %xmm10
	movhpd	13 * SIZE(A1, LDA, 2), %xmm10
	mulpd	 %xmm1, %xmm14
	addpd	 %xmm11, %xmm7
	movlpd	14 * SIZE(A1, LDA, 2), %xmm11
	movhpd	15 * SIZE(A1, LDA, 2), %xmm11
	mulpd	 %xmm1, %xmm15

	PREFETCH	(PREFETCHSIZE + 8) * SIZE(A2)
	addpd	 %xmm12, %xmm4
	movlpd	 8 * SIZE(A2, LDA, 2), %xmm12
	movhpd	 9 * SIZE(A2, LDA, 2), %xmm12
	mulpd	 %xmm2, %xmm8
	addpd	 %xmm13, %xmm5
	movlpd	10 * SIZE(A2, LDA, 2), %xmm13
	movhpd	11 * SIZE(A2, LDA, 2), %xmm13
	mulpd	 %xmm2, %xmm9

	addpd	 %xmm14, %xmm6
	movlpd	12 * SIZE(A2, LDA, 2), %xmm14
	movhpd	13 * SIZE(A2, LDA, 2), %xmm14
	mulpd	 %xmm2, %xmm10
	addpd	 %xmm15, %xmm7
	movlpd	14 * SIZE(A2, LDA, 2), %xmm15
	movhpd	15 * SIZE(A2, LDA, 2), %xmm15
	mulpd	 %xmm2, %xmm11

	PREFETCH	(PREFETCHSIZE + 8) * SIZE(A1, LDA, 2)
	addpd	 %xmm8,  %xmm4
	movlpd	16 * SIZE(A1), %xmm8
	movhpd	17 * SIZE(A1), %xmm8
	mulpd	 %xmm3, %xmm12
	addpd	 %xmm9,  %xmm5
	movlpd	18 * SIZE(A1), %xmm9
	movhpd	19 * SIZE(A1), %xmm9
	mulpd	 %xmm3, %xmm13

	addpd	 %xmm10, %xmm6
	movlpd	20 * SIZE(A1), %xmm10
	movhpd	21 * SIZE(A1), %xmm10
	mulpd	 %xmm3, %xmm14
	addpd	 %xmm11, %xmm7
	movlpd	22 * SIZE(A1), %xmm11
	movhpd	23 * SIZE(A1), %xmm11
	mulpd	 %xmm3, %xmm15

	PREFETCH	(PREFETCHSIZE + 8) * SIZE(A2, LDA, 2)
	addpd	 %xmm12, %xmm4
	movlpd	16 * SIZE(A2), %xmm12
	movhpd	17 * SIZE(A2), %xmm12
	mulpd	 %xmm0, %xmm8
	addpd	 %xmm13, %xmm5
	movlpd	18 * SIZE(A2), %xmm13
	movhpd	19 * SIZE(A2), %xmm13
	mulpd	 %xmm0, %xmm9

	addpd	 %xmm14, %xmm6
	movlpd	20 * SIZE(A2), %xmm14
	movhpd	21 * SIZE(A2), %xmm14
	mulpd	 %xmm0, %xmm10
	addpd	 %xmm15, %xmm7
	movlpd	22 * SIZE(A2), %xmm15
	movhpd	23 * SIZE(A2), %xmm15
	mulpd	 %xmm0, %xmm11

	movlpd	 %xmm4,  8 * SIZE(Y1)
	movlpd	16 * SIZE(Y1), %xmm4
	movhpd	 %xmm4,  9 * SIZE(Y1)
	movhpd	17 * SIZE(Y1), %xmm4
	movlpd	 %xmm5, 10 * SIZE(Y1)
	movlpd	18 * SIZE(Y1), %xmm5
	movhpd	 %xmm5, 11 * SIZE(Y1)
	movhpd	19 * SIZE(Y1), %xmm5
	movlpd	 %xmm6, 12 * SIZE(Y1)

	movlpd	20 * SIZE(Y1), %xmm6
	movhpd	 %xmm6, 13 * SIZE(Y1)
	movhpd	21 * SIZE(Y1), %xmm6
	movlpd	 %xmm7, 14 * SIZE(Y1)
	movlpd	22 * SIZE(Y1), %xmm7
	movhpd	 %xmm7, 15 * SIZE(Y1)
	movhpd	23 * SIZE(Y1), %xmm7

	subq	$-16 * SIZE, A1
	subq	$-16 * SIZE, A2
	subq	$-16 * SIZE, Y1
	decq	 I
	jg	.L12
	ALIGN_3

.L13:
	addpd	 %xmm8,  %xmm4
	movlpd	 0 * SIZE(A1, LDA, 2), %xmm8
	movhpd	 1 * SIZE(A1, LDA, 2), %xmm8
	mulpd	 %xmm1, %xmm12
	addpd	 %xmm9,  %xmm5
	movlpd	 2 * SIZE(A1, LDA, 2), %xmm9
	movhpd	 3 * SIZE(A1, LDA, 2), %xmm9
	mulpd	 %xmm1, %xmm13

	addpd	 %xmm10, %xmm6
	movlpd	 4 * SIZE(A1, LDA, 2), %xmm10
	movhpd	 5 * SIZE(A1, LDA, 2), %xmm10
	mulpd	 %xmm1, %xmm14
	addpd	 %xmm11, %xmm7
	movlpd	 6 * SIZE(A1, LDA, 2), %xmm11
	movhpd	 7 * SIZE(A1, LDA, 2), %xmm11
	mulpd	 %xmm1, %xmm15

	addpd	 %xmm12, %xmm4
	movlpd	 0 * SIZE(A2, LDA, 2), %xmm12
	movhpd	 1 * SIZE(A2, LDA, 2), %xmm12
	mulpd	 %xmm2, %xmm8
	addpd	 %xmm13, %xmm5
	movlpd	 2 * SIZE(A2, LDA, 2), %xmm13
	movhpd	 3 * SIZE(A2, LDA, 2), %xmm13
	mulpd	 %xmm2, %xmm9

	addpd	 %xmm14, %xmm6
	movlpd	 4 * SIZE(A2, LDA, 2), %xmm14
	movhpd	 5 * SIZE(A2, LDA, 2), %xmm14
	mulpd	 %xmm2, %xmm10
	addpd	 %xmm15, %xmm7
	movlpd	 6 * SIZE(A2, LDA, 2), %xmm15
	movhpd	 7 * SIZE(A2, LDA, 2), %xmm15
	mulpd	 %xmm2, %xmm11

	addpd	 %xmm8,  %xmm4
	movlpd	 8 * SIZE(A1), %xmm8
	movhpd	 9 * SIZE(A1), %xmm8
	mulpd	 %xmm3, %xmm12
	addpd	 %xmm9,  %xmm5
	movlpd	10 * SIZE(A1), %xmm9
	movhpd	11 * SIZE(A1), %xmm9
	mulpd	 %xmm3, %xmm13

	addpd	 %xmm10, %xmm6
	movlpd	12 * SIZE(A1), %xmm10
	movhpd	13 * SIZE(A1), %xmm10
	mulpd	 %xmm3, %xmm14
	addpd	 %xmm11, %xmm7
	movlpd	14 * SIZE(A1), %xmm11
	movhpd	15 * SIZE(A1), %xmm11
	mulpd	 %xmm3, %xmm15

	addpd	 %xmm12, %xmm4
	movlpd	 8 * SIZE(A2), %xmm12
	movhpd	 9 * SIZE(A2), %xmm12
	mulpd	 %xmm0, %xmm8
	addpd	 %xmm13, %xmm5
	movlpd	10 * SIZE(A2), %xmm13
	movhpd	11 * SIZE(A2), %xmm13
	mulpd	 %xmm0, %xmm9

	addpd	 %xmm14, %xmm6
	movlpd	12 * SIZE(A2), %xmm14
	movhpd	13 * SIZE(A2), %xmm14
	mulpd	 %xmm0, %xmm10
	addpd	 %xmm15, %xmm7
	movlpd	14 * SIZE(A2), %xmm15
	movhpd	15 * SIZE(A2), %xmm15
	mulpd	 %xmm0, %xmm11

	movlpd	 %xmm4, 0 * SIZE(Y1)
	movlpd	 8 * SIZE(Y1), %xmm4
	movhpd	 %xmm4, 1 * SIZE(Y1)
	movhpd	 9 * SIZE(Y1), %xmm4
	movlpd	 %xmm5, 2 * SIZE(Y1)
	movlpd	10 * SIZE(Y1), %xmm5
	movhpd	 %xmm5, 3 * SIZE(Y1)
	movhpd	11 * SIZE(Y1), %xmm5

	movlpd	 %xmm6, 4 * SIZE(Y1)
	movlpd	12 * SIZE(Y1), %xmm6
	movhpd	 %xmm6, 5 * SIZE(Y1)
 	movhpd	13 * SIZE(Y1), %xmm6
	movlpd	 %xmm7, 6 * SIZE(Y1)
	movlpd	14 * SIZE(Y1), %xmm7
	movhpd	 %xmm7, 7 * SIZE(Y1)
	movhpd	15 * SIZE(Y1), %xmm7

	addpd	 %xmm8,  %xmm4
	movlpd	 8 * SIZE(A1, LDA, 2), %xmm8
	movhpd	 9 * SIZE(A1, LDA, 2), %xmm8
	mulpd	 %xmm1, %xmm12
	addpd	 %xmm9,  %xmm5
	movlpd	10 * SIZE(A1, LDA, 2), %xmm9
	movhpd	11 * SIZE(A1, LDA, 2), %xmm9
	mulpd	 %xmm1, %xmm13

	addpd	 %xmm10, %xmm6
	movlpd	12 * SIZE(A1, LDA, 2), %xmm10
	movhpd	13 * SIZE(A1, LDA, 2), %xmm10
	mulpd	 %xmm1, %xmm14
	addpd	 %xmm11, %xmm7
	movlpd	14 * SIZE(A1, LDA, 2), %xmm11
	movhpd	15 * SIZE(A1, LDA, 2), %xmm11
	mulpd	 %xmm1, %xmm15