zgemv_n_sse2.s

Optimized GotoBLAS libraries

/*********************************************************************/
/*                                                                   */
/*             Optimized BLAS libraries                              */
/*                     By Kazushige Goto <[e-mail]>     */
/*                                                                   */
/* Copyright (c) The University of Texas, 2005. All rights reserved. */
/* UNIVERSITY EXPRESSLY DISCLAIMS ANY AND ALL WARRANTIES CONCERNING  */
/* THIS SOFTWARE AND DOCUMENTATION, INCLUDING ANY WARRANTIES OF      */
/* MERCHANTABILITY, FITNESS FOR ANY PARTICULAR PURPOSE,              */
/* NON-INFRINGEMENT AND WARRANTIES OF PERFORMANCE, AND ANY WARRANTY  */
/* THAT MIGHT OTHERWISE ARISE FROM COURSE OF DEALING OR USAGE OF     */
/* TRADE. NO WARRANTY IS EITHER EXPRESS OR IMPLIED WITH RESPECT TO   */
/* THE USE OF THE SOFTWARE OR DOCUMENTATION.                         */
/* Under no circumstances shall University be liable for incidental, */
/* special, indirect, direct or consequential damages or loss of     */
/* profits, interruption of business, or related expenses which may  */
/* arise from use of Software or Documentation, including but not    */
/* limited to those resulting from defects in Software and/or        */
/* Documentation, or loss or inaccuracy of data of any kind.         */
/*********************************************************************/

#define ASSEMBLER
#include "common.h"

#ifdef PARAMTEST
#define P	  60(%esp)
#endif

#ifdef PENTIUM4
#ifndef PARAMTEST
#define P 32
#endif
#define PREFETCHSIZE 24
#endif

#ifdef CORE2
#ifndef PARAMTEST
#define P 32
#endif
#define PREFETCHSIZE 24
#endif

#ifdef PENRYN
#ifndef PARAMTEST
#define P 32
#endif
#define PREFETCHSIZE 24
#endif

#if defined(OPTERON) || defined(BARCELONA)
#ifndef PARAMTEST
#define P 24
#endif
#define movsd	movlpd
#define PREFETCHSIZE 32
#endif

#ifndef P
#error  P is undefined!!
#endif

#define KERNELMACRO(address) \
	movsd	  0 * SIZE(%ecx), %xmm0; \
	movhpd	  1 * SIZE(%ecx), %xmm0; \
	mulpd	%xmm0, %xmm1; \
	movsd	  2 * SIZE(%ecx), %xmm2; \
	movhpd	  3 * SIZE(%ecx), %xmm2; \
	prefetcht2	PREFETCHSIZE * SIZE(%ecx); \
	addpd	%xmm1, %xmm4; \
	movapd	  0 * SIZE + address * SIZE(%edx), %xmm3; \
	addl	%ebx, %ecx; \
	mulpd	  2 * SIZE + address * SIZE(%edx), %xmm0; \
	addpd	%xmm0, %xmm5; \
	mulpd	%xmm2, %xmm3; \
	movapd	  4 * SIZE + address * SIZE(%edx), %xmm1; \
	addpd	%xmm3, %xmm6; \
	mulpd	  2 * SIZE + address * SIZE(%edx), %xmm2; \
	addpd	%xmm2, %xmm7


#define STACK	16
#define ARGS	 8
	
#define PLDA_M	  0 + STACK(%esp)
#define IS	  4 + STACK(%esp)

#define M	 4 + STACK + ARGS(%esp)
#define N	 8 + STACK + ARGS(%esp)
#define ALPHA_R	16 + STACK + ARGS(%esp)
#define ALPHA_I	24 + STACK + ARGS(%esp)
#define A	32 + STACK + ARGS(%esp)
#define LDA	36 + STACK + ARGS(%esp)
#define X	40 + STACK + ARGS(%esp)
#define INCX	44 + STACK + ARGS(%esp)
#define Y	48 + STACK + ARGS(%esp)
#define INCY	52 + STACK + ARGS(%esp)
#define BUFFER	56 + STACK + ARGS(%esp)

	PROLOGUE

	subl	$ARGS, %esp
	pushl	%ebp
	pushl	%edi
	pushl	%esi
	pushl	%ebx

	PROFCODE

	EMMS

	movl	INCX, %eax
	sall	$4,   %eax		# INCX *= 2
	movl	%eax, INCX

	movl	INCY, %edx
	sall	$4,   %edx		# INCY *= 2
	movl	%edx, INCY

	movl	LDA,  %edi
	sall	$4,   %edi		# LDA *= 2
	movl	%edi, LDA

	movl	M,    %ebp
	movl	N,    %ebx
	
