user_pwdmdy_save.asp

是一个很好用的通信录源码,可以用在同学朋友等的通信上使用!

<%
'===================================================================
'= ASP FILENAME	: /user/user_pwdmdy_save.asp
'= CREATED TIME : 2006-5-3
'= LAST MODIFIED: 2006-5-3
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 用户密码修改
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/customer/include_customer_action_execute.asp" -->
<!-- #include file = "./user_inc.asp" -->
<!-- #include file = "../inc/inc_md5.asp" -->
<!-- #include file = "../inc/logic/logic_user.asp" -->
<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "user/user_pwdmdy_save.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "用户密码修改"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "FormSavePwdMdyCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 页面析构
Call ActionOver()

%>


<%
'===================================================================
'= Function    : FormSavePwdMdyCtl()
'= Time		   : Created At 2006-5-3
'= Input       : None
'= Description : 用户密码修改
'===================================================================
Function FormSavePwdMdyCtl()
	
	Dim strOldPwd,strNewPwd,strNewPwd2
	Dim strAddInfo

	'== 服务器端数据校验
	If Not ServerDataCheck(arrUserPwdMdyDataChk) Then
		Exit Function
	End If
	
	'== 表单数据获取
	Call CnvFormData(strUserPwdMdyFormName,GBL_objFormData)

	If GBL_objFormData.Item("NewPwd") <> GBL_objFormData.Item("NewPwd2") Then
		Call GBL_objException.catchErr(E_USER_PUB,"新密码和确认密码不一致")
		Exit Function
	End If

	If Not CheckUserPwdLogic(GBL_intUserId,GBL_objFormData) Then
		Call GBL_objException.catchErr(E_USER_PUB,"老密码不正确,请重新输入")
		Exit Function
	End If

	If Not SaveUserPwdLogic(GBL_intUserId,GBL_objFormData) Then
		Exit Function
	End If

	'== 成功处理
	Dim strHtmlCode,strSuccUrl
	strHtmlCode = "您的用户密码修改成功"
	strSuccUrl = "user/user_pwdmdy_form.asp"
	Call SuccExecute(strHtmlCode,strSuccUrl)

End Function
'================= End of Function FormSavePwdMdy() ==================
%>