browserheader.as

国外强大的xml相册

// import hint class
import pssclasses.hint.*;
//***************************import FormatText class**************************
import pssclasses.*;
//***************************Browser Class******************
import pssclasses.browser.*;
class BrowserHeader extends MovieClip {
	// *****************define  class variables****************
	// movie inside
	private var container_mc:MovieClip;
	private var left_mc:MovieClip;
	private var center_mc:MovieClip;
	private var right_mc:MovieClip;
	// virtual movie
	private var __parent:MovieClip;
	private var __this:MovieClip;
	private var containerHeaderBG:MovieClip;
	private var BROWSER:MovieClip;
	// header label
	private var headerLabel:MovieClip;
	private var headerLabelName:String = "label_mc";
	private var headerLabelDepth:Number = 0;
	// Separator
	private var browserSeparatorLinkageName:String = "browserSeparator";
	private var browserSeparatorName:String = "separator_mc";
	private var browserSeparatorDepth:Number = 4;
	private var browserSeparator:MovieClip;
	// PSS icon
	private var pssIconLinkageName:String = "pssIcon";
	private var pssIconName:String = "pssIcon_mc";
	private var pssIconDepth:Number = 1;
	private var pssIcon:MovieClip;
	// corner close resize menu
	private var cornerMenuLinkageName:String = "cornerMenu";
	private var cornerMenuName:String = "cornerMenu_mc";
	private var cornerMenuDepth:Number = 2;
	private var cornerMenu:MovieClip;
	// button inside cornerMenu
	private var minimazer_but:Button;
	private var maximazer_but:Button;
	private var closer_but:Button;
	// cornerMenu margin
	private var cornerMenuMargin:Number = 12;
	// text field into label
	// top
	private var topText:TextField;
	private var topTextName:String = "top_txt";
	private var topTextDepth:Number = 1;
	//bottom
	private var botText:TextField;
	private var botTextName:String = "bot_txt";
	private var botTextDepth:Number = 0;
	// label text field property
	private var labelFont:String = "Verdana";
	private var labelSize:Number = 10;
	private var labelTopColor:Number = 0x333333;
	private var labelBotColor:Number = 0xCCCCCC;
	private var labelBold:Boolean = false;
	private var labelAlign:String = "center";
	private var labelMargin:Number = 0;
	// pixels displacement bottom textfield comparison top text field
	private var displaceX:Number = 1;
	private var displaceY:Number = 1;
	private var maximumazerON:Boolean=false
	// ****************define metods*********************
	private function BrowserHeader() {
		__this = this;
		__parent = __this._parent.hirArea_mc;
		BROWSER = __this._parent;
		// ***********************define variables:MovieClip************************
		containerHeaderBG = container_mc;
		left_mc = containerHeaderBG.left_mc;
		center_mc = containerHeaderBG.center_mc;
		right_mc = containerHeaderBG.right_mc;
		// *******end************define variables:MovieClip************************
		// *****************build header*************
		drawToStart();
		// attach separator
		browserSeparator = __this.attachMovie(browserSeparatorLinkageName, browserSeparatorName, browserSeparatorDepth);
		browserSeparator._y = __this._height;
		browserSeparator._x = 2;
		// attach PSS icon 
		pssIcon = __this.attachMovie(pssIconLinkageName, pssIconName, pssIconDepth);
		pssIcon._x = 6;
		pssIcon._y = 6;
		// attach CornerMenu
		cornerMenu = __this.attachMovie(cornerMenuLinkageName, cornerMenuName, cornerMenuDepth);
		placeCornerMenu();
		// define button inside cornerMenu
		minimazer_but = cornerMenu.minimazer_but;
		maximazer_but = cornerMenu.maximazer_but;
		closer_but = cornerMenu.closer_but;
		// *********************************set all events*****************************
		setAllEvents();
		// cacheAsBitmap
		__this.cacheAsBitmap = true;
	}
	// ****************build header to start*********************
	private function drawToStart():Void {
		// build header bg
		buildBg(__parent);
		// build label container
		buildLabel(__this);
	}
	// ****end********build header to start*********************
	//****************build header bg********************
	private function buildBg(container:MovieClip):Void {
		var containSize = container._width;
		var leftSize = left_mc._width;
		// build header bg 
		center_mc._x = left_mc._x+leftSize;
		center_mc._width = containSize-leftSize*2;
		right_mc._x = center_mc._x+center_mc._width;
	}
	//*****end********build header bg********************
	// ********************build label***********************
	private function buildLabel(container:MovieClip):Void {
		// create label container
		headerLabel = container.createEmptyMovieClip(headerLabelName, headerLabelDepth);
		// place label 
		placeLabel();
		headerLabel.cacheAsBitmap = true;
		//******************FormatText class******************
		//FormatText.setTextFieldProp(textFieldField:TextField, autoSizeField:Boolean, selectableText:Boolean, embedFont:Boolean, sharpness:Number, gridFitType:String,htmlText:Boolean)
		// FormatText.setTextFieldFormat(textFieldField:TextField, font:String, size:Number, color:Number, bold:Boolean, underLine:Boolean, align:String, leftMargin:Number, rightMargin:Number)
		//top text field
		topText = headerLabel.createTextField(topTextName, topTextDepth, 0, 0, center_mc._width-80, 20);
		FormatText.setTextFieldProp(topText, false, false, false, -400, "pixel", false);
		FormatText.setTextFieldFormat(topText, labelFont, labelSize, labelTopColor, labelBold, false, labelAlign, labelMargin, labelMargin);
		//bottom text field
		botText = headerLabel.createTextField(botTextName, botTextDepth, displaceX, displaceY, center_mc._width-80, 20);
		FormatText.setTextFieldProp(botText, false, false, false, -400, "pixel", false);
		FormatText.setTextFieldFormat(botText, labelFont, labelSize, labelBotColor, labelBold, false, labelAlign, labelMargin, labelMargin);
		//******end******FormatText class******************
		topText.text = "Sonettic PhotoSlideShow";
		botText.text = "Sonettic PhotoSlideShow";
	}
	public function setLabel(lab:String):Void {
		if (lab == undefined) {
			lab = "_";
		}
		if (lab != "sonettic") {
			topText.text = lab;
			botText.text = lab;
		} else {
			topText.text = "Sonettic PhotoSlideShow";
			botText.text = "Sonettic PhotoSlideShow";
		}
	}
	//************************************BROWSER TITLE******************************
	public function set browserTitle(btitle:String) {
		topText.text = btitle;
		botText.text = btitle;
	}
	//**********end**********************BROWSER TITLE******************************
	// *****end************build label***********************
	//**********************resize label************************
	private function resizeLabel():Void {
		topText._width = center_mc._width-90;
		botText._width = center_mc._width-90;
	}
	// place label
	private function placeLabel():Void {
		headerLabel._y = 5;
		headerLabel._x = center_mc._x+40;
	}
	// place cornerMenu
	private function placeCornerMenu():Void {
		cornerMenu._y = 6;
		cornerMenu._x = Math.floor(containerHeaderBG._width-cornerMenu._width-cornerMenuMargin);
	}
	//*******************REBUILD HEADER********************
	public function rebuildHeader():Void {
		// build header bg
		buildBg(__parent);
		// resize label
		resizeLabel();
		// separator rebuild
		browserSeparator.separatorBuild(__parent);
		// place cornerMenu
		placeCornerMenu();
	}
	public function setIsFullSkreen(fs:Boolean):Void{
	maximumazerON=fs
	}
	//******************************EVENTS******************************
	private function setAllEvents():Void {
		// local browser link variables
		var _BROWSER:MovieClip = BROWSER;
		var THIS:MovieClip=__this
		//var maximumazerON:Boolean = false;
		//******************************START STOP DRAG******************************
		// hand cursor
		containerHeaderBG.useHandCursor = false;
		// press for drag and swap depths
		var timer:Number;
		var flag:Boolean;
		containerHeaderBG.onPress = function():Void  {
			//*********************DOUBLE CLICK***********************
			if (getTimer()-timer<=400 && flag) {
				//************resize browser***********
				if (!THIS.maximumazerON) {
					_BROWSER.setMaximumSize();
				} else {
					_BROWSER.setMemirySize();
				}
				THIS.maximumazerON = !THIS.maximumazerON;
				//****end******resize browser***********
				flag = false;
			} else {
				timer = getTimer();
				flag = true;
				// start drag browser
				_BROWSER.startDrag();
			}
			//****end**************DOUBLE CLICK***********************
			// make browser as selected
			_BROWSER.browserSelected();
		};
		// release for drag
		containerHeaderBG.onRelease = function():Void  {
			// stop drag browser
			_BROWSER.stopDrag();
		};
		//*****end********************START STOP DRAG******************************
		//***************************CORNER MENU EVENTS**************************
		// define button inside cornerMenu
		minimazer_but.useHandCursor = false;
		maximazer_but.useHandCursor = false;
		closer_but.useHandCursor = false;
		//maximazer
		maximazer_but.onPress = function():Void  {
			// from hint class
			Hint.killHint();
			if (!THIS.maximumazerON) {
				_BROWSER.setMaximumSize();
			} else {
				_BROWSER.setMemirySize();
			}
			THIS.maximumazerON = !THIS.maximumazerON;
		};
		maximazer_but.onRollOver = function():Void  {
			if (!THIS.maximumazerON) {
				// from hint class
				var hinttext:String = _global.PSS_UI.lib_maximaze;
			} else {
				var hinttext:String = _global.PSS_UI.lib_restoredown;
			}
			Hint.labelText(hinttext, 200);
		};
		maximazer_but.onRollOut = function():Void  {
			// from hint class
			Hint.killHint();
		};
		// minimazer
		minimazer_but.onPress = function():Void  {
			_BROWSER.setMinimumSize();
			THIS.maximumazerON = false;
			// from hint class
			Hint.killHint();
		};
		// minimazer
		minimazer_but.onRollOver = function():Void  {
			// from hint class
			var hinttext:String = _global.PSS_UI.lib_minimaze;
			Hint.labelText(hinttext, 200);
		};
		minimazer_but.onRollOut = function():Void  {
			// from hint class
			Hint.killHint();
		};
		// closer
		closer_but.onPress = function():Void  {
			_BROWSER.removeBrowser();
			// from hint class
			Hint.killHint();
		};
		closer_but.onRollOver = function():Void  {
			// from hint class
			var hinttext:String = _global.PSS_UI.lib_close;
			Hint.labelText(hinttext, 200);
		};
		closer_but.onRollOut = function():Void  {
			// from hint class
			Hint.killHint();
		};
		//********end**************CORNER MENU EVENTS**************************
	}
	//*****end**********************EVENTS******************************
	//***************************SET NEW COLOR*****************
	public function setNewColor():Void{
	pssIcon.setNewColor();
	}
	//****************end class*******************
}