admin_board_manage_save.asp

是一个很好用的通信录源码,可以用在同学朋友等的通信上使用!

<%
'===================================================================
'= ASP FILENAME	: /admin/admin_board_manage.asp
'= CREATED TIME : 2006-5-2
'= LAST MODIFIED: 2006-5-2
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 留言管理(删除,top,untop)
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/admin/include_admin_action_execute.asp" -->
<!-- #include file = "./admin_inc.asp" -->
<!-- #include file = "../inc/logic/logic_board.asp" -->

<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "admin/admin_board_manage.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "留言管理"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "BoardManageCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 请求校验与过滤
Call ActionExecFilterAdmin(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 页面析构
Call ActionOver()
%>

<%
'===================================================================
'= Function		: BoardManageCtl()  
'= Time		    : Created At 2006-5-2
'= Input        : None
'= Description  : 留言管理
'===================================================================
Function BoardManageCtl()
	Dim strMethod
	strMethod = Trim(Request.Form("method"))
	Select Case strMethod
		Case	"del" :
				Call DelBoardCtl()
		Case	"top" :
				Call TopBoardCtl()
		Case	"untop" :
				Call UnTopBoardCtl()
		Case Else :
				Call DelBoardCtl()
	End Select
End Function
'===================================================================
'= Function		: DelBoardCtl()  
'= Time		    : Created At 2006-5-2
'= Input        : None
'= Description  : 删除留言
'===================================================================
Function DelBoardCtl()
	Dim strSql,strIds,intPageNow

	'== 服务器端数据校验
	If Not ServerDataCheck(arrBoardDelDataChk) Then
		Exit Function
	End If

	'== 获取表单数据
	strIds = Trim(Request.Form("selId"))
 
	'== 逻辑处理
	strSql = " AND BOARD_ID IN (" & strIds & ")"
	If Not RemoveBoardsLogic(strSql) Then
		Exit Function
	End If

	'== Get now page
	intPageNow = Trim(Request("intPageNow"))

	'== 成功处理
	Dim strHtmlCode,strSuccUrl
	strHtmlCode = "所选择留言已被删除"
	strSuccUrl = "admin/admin_board_manage.asp?intPageNow=" & intPageNow
	Call SuccExecute(strHtmlCode,strSuccUrl)

End Function

'===================================================================
'= Function		: TopBoardCtl()  
'= Time		    : Created At 2006-5-2
'= Input        : None
'= Description  : top留言
'===================================================================
Function TopBoardCtl()
	Dim strSql,strIds,intPageNow

	'== 服务器端数据校验
	If Not ServerDataCheck(arrBoardDelDataChk) Then
		Exit Function
	End If

	'== 获取表单数据
	strIds = Trim(Request.Form("selId"))
 
 	'== 逻辑处理
	strSql = " AND BOARD_ID IN (" & strIds & ")"
	If Not TopBoardsLogic(strSql,CONST_BOARD_TOP) Then
		Exit Function
	End If

	'== Get now page
	intPageNow = Trim(Request("intPageNow"))

	'== 成功处理
	Dim strHtmlCode,strSuccUrl
	strHtmlCode = "所选择留言已被置顶"
	strSuccUrl = "admin/admin_board_manage.asp?intPageNow=" & intPageNow
	Call SuccExecute(strHtmlCode,strSuccUrl)

End Function

'===================================================================
'= Function		: UnTopBoardCtl()  
'= Time		    : Created At 2006-5-2
'= Input        : None
'= Description  : untop留言
'===================================================================
Function UnTopBoardCtl()
	Dim strSql,strIds,intPageNow

	'== 服务器端数据校验
	If Not ServerDataCheck(arrBoardDelDataChk) Then
		Exit Function
	End If

	'== 获取表单数据
	strIds = Trim(Request.Form("selId"))
 
 	'== 逻辑处理
	strSql = " AND BOARD_ID IN (" & strIds & ")"
	If Not TopBoardsLogic(strSql,CONST_BOARD_COMM) Then
		Exit Function
	End If

	'== Get now page
	intPageNow = Trim(Request("intPageNow"))

	'== 成功处理
	Dim strHtmlCode,strSuccUrl
	strHtmlCode = "所选择留言已被解除置顶"
	strSuccUrl = "admin/admin_board_manage.asp?intPageNow=" & intPageNow
	Call SuccExecute(strHtmlCode,strSuccUrl)

End Function
%>