preloaderaction.as

国外强大的xml相册

//*************************class PreloaderAction*****************
//import ColoRDespatcher
import pssclasses.*;
// package classes
import pssclasses.preloader.*;
//***********************************define class************************************
class PreloaderAction extends MovieClip {
	//******************define variables******************
	private var __this:MovieClip;
	private var lepestokArray:Array = new Array();
	private var alphaOffset:Number = 2;
	private var activColor:Number = 0xFF6600;
	private var activColorAlpha:Number = 255;
	// movie inside
	private var heart_mc:MovieClip;
	private var lepestki_mc:MovieClip;
	//colorPassive_mc
	//******************define metods*********************
	private function PreloaderAction() {
		__this = this;
		//*****************set all lepestok array**************
		if (lepestokArray.length == 0) {
			lepestokArray = setLepestokArray();
		}
		//******end********set all lepestok array**************                    
		__this.onEnterFrame = function() {
			if (_global.ActivColor) {
				activColor = _global.ActivColor;
				setGlobalColor();
				delete __this.onEnterFrame;
			}
		};
		//action
		heartAction(heart_mc);
		lepestAction(lepestokArray);
		//loadingProgress(200, 100)
	}
	// ************************setToActiv*****************************
	public function setToActiv(colorActivMC:MovieClip, activity:Number):Void {
		var activeMC:MovieClip = colorActivMC;
		var alphaStep:Number = alphaOffset;
		//make activity
		activeMC.onEnterFrame = function() {
			activeMC._alpha += alphaStep;
			if (activeMC._alpha>=activity) {
				activeMC._alpha = activity;
				//clearInterval(intervalIndex);
				delete activeMC.onEnterFrame;
			}
		};
	}
	// **********************setToPacive**********************************
	function setToPacive(colorActivMC:MovieClip, passivity:Number):Void {
		var activeMC:MovieClip = colorActivMC;
		var alphaStep:Number = alphaOffset;
		//make passivity
		activeMC.onEnterFrame = function() {
			activeMC._alpha -= alphaStep;
			if (activeMC._alpha<=passivity) {
				activeMC._alpha = passivity;
				delete activeMC.onEnterFrame;
			}
		};
	}
	// **************************set color for activ movie***************************************
	private function setActiveColor(__mc:MovieClip, newcolor:Number, newalpha:Number):Void {
		ColorDispatcher.setColorAndAlpha(__mc, newcolor, newalpha);
	}
	//**********************define array with all movie*************
	private function setLepestokArray():Array {
		var movieArray:Array = new Array();
		for (var movieL in lepestki_mc) {
			movieArray.push(lepestki_mc[movieL]);
		}
		//movieArray.reverse()
		return movieArray;
	}
	//*********************set color for all movie*******************
	private function setGlobalColor():Void {
		var movieCount:Number = lepestokArray.length;
		for (var i = 0; i<movieCount; i++) {
			//*****set activcolor PrevSmallButt
			setActiveColor(lepestokArray[i].colorActiv_mc.color_mc, activColor, activColorAlpha);
			// set to pasiv color
			lepestokArray[i].colorActiv_mc._alpha = 0;
		}
		setActiveColor(heart_mc.colorActiv_mc.color_mc, activColor, activColorAlpha);
		// set to pasiv color
		heart_mc.colorActiv_mc._alpha = 0;
	}
	//**************************************action*******************
	private function heartAction(mc:MovieClip):Void {
		var colorMC:MovieClip = mc.colorActiv_mc;
		var go:Boolean = true;
		colorMC.onEnterFrame = function() {
			if (colorMC._alpha<100 && go) {
				colorMC._alpha += 5;
			}
			if (colorMC._alpha>100 && go) {
				go = false;
			}
			if (colorMC._alpha>30 && !go) {
				colorMC._alpha -= 2;
			}
			if (colorMC._alpha<30 && !go) {
				go = true;
			}
		};
	}
	//*******************lepestki***************
	private function lepestAction(larray:Array):Void {
		var lepestokCount:Number = larray.length-1;
		var lepestokArray:Array = larray;
		var counter:Number = 0;
		var startL:Number = 5;
		var go:Boolean = true;
		lepestki_mc.onEnterFrame = function() {
			lAction(lepestokArray[counter]);
			if (counter>lepestokCount) {
				counter = 0;
			}
		};
		function lAction(mc:MovieClip):Void {
			var colorMC:MovieClip = mc.colorActiv_mc;
			var go:Boolean = true;
			colorMC.onEnterFrame = function() {
				if (colorMC._alpha<100 && go) {
					colorMC._alpha += 22;
				}
				if (colorMC._alpha>100 && go) {
					go = false;
					counter++;
				}
				if (colorMC._alpha>0 && !go) {
					colorMC._alpha -= 2;
				}
				if (colorMC._alpha<0 && !go) {
					delete colorMC.onEnterFrame;
				}
			};
		}
	}
	//*********************LOADING************************
	public function loadingProgress(totalBut:Number, loadedBut:Number):Void {
		var total:Number = totalBut;
		var loaded:Number = loadedBut;
		var lepestoks:Number = lepestokArray.length;
		var loadedPerc:Number = loaded/totalBut*100;
		var lepestokOn:Number = Math.round(lepestoks/100*loadedPerc);
		for (var i = 0; i<lepestokOn; i++) {
			setActiveColor(lepestokArray[i].colorPassive_mc.color_mc, activColor, activColorAlpha);
			lepestokArray[i].colorPassive_mc._alpha = 35;
		}
	}
	//**********************end class***************************
}