#ifndef PARAMTEST
	imull	$P,   %edi
#else
	imull	 P,   %edi
#endif
	movl	%ebp, %ecx
	sall	$4,   %ecx
	subl	%ecx, %edi
	movl	%edi, PLDA_M

	movl	BUFFER, %edi

	pcmpeqb	%mm7, %mm7
	psllq	$63, %mm7	

	movq	ALPHA_R,  %mm0
	movq	ALPHA_I,  %mm1

	movq	%mm0, 0 * SIZE(%edi)
	movq	%mm0, 1 * SIZE(%edi)
	movq	%mm1, 2 * SIZE(%edi)
	pxor	%mm7, %mm1
	movq	%mm1, 3 * SIZE(%edi)

	xorl	%edx,%edx		# is = 0

	testl	%ebx, %ebx
	jle	.L999
	testl	%ebp, %ebp
	jle	.L999
	ALIGN_3

.L10:
	movl	N,    %ebp
	subl	%edx, %ebp		# m - is
#ifndef PARAMTEST
	movl	$P,   %eax
#else
	movl	 P,   %eax
#endif
	cmpl	%eax, %ebp
	cmovg	%eax, %ebp

	movl	BUFFER, %ecx
	addl	$128, %ecx

	movl	%edx, IS

	movl	X,    %ebx
	movl	INCX, %edx

	movl	%ebp, %eax
	sarl	$2,   %eax
	jle	.L12
	ALIGN_3

.L11:
#ifndef CONJ
	movq	0 * SIZE(%ebx), %mm0
	movq	1 * SIZE(%ebx), %mm1
	addl	%edx,%ebx
	movq	0 * SIZE(%ebx), %mm2
	movq	1 * SIZE(%ebx), %mm3
	addl	%edx,%ebx

	movq	%mm0, 0 * SIZE(%ecx)
	movq	%mm0, 1 * SIZE(%ecx)
	movq	%mm1, 3 * SIZE(%ecx)
	pxor	%mm7, %mm1
	movq	%mm1, 2 * SIZE(%ecx)

	movq	%mm2, 4 * SIZE(%ecx)
	movq	%mm2, 5 * SIZE(%ecx)
	movq	%mm3, 7 * SIZE(%ecx)
	pxor	%mm7, %mm3
	movq	%mm3, 6 * SIZE(%ecx)

	movq	0 * SIZE(%ebx), %mm0
	movq	1 * SIZE(%ebx), %mm1
	addl	%edx,%ebx

	movq	0 * SIZE(%ebx), %mm2
	movq	1 * SIZE(%ebx), %mm3
	addl	%edx,%ebx

	movq	%mm0,  8 * SIZE(%ecx)
	movq	%mm0,  9 * SIZE(%ecx)
	movq	%mm1, 11 * SIZE(%ecx)
	pxor	%mm7, %mm1
	movq	%mm1, 10 * SIZE(%ecx)

	movq	%mm2, 12 * SIZE(%ecx)
	movq	%mm2, 13 * SIZE(%ecx)
	movq	%mm3, 15 * SIZE(%ecx)
	pxor	%mm7, %mm3
	movq	%mm3, 14 * SIZE(%ecx)
#else
	movq	0 * SIZE(%ebx), %mm0
	movq	1 * SIZE(%ebx), %mm1
	addl	%edx,%ebx
	movq	0 * SIZE(%ebx), %mm2
	movq	1 * SIZE(%ebx), %mm3
	addl	%edx,%ebx

	movq	%mm0, 0 * SIZE(%ecx)
	pxor	%mm7, %mm0
	movq	%mm0, 1 * SIZE(%ecx)
	movq	%mm1, 2 * SIZE(%ecx)
	movq	%mm1, 3 * SIZE(%ecx)

	movq	%mm2, 4 * SIZE(%ecx)
	pxor	%mm7, %mm2
	movq	%mm2, 5 * SIZE(%ecx)
	movq	%mm3, 6 * SIZE(%ecx)
	movq	%mm3, 7 * SIZE(%ecx)

	movq	0 * SIZE(%ebx), %mm0
	movq	1 * SIZE(%ebx), %mm1
	addl	%edx,%ebx

	movq	0 * SIZE(%ebx), %mm2
	movq	1 * SIZE(%ebx), %mm3
	addl	%edx,%ebx

	movq	%mm0,  8 * SIZE(%ecx)
	pxor	%mm7, %mm0
	movq	%mm0,  9 * SIZE(%ecx)
	movq	%mm1, 10 * SIZE(%ecx)
	movq	%mm1, 11 * SIZE(%ecx)

	movq	%mm2, 12 * SIZE(%ecx)
	pxor	%mm7, %mm2
	movq	%mm2, 13 * SIZE(%ecx)
	movq	%mm3, 14 * SIZE(%ecx)
	movq	%mm3, 15 * SIZE(%ecx)
