arrowframe.as

1.配置java环境

import org.game.context.Session;
import org.blue.net.ConnectJavaServer;
/**
 * @(#)ArrowFrame.as
 * 
 * @author soda E-mail:[e-mail]
 * @version 1.0
 * <br>Program Name: NetGame for Blue
 * <br>Date: 2007-5-2
 */

/**
 * 提示的箭头mc
 */
class org.game.frame.ArrowFrame extends MovieClip 
{
	//提示框
	private var speakFrameMC:MovieClip;
	private var arrowMC:MovieClip;
	private var contentText:TextField;
	private var sceneName:String;
	
	public function ArrowFrame()
	{
		debug("arrowMC:" + arrowMC);
		speakFrameMC._visible = false;
		contentText._visible = false;
		mouseEvents();
	}
	
	/**
	 * 设置提示内容
	 * @param msg:提示内容
	 */
	public function setContent(msg:String):Void
	{
		debug("setContent for msg:" + msg);
		contentText.text = msg;
	}
	
	/**
	 * 设置提示内容的颜色
	 */
	public function setColor(color:Number):Void
	{
		contentText.textColor = color;
	}
	
	/**
	 * 设置要加载的场景名
	 */
	public function setSceneName(sceneName:String):Void
	{
		this.sceneName = sceneName;
	}
	
	/**
	 * 鼠标事件
	 */
	private function mouseEvents()
	{
		this.onRollOver = function()
		{
			debug("onRollOver");
			speakFrameMC._visible = true;
			contentText._visible = true;
		};
		
		this.onRollOut = function()
		{
			speakFrameMC._visible = false;
			contentText._visible = false;
		};
		
		this.onRelease = function()
		{
			debug("sceneName:" + sceneName);
			this._parent.setScene(sceneName);
		};
	}
	
	/**
	 * 改变方向
	 */
	public function changeWay()
	{
		speakFrameMC._x = speakFrameMC._x + 115;
		speakFrameMC._xscale = -speakFrameMC._xscale;
		arrowMC._x = arrowMC._x + 30;
		arrowMC._xscale = -arrowMC._xscale;
	}
	
	/**
	 * 调试信息
	 */
	private function debug(msg:String):Void
	{
		trace("debug ArrowFrame -> " + msg);
	}
}