browsercontentholder.as

国外强大的xml相册

//     DrawPrimitive
import pssclasses.*;
//SplitPanelControler class
import pssclasses.splitpanel.*;
//************************browser BrowserContentHolder*********************
import pssclasses.browser.*;
class BrowserContentHolder extends MovieClip {
	// *****************define  class variables****************
	// ********content hit area***************
	private var contentHitArea:MovieClip;
	private var contentHitAreaName:String = "hitArea_mc";
	private var contentHitAreaDepth:Number = 0;
	private var contentHitAreaX:Number = 0;
	private var contentHitAreaY:Number = 0;
	//********content face hit area for event when browser passive
	private var contentFaceHitArea:MovieClip;
	private var contentFaceHitAreaName:String = "hitFaceArea_mc";
	private var contentFaceHitAreaDepth:Number = 10;
	private var contentFaceHitAreaX:Number = 0;
	private var contentFaceHitAreaY:Number = 0;
	// width and height in percent
	private var contentHitAreaW:Number;
	private var contentHitAreaH:Number;
	private var contentHitAreaAlpha:Boolean = true;
	private var contentHitAreaFillColor:Number = 0x00996699;
	// parent 
	private var container:MovieClip;
	private var __this:MovieClip;
	private var __parent:MovieClip;
	//*****************SplitPanelControler Class************
	private var newSplitPanelControler:Object;
	// *****************define  class metods****************
	private function BrowserContentHolder() {
		__this = this;
		__this.cacheAsBitmap = true;
		__parent = __this._parent;
		container = __parent.hirArea_mc;
		__this._x = 2;
		__this._y = __parent.header_mc._height;
		contentHitAreaW = container._width-4;
		contentHitAreaH = __parent.footer_mc._y-__this._y;
		// draw hitarea
		drawHitArea();
		//*****************SplitPanelControler************
		newSplitPanelControler = new SplitPanelControler();
		//build SplitPanel
		newSplitPanelControler.buildSplitPanel(__this);
	}
	//************************SET NEW COLOR********************
	public function setNewColor():Void{
	newSplitPanelControler.setNewColor()
	}
	// *****************drawing browser hit area*********************
	private function drawHitArea():Void {
		//***************draw contentHitArea with DrawPrimitive class*************
		contentHitArea = DrawPrimitive.drawBitmapRectangle(__this, contentHitAreaName, contentHitAreaDepth, contentHitAreaW, contentHitAreaH, contentHitAreaAlpha, contentHitAreaFillColor);
	}
	// ****end*********drawing browser hit area*********************
	// *****************drawing contentFace hit area*********************
	public function drawFaceHitArea():Void {
		//***************draw contentFaceHitArea with DrawPrimitive class*************
		contentFaceHitArea = DrawPrimitive.drawBitmapRectangle(__this, contentFaceHitAreaName, contentFaceHitAreaDepth, contentHitArea._width, contentHitArea._height, contentHitAreaAlpha, contentHitAreaFillColor);
		//****end*******draw contentFace area with DrawPrimitive class*************
		contentFaceHitArea._x = contentFaceHitAreaX;
		contentFaceHitArea._y = contentFaceHitAreaY;
		var BROWSER:MovieClip = __parent;
		contentFaceHitArea.useHandCursor = false;
		//************set browser to select***************
		contentFaceHitArea.onPress = function() {
			BROWSER.browserSelected();
		};
		//***end******set browser to select***************
	}
	public function killFaceHitArea():Void {
		//********remove contentFaceHitArea************
		contentFaceHitArea.removeMovieClip();
	}
	// ****end*********drawing contentFace hit area*********************
	//***********************RESIZE CONTAINER**************************
	public function rebuildContentContainer():Void {
		contentHitAreaW = container._width-4;
		contentHitAreaH = __parent.footer_mc._y-__this._y;
		//resize hitArea
		resizeHitArea(contentHitAreaW, contentHitAreaH);
		//resize splitPanel
		newSplitPanelControler.resizeSplitPanel(contentHitAreaW, contentHitAreaH);
	}
	// resize hitarea
	private function resizeHitArea(__width:Number, __height:Number):Void {
		contentHitArea._width = __width;
		contentHitArea._height = __height;
	}
	//********end**********RESIZE CONTAINER**************************
	//**********end class************
}