browserfooter.as

国外强大的xml相册

//************************browser footer*********************
// setting class import
import pssclasses.*;
// import hint class
import pssclasses.hint.*;
// import BrowserControler class
import pssclasses.browser.*;
class BrowserFooter extends MovieClip {
	// *****************define  class variables****************
	private var BROWSER:MovieClip;
	// movie inside
	private var container_mc:MovieClip;
	private var left_mc:MovieClip;
	private var center_mc:MovieClip;
	private var right_mc:MovieClip;
	// virtual movie
	private var __parent:MovieClip;
	private var __this:MovieClip;
	private var containerFooterBG:MovieClip;
	// Separator
	private var browserSeparatorLinkageName:String = "browserSeparator";
	private var browserSeparatorName:String = "separator_mc";
	private var browserSeparatorDepth:Number = 4;
	private var browserSeparator:MovieClip;
	// Play menu 
	private var playMenuLinkageName:String = "playMenu";
	private var playMenuName:String = "playMenu_mc";
	private var playMenuDepth:Number = 0;
	private var playMenu:MovieClip;
	// Search
	private var searchPanelLinkageName:String = "searchPanel";
	private var searchPanelName:String = "searchPanel_mc";
	private var searchPanelDepth:Number = 3;
	private var searchPanel:MovieClip;
	// New Browser button
	private var browserButLinkageName:String = "browserBut";
	private var browserButName:String = "browser_but";
	private var browserButDepth:Number = 2;
	private var browserBut:MovieClip;
	// New Browser button
	private var settingButLinkageName:String = "setting_but";
	private var settingButName:String = "setting_but";
	private var settingButDepth:Number = 5;
	private var settingBut:MovieClip;
	// browser Resizer
	private var browserResizerLinkageName:String = "browserResizer";
	private var browserResizerName:String = "browserResizer_mc";
	private var browserResizerDepth:Number = 1;
	private var browserResizer:MovieClip;
	//photo dop menu
	// sound menu 
	private var soundMenuLinkageName:String = "soundMenuMC";
	private var soundMenuName:String = "soundMenu_mc";
	private var soundMenuDepth:Number = 6;
	private var soundMenu:MovieClip;
	// linkPhoto ico
	private var linkPhotoButLinkageName:String = "PhotoLinkIcon";
	private var linkPhotoButName:String = "PhotoLinkIcon_mc";
	private var linkPhotoButDepth:Number = 7;
	private var linkPhotoBut:MovieClip;
	// photo menu 
	private var photoMenuLinkageName:String = "photoDopMenuMC";
	private var photoMenuName:String = "photoMenu_mc";
	private var photoMenuDepth:Number = 8;
	private var photoMenu:MovieClip;
	//copyride
	private var CopyRide:MovieClip;
	// ****************define metods*********************
	private function BrowserFooter() {
		__this = this;
		__parent = __this._parent.hirArea_mc;
		BROWSER = __this._parent;
		// ***********************define movie inside**********************
		containerFooterBG = container_mc;
		left_mc = containerFooterBG.left_mc;
		center_mc = containerFooterBG.center_mc;
		right_mc = containerFooterBG.right_mc;
		// ******end************define movie inside**********************
		// build
		buildFooter(__parent);
		// place footer
		placeFooter();
		// attach separator into footer
		browserSeparator = __this.attachMovie(browserSeparatorLinkageName, browserSeparatorName, browserSeparatorDepth);
		browserSeparator._x = 2;
		// attach play menu
		playMenu = __this.attachMovie(playMenuLinkageName, playMenuName, playMenuDepth);
		//place menu
		placePaymenu();
		// set to menu menuPlace
		playMenu.setPlace(false);
		// attach search panel
		searchPanel = __this.attachMovie(searchPanelLinkageName, searchPanelName, searchPanelDepth);
		placeSearchPanel();
		//set into search panel browser load or playpanel
		searchPanel.setPlace(false);
		//photo dop menu
		photoMenu = __this.attachMovie(photoMenuLinkageName, photoMenuName, photoMenuDepth);
		placePhotoMenu();
		photoMenu._visible = false;
		// new browser button
		browserBut = __this.attachMovie(browserButLinkageName, browserButName, browserButDepth);
		placeBrowserBut();
		// setting button
		settingBut = __this.attachMovie(settingButLinkageName, settingButName, settingButDepth);
		placeSettingBut();
		// sound menu
		soundMenu = __this.attachMovie(soundMenuLinkageName, soundMenuName, soundMenuDepth);
		placeSoundMenu();
		soundMenu._visible = false;
		// linkphoto but
		linkPhotoBut = __this.attachMovie(linkPhotoButLinkageName, linkPhotoButName, linkPhotoButDepth);
		linkPhotoBut._visible = false;
		linkPhotoBut._x = Math.round(soundMenu._x+soundMenu._width+50);
		linkPhotoBut._y = soundMenu._y;
		// browser resizer
		browserResizer = __this.attachMovie(browserResizerLinkageName, browserResizerName, browserResizerDepth);
		placeResizer();
		//copyride
		//CopyRide=__this.attachMovie("pssIconCopy", "pssIconCopy_mc", 9);
		//placeCopyride()
		//CopyRide.cacheAsBitmap = true;
		// *****************EVENTS OPEN NEW BROWSER********************
		setEventsOpenNewBrowser();
		// cacheAsBitmap
		__this.cacheAsBitmap = true;
		//drag
		 footerEv()
	}
	//************************EVENT FOR FOOTER**************************
	private function footerEv():Void {
		var _BROWSER:MovieClip = BROWSER;
		containerFooterBG.useHandCursor=false
		containerFooterBG.onPress = function():Void  {
			_BROWSER.startDrag();
		};
		// release for drag
		containerFooterBG.onRelease = function():Void  {
			// stop drag browser
			_BROWSER.stopDrag();
		};
	}
	//****************build header bg********************
	private function buildFooter(container:MovieClip):Void {
		var containSize = container._width;
		var leftSize = left_mc._width;
		// build header bg 
		center_mc._x = left_mc._x+leftSize;
		center_mc._width = containSize-leftSize*2;
		right_mc._x = center_mc._x+center_mc._width;
	}
	//*****end********build header bg********************
	// ******************place footer*********************
	private function placeFooter():Void {
		__this._y = __parent._height-__this._height;
	}
	// ****end**********place footer*********************
	// ******************place payMenu*************
	private function placePaymenu():Void {
		playMenu._y = 14;
		playMenu._x = Math.floor((containerFooterBG._width-playMenu._width)/2);
	}
	// *****end***********place payMenu*************
	// ******************place search panel****************
	private function placeSearchPanel():Void {
		searchPanel._x = Math.floor(containerFooterBG._width-searchPanel._width-10);
		searchPanel._y = 52;
	}
	// ***end***********place search panel****************
	// *******************place photo menu*******************
	private function placePhotoMenu():Void {
		photoMenu._x = Math.floor(containerFooterBG._width-photoMenu._width-30);
		photoMenu._y = 10;
	}
	// ******************place resizer****************
	private function placeResizer():Void {
		browserResizer._x = Math.floor(containerFooterBG._width-browserResizer._width+3);
		browserResizer._y = 54;
	}
	// ***end***********place resizer****************
	//*******************place newBrowser button***************
	private function placeBrowserBut():Void {
		browserBut._x = 30;
		browserBut._y = 55;
	}
	//*******************place setting button***************
	private function placeSettingBut():Void {
		settingBut._x = 71;
		settingBut._y = 55;
	}
	//*******************place sound menu***************
	private function placeSoundMenu():Void {
		soundMenu._x = 30;
		soundMenu._y = 10;
	}
	//******************place copyride******************
	private function placeCopyride():Void {
		CopyRide._y = 47;
		CopyRide._x = Math.round((playMenu._x+80)/2);
	}
	//*******************rebuild footer********************
	public function rebuildFooter():Void {
		buildFooter(__parent);
		// separator rebuild
		browserSeparator.separatorBuild(__parent);
		//place
		placeFooter();
		// place searchPanel
		placeSearchPanel();
		// place photo menu
		placePhotoMenu();
		// place playMenu
		placePaymenu();
		// place resizer
		placeResizer();
		//copyride
		//placeCopyride()
	}
	// *********************EVENTS************************
	private function setEventsOpenNewBrowser():Void {
		// *********OPEN NEW BROWSR****************
		browserBut.useHandCursor = false;
		browserBut.onPress = function() {
			BrowserControler.openNewBrowser();
			// from hint class
			Hint.killHint();
		};
		browserBut.onRollOver = function():Void  {
			// from hint class
			var hinttext:String = _global.PSS_UI.lib_opennewbrowser;
			Hint.labelText(hinttext);
		};
		browserBut.onRollOut = function():Void  {
			// from hint class
			Hint.killHint();
		};
		// ****************OPEN PSS SETTING PANEL***************
		settingBut.useHandCursor = false;
		settingBut.onPress = function() {
			// open setting panel
			PSSetting.openSetting();
			// from hint class
			Hint.killHint();
		};
		settingBut.onRollOver = function():Void  {
			// from hint class
			var hinttext:String = _global.PSS_UI.lib_opensetting;
			Hint.labelText(hinttext);
		};
		settingBut.onRollOut = function():Void  {
			// from hint class
			Hint.killHint();
		};
	}
	// ***end***OPEN NEW BROWSR****************
	//****************************PLAY MENU ACTIV METODS**************************
	public function setLisetenersToActiv():Void {
		//metods from PlayMenu
		playMenu.activBehave(true);
	}
	public function setLisetenersToPassiv():Void {
		//metods from PlayMenu
		playMenu.activBehave(false);
	}
	//************end**************PLAY MENU ACTIV METODS**************************
	// *****end***********EVENTS************************
	//**************************SET NEW COLOR******************
	public function setNewColor():Void {
		playMenu.setNewColor();
	}
	//**************************update hint language***********************
	public function updateHintLang():Void {
		playMenu.updateHintLang();
	}
	//******end**************update hint language***********************
	// **********************get components of browser footer*************************
	public function getPhotoMenu():MovieClip {
		return photoMenu;
	}
	public function getLinkMenu():MovieClip {
		return linkPhotoBut;
	}
	public function getSoundMenu():MovieClip {
		return soundMenu;
	}
	public function getPlayMenu():MovieClip {
		return playMenu;
	}
	// *******end**********get components of browser footer*************************
	//************end class*************************
}