iconbasis.as

国外强大的xml相册

//**************************IconBasis Class****************
//hint
import pssclasses.hint.*;
//colormatrix
import pssclasses.ColorsClass.*;
//icon
import pssclasses.icons.*;
class IconBasis extends MovieClip {
	//************define attributes*************
	private var iconHolder:MovieClip;
	private var iconLabelHolder:MovieClip;
	private var iconHint:String;
	private var dopiconHint:String;
	private var ShowIconHint:Boolean = false;
	private var myPressAction:Function;
	private var myPressActionArguments:Array;
	private var __this:MovieClip;
	private var ImInMidelActiv:Boolean;
	private var MidelActivPosi:Number = 30;
	//*************define metods**************
	public function IconBasis() {
		__this = this;
		__this.cacheAsBitmap = true;
		__this.useHandCursor = false;
	}
	public function buildIcon(iconName:String, iconLab:String, labsize:Number):Void {
		iconHolder = __this.createEmptyMovieClip("iconHolder_mc", 0);
		__this.hitArea = iconHolder;
		iconHolder.attachMovie(iconName, iconName, 0);
		//label component
		iconHint = iconLab;
		if (iconLab && labsize != 0) {
			iconLabelHolder = __this.attachMovie("LabelComponent", "label_mc", 1);
			if (labsize == 0 || labsize == undefined) {
				iconLabelHolder.autosize = true;
			} else {
				iconLabelHolder.align = "center";
				iconLabelHolder.size = labsize;
			}
			iconLabelHolder.label = iconLab;
			//iconLabelHolder.autosize = true;
			iconLabelHolder._y = iconHolder._y+iconHolder._height+3;
			if (iconLabelHolder._width>iconHolder._width) {
				iconLabelHolder._x = 0;
				iconHolder._x = (iconLabelHolder._width-iconHolder._width)/2;
			} else {
				iconLabelHolder._x = (iconHolder._width-iconLabelHolder._width)/2;
			}
		} else {
			if (iconHint != undefined) {
				ShowIconHint = true;
			}
		}
	}
	//**********************activ / pasiv / disable***************
	public function setActiv():Void {
		if (ImInMidelActiv) {
			var stopCount:Number = MidelActivPosi;
		} else {
			var stopCount:Number = 0;
		}
		var satCount:Number = 5+stopCount;
		__this.onEnterFrame = function() {
			ColorComander.adjustBrightnessMC(this, 0, false);
			ColorComander.adjustSaturationMC(this, satCount, true);
			if (satCount>=100) {
				delete this.onEnterFrame;
				ColorComander.adjustSaturationMC(this, 100, true);
			}
			satCount += 10;
		};
	}
	public function setPasiv():Void {
		if (ImInMidelActiv) {
			var stopCount:Number = MidelActivPosi;
		} else {
			var stopCount:Number = 0;
		}
		var satCount:Number = 100;
		__this.onEnterFrame = function() {
			ColorComander.adjustBrightnessMC(this, 0, false);
			ColorComander.adjustSaturationMC(this, satCount, true);
			if (satCount<=stopCount) {
				delete this.onEnterFrame;
				ColorComander.adjustSaturationMC(this, stopCount, true);
			}
			satCount -= 20;
		};
	}
	public function setDisable():Void {
		__this.enabled = false;
		ColorComander.adjustBrightnessMC(this, +10, false);
		ColorComander.adjustSaturationMC(this, 0, true);
	}
	public function setAble():Void {
		if (ImInMidelActiv) {
			var stopCount:Number = MidelActivPosi;
		} else {
			var stopCount:Number = 0;
		}
		__this.enabled = true;
		ColorComander.adjustBrightnessMC(this, 0, true);
		ColorComander.adjustSaturationMC(this, stopCount, true);
	}
	public function setDesablGrey():Void {
		__this.enabled = false;
		ColorComander.adjustBrightnessMC(this, 0, true);
		ColorComander.adjustSaturationMC(this, 0, true);
	}
	public function setToMidleActiv():Void {
		ImInMidelActiv = true;
		ColorComander.adjustBrightnessMC(this, 0, false);
		ColorComander.adjustSaturationMC(this, MidelActivPosi, true);
	}
	//**********************events*********************
	private function onRollOver():Void {
		if (ShowIconHint) {
			if(dopiconHint==""||dopiconHint==undefined){
			var printlabel:String=iconHint
			}else{
			var printlabel:String=dopiconHint
			}
			// ********************************************** HINT********************************************
			Hint.labelText(printlabel);
			// ************end****************************** HINT********************************************
		}
		setActiv();
	}
	private function onRollOut():Void {
		if (ShowIconHint) {
			// **********************************************KILL HINT********************************************
			Hint.killHint();
			// ****************end**************************KILL HINT********************************************
		}
		setPasiv();
	}
	public function setPressAction(pressact:Function, argument:Array):Void {
		myPressAction = pressact;
		myPressActionArguments = argument;
	}
	private function onPress():Void {
		if (ShowIconHint) {
			// **********************************************KILL HINT********************************************
			Hint.killHint();
			// ****************end**************************KILL HINT********************************************
		}
	}
	private function onReleaseOutside():Void {
		setPasiv();
	}
	private function onRelease():Void {
		myPressAction.apply(null, myPressActionArguments);
	}
	//**************set icon label*************
	public function setIconLabel(lab:String, fullnew:Boolean):Void {
		if (!fullnew) {
			dopiconHint = iconHint+" "+lab;
		} else {
			dopiconHint = lab;
		}
		
	}
	//********end class****************
}