loginframe.as

1.配置java环境

/**
 * @(#)LoginFrame.as
 * 
 * @author soda E-mail:[e-mail]
 * @version 1.0
 * <br>Program Name: NetGame for Blue
 * <br>Date: 2007-4-21
 */
import mx.controls.Label;
import mx.controls.TextInput;
import org.blue.net.ConnectJavaServer;
import org.game.context.Session;
import org.game.response.PersonAction;
import org.game.Application;
import org.game.scene.WelcomeScene;
/**
 * 登陆界面
 */
class org.game.frame.LoginFrame extends MovieClip 
{
	private var loginBtn:Button;
	private var clew:Label;
	private var nameText:TextInput;
	private var passText:TextInput;
	private var session:Session;
	private var gameMainMC:MovieClip;
	private var connect:ConnectJavaServer;
	private var host:String = Application.LOCALHOST;
	
	public function LoginFrame()
	{
		//设置焦点
		Selection.setFocus(nameText);
		session = Session.getSession();
		gameMainMC = this._parent._parent;
		session.setGameMainMC(gameMainMC);
		buttonEvent();
	}
	
	public function buttonEvent()
	{
		loginBtn.onPress = function()
		{
			this._parent.checkForm();
		};
	}
	
	private function checkForm():Boolean
	{
		if (nameText.text.length == 0)
		{
			clew.text = "<font color=\"#FF0000\">请输入用户名.</font>";
			Selection.setFocus(nameText);
			return false;
		}
		if (passText.text.length == 0)
		{
			clew.text = "<font color=\"#FF0000\">请输入密码.</font>";
			Selection.setFocus(passText);
			return false;
		}
		connect = ConnectJavaServer.getConnectJavaServer();
		connect.connect(host,5000,nameText.text,passText.text);
		clew.text = "<font color=\"#FF0000\">正在连接服务器，请稍等......</font>";
		var par = this;
		connect.onConnect = function(msg:String)
		{
			trace("msg:" + msg );
			//连接成功
			if(msg == "connect success")
			{
				par.clew.text = "<font color=\"#FF0000\">登陆成，正在读取资料......</font>";
				trace("uesrName:" + par.nameText.text);
				par.session.setName(par.nameText.text);
				par.getUserInfo(this,par.nameText.text);
				trace("连接成功");
			}
			else
			{
				clew.text = msg;
				trace("uesrName:" + par.nameText.text);
				trace("连接失败");
			}
		};
	}
	
	private function getUserInfo(connect:ConnectJavaServer,userName:String):Void
	{
		var par:LoginFrame = this;
		var object:Object = new Object();
		connect.call("PersonRequest","userInfo",object,userName);
		object.onResult = function(obj:Object)
		{
			par.clew.text = "<font color=\"#FF0000\">准备进入游戏......</font>";
			par.session.setId(obj.id);
			par.session.setSculpt(obj.sculpt);
			par.session.setLocality("welcomeScene");
			par.session.setMoeny(obj.money);
			//进入游戏界面
			par.gameMainMC.gameInstance();
			//new WelcomeScene(par.gameMainMC);
			par.connect.addServerCall("PersonAction",new PersonAction(par.gameMainMC));
			par.connect.call("PersonAction","loginSuccess",null,"welcomeScene",
							par.session.getName(),par.session.getSculpt());
			par.unloadMovie();
		};
		object.onFaul = function(obj:Object)
		{
			par.clew.text = "<font color=\"#FF0000\">读取用户资料失败......</font>";
		};
	}
}