#endif

	subl	$-16 * SIZE, %ecx
	decl	%eax
	jg	.L11
	ALIGN_3

.L12:
	movl	%ebp, %eax
	andl	$3,   %eax
	jle	.L20
	ALIGN_3

.L13:
	movq	0 * SIZE(%ebx), %mm0
	movq	1 * SIZE(%ebx), %mm1

#ifndef CONJ
	movq	%mm0, 0 * SIZE(%ecx)
	movq	%mm0, 1 * SIZE(%ecx)
	movq	%mm1, 3 * SIZE(%ecx)
	pxor	%mm7, %mm1
	movq	%mm1, 2 * SIZE(%ecx)
#else
	movq	%mm0, 0 * SIZE(%ecx)
	pxor	%mm7, %mm0
	movq	%mm0, 1 * SIZE(%ecx)
	movq	%mm1, 2 * SIZE(%ecx)
	movq	%mm1, 3 * SIZE(%ecx)
#endif

	addl	$4 * SIZE, %ecx
	addl	%edx, %ebx
	decl	%eax
	jg	.L13
	ALIGN_3

.L20:
	movl	%ebx, X
	movl	Y,  %edi
	movl	M,  %esi
	sarl	$1, %esi
	jle	.L50
	ALIGN_3

.L21:
	pxor	%xmm4, %xmm4
	pxor	%xmm5, %xmm5
	pxor	%xmm6, %xmm6
	pxor	%xmm7, %xmm7

	movl	A, %ecx
	addl	$4 * SIZE, A
	movl	LDA, %ebx

	movl	BUFFER, %edx
	addl	$128, %edx
	movapd	  0 * SIZE(%edx), %xmm1

	movl	%ebp, %eax		# i = min_n
	sarl	$2,   %eax
	jle	.L23
	ALIGN_3

.L22:
	KERNELMACRO( 0)
	KERNELMACRO( 4)
	KERNELMACRO( 8)
	KERNELMACRO(12)

	addl	$16 * SIZE, %edx
	decl	%eax
	jg	.L22
	ALIGN_3

.L23:
	movl	%ebp, %eax		# i = min_n
	andl	$3,  %eax
	jle	.L29
	ALIGN_3

.L24:
	KERNELMACRO( 0)
	addl	$4 * SIZE,%edx
	decl	%eax
	jg	.L24
	ALIGN_3

.L29:
	movl	BUFFER, %eax
	movl	INCY, %ebx

	movapd	0 * SIZE(%eax), %xmm0
	movapd	2 * SIZE(%eax), %xmm1

	SHUFPD_1 %xmm5, %xmm5
	SHUFPD_1 %xmm7, %xmm7
#if (!defined(XCONJ) && !defined(CONJ)) || (defined(XCONJ) && defined(CONJ))
	subpd	%xmm5, %xmm4
	subpd	%xmm7, %xmm6
#else
	addpd	%xmm5, %xmm4
	addpd	%xmm7, %xmm6
#endif
	movapd	%xmm4, %xmm5
	movapd	%xmm6, %xmm7

	mulpd	%xmm0, %xmm4
	mulpd	%xmm1, %xmm5
	mulpd	%xmm0, %xmm6
	mulpd	%xmm1, %xmm7

	SHUFPD_1 %xmm5, %xmm5
	SHUFPD_1 %xmm7, %xmm7
	addpd	%xmm5, %xmm4
	addpd	%xmm7, %xmm6

	movsd	 0 * SIZE(%edi), %xmm0
	movhpd	 1 * SIZE(%edi), %xmm0
	addpd	%xmm0, %xmm4
	movsd	%xmm4, 0 * SIZE(%edi)
	unpckhpd %xmm4, %xmm4
	movsd	%xmm4, 1 * SIZE(%edi)
	addl	%ebx, %edi		# coffset += incy

	movsd	 0 * SIZE(%edi), %xmm0
	movhpd	 1 * SIZE(%edi), %xmm0
	addpd	%xmm0, %xmm6
	movsd	%xmm6, 0 * SIZE(%edi)
	unpckhpd %xmm6, %xmm6
	movsd	%xmm6, 1 * SIZE(%edi)
	addl	%ebx, %edi		# coffset += incy

	decl	%esi
	jg	.L21

