usermovie.as

1.配置java环境

/**
 * @(#)UserMovie.as
 * 
 * @author soda E-mail:[e-mail]
 * @version 1.0
 * <br>Program Name: NetGame for Blue
 * <br>Date: 2007-4-21
 */
import mx.soda.util.HashMap;
import mx.soda.util.Map;

import org.game.role.UserEvents;
/**
 * 玩家控制的角色
 */
class org.game.role.UserMovie extends MovieClip
{
	private var speed:Number = 5;
	private var speakMC:MovieClip;
	//private var handleBtn:Button;
	private var isRigth:Boolean;
	private var nameText:TextField;
	//默认值
	private var isDown:Boolean = false;
	private var isUp:Boolean = false;
	private var isLeft:Boolean = false;
	private var isrigth:Boolean = true;
	private var isJump:Boolean = false;
	private var jumpHigth:Number = 368;
	private var jumpUp:Boolean = false;
	private var personMC:MovieClip;
	
	
	//障碍物集合
	private var barSet:Map;
	
	public function UserMovie()
	{
		speakMC._visible = false;
	}
	public function setName(name:String):Void
	{
		nameText.text = name;
	}
	/**
	 * 设置名字的颜色
	 */
	public function setNameColor(nameColor:Number):Void
	{
		//当前玩家，则设置事件
		nameText.textColor = nameColor;
		barSet = new HashMap();
		new UserEvents(this);
	}
	/**
	 * 设置说话内容的颜色
	 */
	public function setSpeanColor(speakColor:Number):Void
	{
		speakMC.speakText.textColor = speakColor;
	}
	public function slack():Void
	{
		this.personMC.gotoAndStop("slack");
	}
	public function left():Void
	{
		if(!isJump)
		{
			personMC.gotoAndStop("run");
		}
		this._x -= speed;
	}
	//左转身
	public function turnLeft():Void
	{
		this.isLeft = true;
		this.isrigth = false;
		this.personMC._xscale = -65;
		this.personMC._x += 50;
	}
	public function rigth():Void
	{
		if(!isJump)
		{
			personMC.gotoAndStop("run");
		}
		this._x += speed;
	}
	public function turnRigth():Void
	{
		this.isrigth = true;
		this.isLeft = false;
		this.personMC._xscale = 65;
		this.personMC._x -= 50;
	}
	public function down():Void
	{
		personMC.gotoAndStop("shin");
		this._y += speed;
	}
	public function up():Void
	{
		personMC.gotoAndStop("shin");
		this._y -= speed;
	}
	public function attackOne():Void
	{
		personMC.gotoAndStop("attack1");
	}
	public function attackTwo():Void
	{
		personMC.gotoAndStop("attack2");
	}	
	public function jump():Void
	{
		if(isJump)
		{
			if(this._y > jumpHigth && jumpUp)
			{
				this._y -= 10;
			}
			else
			{
				jumpUp = false;
				if(this._y < 428 && !jumpUp)
				{
					this._y += 10;
				}
				else
				{
					this._y = 428;
					isJump = false;
				}
			}
		}
	}
	public function speak(msg:String)
	{
		//trace("=====说话啦~~");
		//首先存在的删除循环
		if(speakMC.onEnterFrame != undefined)
		{
			delete speakMC.onEnterFrame;
		}
		speakMC._visible = true;
		speakMC.speakText.text = msg;
		var time:Number = getTimer();
		//trace("time:" + time);
		var par = this;
		speakMC.onEnterFrame = function()
		{
			//trace("getTimer():" + getTimer());
			if((getTimer() - time) > 5000)
			{
				delete par.speakMC.onEnterFrame;
				par.speakMC._visible = false;
			}
		};
	}
}