.L50:
	movl	M,  %esi
	testl	$1, %esi
	jle	.L99

	pxor	%xmm4, %xmm4
	pxor	%xmm5, %xmm5
	pxor	%xmm6, %xmm6
	pxor	%xmm7, %xmm7

	movl	BUFFER, %edx
	addl	$128, %edx

	movl	A, %ecx
	addl	$2 * SIZE, A
	movl	LDA, %ebx

	movapd	  0 * SIZE(%edx), %xmm1
	movapd	  8 * SIZE(%edx), %xmm3

	movl	%ebp, %eax
	sarl	$2,   %eax
	jle	.L53
	ALIGN_3

.L52:
	movsd	  0 * SIZE(%ecx), %xmm0
	movhpd	  1 * SIZE(%ecx), %xmm0
	addl	%ebx, %ecx
	movsd	  0 * SIZE(%ecx), %xmm2
	movhpd	  1 * SIZE(%ecx), %xmm2
	addl	%ebx, %ecx

	mulpd	%xmm0,	%xmm1
	mulpd	  2 * SIZE(%edx), %xmm0
	addpd	%xmm1, %xmm4
	movapd	  4 * SIZE(%edx), %xmm1
	addpd	%xmm0, %xmm5
	movsd	  0 * SIZE(%ecx), %xmm0
	mulpd	%xmm2,	%xmm1
	mulpd	  6 * SIZE(%edx), %xmm2
	addpd	%xmm1, %xmm6
	movapd	 16 * SIZE(%edx), %xmm1
	addpd	%xmm2, %xmm7

	movhpd	  1 * SIZE(%ecx), %xmm0
	addl	%ebx, %ecx
	movsd	  0 * SIZE(%ecx), %xmm2
	movhpd	  1 * SIZE(%ecx), %xmm2
	addl	%ebx, %ecx

	mulpd	%xmm0,	%xmm3
	mulpd	 10 * SIZE(%edx), %xmm0
	addpd	%xmm3, %xmm4
	movapd	 12 * SIZE(%edx), %xmm3
	addpd	%xmm0, %xmm5
	mulpd	%xmm2,	%xmm3
	mulpd	 14 * SIZE(%edx), %xmm2
	addpd	%xmm3, %xmm6
	movapd	 24 * SIZE(%edx), %xmm3
	addpd	%xmm2, %xmm7

	addl	$16 * SIZE, %edx
	decl	%eax
	jg	.L52
	ALIGN_3

.L53:
	movl	%ebp, %eax
	andl	$3,   %eax
	jle	.L59
	ALIGN_3

.L54:
	movsd	 0 * SIZE(%ecx), %xmm0
	movhpd	 1 * SIZE(%ecx), %xmm0

	mulpd	%xmm0,	%xmm1
	addpd	%xmm1, %xmm4
	movapd	 2 * SIZE(%edx), %xmm1
	mulpd	%xmm0, %xmm1
	addpd	%xmm1, %xmm5
	movapd	 4 * SIZE(%edx), %xmm1

	addl	%ebx, %ecx
	addl	$4 * SIZE, %edx
	decl	%eax
	jg	.L54
	ALIGN_3

.L59:
	addpd	%xmm6, %xmm4
	addpd	%xmm7, %xmm5

	movl	BUFFER, %eax
	SHUFPD_1 %xmm5, %xmm5
#if (!defined(XCONJ) && !defined(CONJ)) || (defined(XCONJ) && defined(CONJ))
	subpd	%xmm5, %xmm4
#else
	addpd	%xmm5, %xmm4
#endif
	movapd	%xmm4, %xmm5

	movapd	0 * SIZE(%eax), %xmm0
	movapd	2 * SIZE(%eax), %xmm1

	mulpd	%xmm0, %xmm4
	mulpd	%xmm1, %xmm5
	SHUFPD_1 %xmm5, %xmm5
	addpd	%xmm5, %xmm4

	movsd	 0 * SIZE(%edi), %xmm0
	movhpd	 1 * SIZE(%edi), %xmm0
	addpd	%xmm0, %xmm4
	movsd	%xmm4, 0 * SIZE(%edi)
	unpckhpd %xmm4, %xmm4
	movsd	%xmm4, 1 * SIZE(%edi)
	ALIGN_3

.L99:
	movl	PLDA_M, %eax
	addl	%eax, A

	movl	IS,  %edx
#ifndef PARAMTEST
	addl	$P,  %edx
#else
	addl	 P,  %edx
#endif
	cmpl	N,   %edx
	jl	.L10
	ALIGN_3

.L999:
	EMMS

	popl	%ebx
	popl	%esi
	popl	%edi
	popl	%ebp
	addl	$ARGS, %esp
	ret

	EPILOGUE